I'm not sure what you mean by

"Instead of just outputting the matrix for aesthetics, how can i then pass those values on to a matrix P?"

My procedure matrixMaplet returns the Matrix, and you can do whatever you wish with the result, for example assign it to P:

P := matrixMaplet(3,4);

A useful addition to matrixMaplet might be an optional third argument that provides initial values for the entries.  Thus:

matrixMaplet:= proc(m::posint, n::posint, 
   M::{Matrix,matrix,listlist})
     local maplet, M0;
     uses Maplets[Elements];
     if nargs = 3 then M0 := M
     else M0 := Matrix(m,n)
     end if;   
     maplet:= Maplet([
         ["Edit the matrix, please"],
         seq([seq(TextBox[_entry||i||j]('width' = 5,
              'value'=M0[i,j]),j = 1..n)],
             i = 1..m),
         [Button("Done",
           Shutdown([seq(seq(_entry||i||j,j=1..n),i=1..m)]))]
        ]);
   Matrix(m,n,map(parse,Maplets[Display](maplet)));
  end proc:

Q:= <<1,2>|<3,4>|<5,6>>;
Q:= matrixMaplet(2, 3, Q);

Here are two alternatives to make the entries numeric. First, you can use the previous maplet with the entries "parsed":

BB := map( parse, eval( parse( Maplets[Display](makeMaplet(1,5))[] ) ) );

Second, you can change the definition of M in GetMatrix to:

M := Matrix( m,n, (i,j)->Get(entry||i||j::numeric,corrections=true) );

With this approach all entries of the matrix must be numeric. If they are not, then a window will appear in which a numeric value must be entered before going further.

If you adopt the second approach, then maybe you want to put a default value of 0 in every entry in the matrix. You can force the entries to be returned as numeric by changing the double loop creating the entries to:

      seq([seq(TextBox[entry||i||j](width = 5,value=0),j = 1..n)],i = 1..m),

That is, insert ",value=0" to set 0 as the default value in each entry. Here is the current version I have:

restart;
with(Maplets:-Elements):
makeMaplet := proc(m::posint,n::posint)
   Maplet([
      ["Enter the matrix, please"],
      seq([seq(TextBox[entry||i||j](width = 5,value=0),j = 1..n)],i = 1..m),
      [TextBox['TBm']('visible'='false', 'width'=1, 'value'=m ),
       TextBox['TBn']('visible'='false', 'width'=1, 'value'=n ),
       Button("Return the matrix",'onclick'='A1'),
       TextBox['TBM']('visible'='false', 'width'=1, 'value'="" ),
       TextBox['TBd']('visible'='false', 'width'=1, 'value'="" )]
   ],
   Action['A1']( Evaluate('function' = "GetMatrix"),
                 Shutdown(['TBM']) )
)
end proc:

GetMatrix := proc()
  local m, n, M;
  uses Maplets:-Tools;
  sprintf( "in GetMatrix with m=%a and n=%a", m,n );
  m := Get( 'TBm'::posint, corrections=true );
  n := Get( 'TBn'::posint, corrections=true );
  M := Matrix( m,n, (i,j)->Get(entry||i||j::numeric,corrections=true) );
  Set( 'TBM' = M );
end proc:

AA:=eval( parse( Maplets[Display](makeMaplet(3,5))[] ) );

How did I learn this? Experience. Lots of trial and error. Reading the help. Re-reading the help. Asking questions of Maple Technical Support. I did all of this while creating Maplets for Calculus, a collection of now 94 maplets for single variable calculus. Take a look at http://m4c.math.sc.edu/. The actual maplets are on a secure site. I can give temporary access to anyone who would like to take them for a test drive.

Doug

---------------------------------------------------------------------
Douglas B. Meade  <><
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu       
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu/~meade/