I don't think the geom3d package is useful here.
The simplest way to define a 3d arc is using a parametric curve, giving the coordinates as a function of a parameter t in some interval.  For example:

A := <cos(t), sin(t), 0>;    

Rotations can then be done using, e.g.,  RotationMatrix in the Student[LinearAlgebra] package.

I discovered the surface of revolution earlier today.  However, it appears to me like it can only rotate vertically or horizontally.  The problem I'm trying to figure out is I have two points A(1,0,0) and B(0,0,2^.5) and I have an arc AB such that for any point p on the arc, angle ApB = 120 degrees.  I'd like to rotate this arc about the line containing A and B, which would make a surface of revolution.  This surface would contain all points p where angle ApB = 120°.

I think I remember working with rotation matrices, but it was a long time ago.  Would that result in a surface or would it just be a transformation?

Thanks again.

Or simple

P, Q, X := <1,0,0>, <0,0,sqrt(2)>, <x,y,z>:
eq:=cos(Student:-LinearAlgebra:-VectorAngle(X-P,X-Q))=-1/2:
plots[implicitplot3d](eq,
    x=-0.1..1.1,y=-0.5..0.5,z=-0.1..1.5,
    numpoints=10000, 
    axes=normal, 
    style=patchnogrid,
    color=red,
    lightmodel=light4,
    scaling=constrained,
    orientation=[-120,66],
    glossiness=0.85);

giving about the same picture as above.

Alec

Thanks so much for the help Alec.  Here's what I've got now.  I've decided to go with the implicitplot3d.

P,Q,R,S,X := <1,0,0>,<0,0,sqrt(2)>,<-.5,sqrt(3)/2,0>,<0,0,-sqrt(2)>,<x,y,z>:
eq1:=cos(Student:-LinearAlgebra:-VectorAngle(X-P,X-Q))=-1/2:
eq2:=cos(Student:-LinearAlgebra:-VectorAngle(X-R,X-S))=-1/2:
T:=[-1/2,-sqrt(3)/2,0]:
plots[implicitplot3d]([eq1,eq2],
     x=-1.1..1.1,y=-1.1..1.1,z=-1.5..1.5,
     numpoints=25^3,
     axes=normal, 
     style=patchnogrid,
     color=[red,blue],
     lightmodel=light4,
     scaling=constrained,
     orientation=[-90,60],
     glossiness=0.75);

This creates two of the footballs, the original and one with endpoints R(-1/2,sqrt(3)/2,0) and S(0,0,-sqrt(2)).  T is a point that makes an equilateral triangle with P and R in the xy-plane.  I'm having trouble defining points A and B, each on the one of surfaces, and point C which connects A, B, and T so that all the angles at C are 120°.  I don't know if this will result in multiple options for the coordinates of A,B, and C, but if it does then I'd like to maximize the two distances AC and BC while keeping the angles all 120°.  Thanks for any help you can give.

Plotting the second football is slightly more tricky, but can be done as follows. First, I'll repeat the first construction,

with(Student:-LinearAlgebra):
P,Q:=<1,0,0>,<0,0,sqrt(2)>:
center:=(P+Q)/2:
e1,e2:=map(Normalize,NullSpace(Transpose(<P-Q>)))[]:
f1:=Normalize(P-Q):
f2:=e1*cos(alpha)+e2*sin(alpha):
cc:=center-f2/2:
a:=plot3d(cc+f1*cos(beta)+f2*sin(beta),
    alpha=0..2*Pi,beta=Pi/6..5*Pi/6,
    axes=normal,
    style=patchnogrid,
    color=red,
    lightmodel=light4,
    scaling=constrained,
    orientation=[-120,66],
    glossiness=0.85
):

Now, the second one,

 R,S:=<-1/2,sqrt(3)/2,0>,<0,0,-sqrt(2)>:
center1:=(R+S)/2:
g1,g2:=NullSpace(Transpose(<R-S>))[]:
g1:=solve((x*g1+g2).g2)*g1+g2:
g1,g2:=map(Normalize,[g1,g2])[]:
h1:=Normalize(R-S):
h2:=g1*cos(phi)+g2*sin(phi):
cc1:=center1-h2/2:
b:=plot3d(cc1+h1*cos(theta)+h2*sin(theta),
    phi=0..2*Pi,theta=Pi/6..5*Pi/6,
    axes=normal,
    style=patchnogrid,
    color=blue,
    lightmodel=light4,
    scaling=constrained,
    orientation=[-120,66],
    glossiness=0.85
):

Finally,

plots[display](a,b);

Alec