# A reference chart for symbol & character plotting

March 02 2013 by
false
Maple

3

Here is a plot in table format of the standard Times, Helvetica, and SYMBOL fonts. This plot provides a reference table that can be used to find the character codes to plot any one-byte character that can be plotted, which is especially useful for the SYMBOL characters and character codes 128-255 in the standard fonts. These characters are available for plotting in both the Standard and Classic GUIs.

All characters are aligned to be immediately above and immediately to the right of the lower left corner of the subsquare in which they appear.

After executing this, you'll need to resize the plot with the mouse to make it large enough so that the characters fit within their subsquares. Note that resizing a plot does not change the size of the characters. The plot shown below does not fit into the MaplePrimes window, but it will easily fit on your screen when you open it in Maple.

The code below also provides some good examples of some of the less-frequently-used plot options, such as labeled tickmarks.

#The plot uses the negative vertical axis so that it displays as a standard table,
#reading left-to-right and top-down.
plots:-display(
plot(  #The inner gridlines
[seq]([[[.5+k,0],[.5+k,-16]],[[0,-.5-k],[16,-.5-k]]][], k= 0..15),
colour= "Cyan", thickness= 0, linestyle= dash
),
plots:-textplot(
[seq](
eval([
[r, q-.5, convert([k], bytes), font= [TIMES, "roman", 20]],
[.5+r, q-.5, convert([k], bytes), font= [HELVETICA, "roman", 20]],
[.5+r, q-1, convert([k], bytes), font= [SYMBOL, 20]],
[r, q-1, sprintf("%d",k), color= "Fuchsia", font= [TIMES, "roman", 12]]
], [r= irem(k,16), q= -iquo(k,16)]
)[],
k= 0..255
), align= {above,right}
),
view= [0..16, -16..0],
labels= ["low nybble", "high nybble"],
labeldirections= ["horizontal", "vertical"],
labelfont= [HELVETICA, "bolditalic", 16],
axes= boxed,
axis[1]= [
location= high,
gridlines= [$(1..15)], tickmarks= [.5 +~ [$(0..15)] =~ [$(0..9),"A","B","C","D","E","F"]] ], axis[2]= [ location= low, gridlines= [$(-15..-1)],
tickmarks= [-.5 +~ [\$(-15..0)] =~ ["F","E","D","C","B","A",seq(9-k, k= 0..9)]]
],
axesfont= [times, italic, 16],
title= "Fonts: Times, Helvetica, and SYMBOL",
titlefont= [HELVETICA, "bolditalic", 24]
);

Download Font_plot.mw

Loading Comments