MaplePrimes - answers and comments on Question, How to calculate coefficient of determination of a nonlinear fit

Best solution is by transforming to a linear fit

epostma — Thu, 19 May 2011 00:13:03 Z

Hi Andreas,

I entered the data in your example; this looks like data that would be good to fit with an exponential function. (The Excel notation is a little puzzling, but it seems that that's what happens there too.) An exponential function is of course nonlinear, but the fitting process itself is linear: you take the logarithms of all the observations, do a linear fit, and then apply exp to the result. Maple supports this using the ?Statistics/ExponentialFit command:

with(Statistics):
data := <0.07, 2,0.16, 0.24, 0.36, 0.5, 0.8, 1.2, 1.8, 8, 4, 6, 9, 15, 20, 30, 43, 66.9, 100, 150>;
PointPlot(data, axis[2]=[mode=log]); # to show that an exponential fit will work
result := ExponentialFit(<seq(1 .. 20)>, data, x);

This assigns result := 0.0866208931860853*exp(0.365097831283158*x). In order to find the R^2 value for this (linear!) fit, we need the residual sum of squares (easy to obtain with ExponentialFit) and the so-called total corrected sum of squares. For this total corrected sum of squares, we can't use ExponentialFit and we'll need to do the transformation by hand. We can obtain the total sum of squares by seeing that the second central moment is the average of the squared deviations from the mean, whereas the total sum of squares is the sum of the squared deviations from the mean - thus they differ by the factor given by the number of data points. Putting this together, we obtain:

ssRes := Statistics:-ExponentialFit(<seq(1..20)>, data, x, 'output = residualsumofsquares');
logdata := log~(data);
ssTotal := numelems(logdata) * CentralMoment(logdata, 2);
Rsquared := 1 - ssRes / ssTotal;

This results in a value of 0.9167199079, which is what Excel also seems to get.

If you have a more esoteric fitting function and you need to use ?Statistics/NonlinearFit or, better, ?Statistics/Fit, you can use the same approach to find the pseudo-R^2, except you would take the central moment of data - since there is not necessarily an equivalent of logdata that makes sense in that case.

Hope this helps,

Erik Postma
Maplesoft.

How to calc residualsumofsquares

Andreas Madsen — Thu, 19 May 2011 22:25:06 Z

Thanks Erik

Just to make sure that I understand this:

When I want to fit on a exponential function I should perform a log on my Y data, as use did

When it is a power function I should also perform a log on my Y data:

X := <seq(i, i = 1 .. 20)>;
Y := <2.6, 3, 3.6, 4, 4.5, 5, 5.7, 6, 6.7, 7, 7.8, 8, 8.5, 9, 9.6, 10.1, 10.6, 11, 12, 12.4)>;
ssRes := PowerFit(X, Y, x, output = 'residualsumofsquares');
Y := log~(Y);
ssTotal := ArrayTools:-NumElems(Y)*CentralMoment(Y, 2);
R^2 = 1-ssRes/ssTotal; #0.9627722617

But in any other case the Y data shouldn't be modified:

X := <seq(10*i, i = 0 .. 18)>;
Y := <0, .4, .8, 1.9, 4, 7.1, 10.1, 14.6, 15.9, 12.3, 11.5, 9.4, 6.1, 2.6, 1.6, .8, .2, 0, 0>;
f := (x) -> a*sin((1/180)*x*Pi)^n;
ssRes := Fit(f(x), X, Y, x, output = 'residualsumofsquares');
ssTotal := ArrayTools:-NumElems(Y)*CentralMoment(Y, 2);
R^2 = 1-ssRes/ssTotal; #0.9062393748

Also how dose maple calculate the residual sum of squares. I'm interested in this because I not always want to make a fit
but just want to compare the results to an already know function.

I have tryed with this:
residualsumofsquares := proc (f, X, Y, T)
local N;
N := ArrayTools:-NumElems(Y);
return add((Y[i]-(eval(f, T = X[i])))^2, i = 1 .. N)
end proc;

But it dosn't work when it is a exponential or power function:

X := <seq(i, i = 1 .. 20)>;
Y := <0.07, 2, .16, .24, .36, .5, .8, 1.2, 1.8, 8, 4, 6, 9, 15, 20, 30, 43, 66.9, 100, 150>;
ssRes := ExponentialFit(X, Y, x, output = 'residualsumofsquares'); #8.05275870047944231
fitFn := ExponentialFit(X, Y, x);
residualsumofsquares(fitFn, X, Y, x); #634.4706207160136 – should be ssRes

The question is:
– are I'm correct when I say the log~(Y) only should be used when it is an exponential or power function?
– how to calculate the residual sum of squares when it is a exponential or power function?

ln

acer — Thu, 19 May 2011 23:45:49 Z

@Andreas Madsen In your `residualsumofsquares` procedure, try,

  add(evalf((ln(Y[i])-ln(eval(f, T = X[i])))^2), i = 1 .. N);

Answers

epostma — Thu, 19 May 2011 23:54:26 Z

@Andreas Madsen : Well, there really is no difference between an exponential function and a power function, right? The equations y = a * b^x and y = a * exp(B * x) and y = exp(A + B * x) are all equivalent, if A = exp(a) and B = exp(b).

The nice thing about doing the log transform is that that turns it into a linear fitting problem. (Both the exponential and the power fit, since they are the same.) That means that we can discuss the transformed, linear, fitting problem instead of the original nonlinear one. A perfect fit for one problem clearly translates into a perfect fit for the other; we sort of assume that a good-but-not-perfect fit for the one will still translate into a good fit for the other (and actually, the measure of fit may be better in this case than in the original, as a friend recently pointed out to me). For the linear problem, we can talk about R^2, defined in terms of the residual sum of squares and total sum of squares in the log-transformed problem; for the nonlinear problem, we need to resort to pseudo-R^2, defined in terms of the residual sum of squares and total sum of squares in the original problem. Those are different numbers, and the values that result are different.

If instead of the R^2 of the linearized problem, we compute the pseudo-R^2 of the original, nonlinear, fitting problem, we will get a different answer. I have argued above that in some cases, the result from the linear fit would be a better answer, mathematically, but in other cases you might be more interested in the pseudo-R^2 of the nonlinear problem. If that is the case, you can use the residualsumofsquares procedure that you have defined; it computes the residual sum of squares of the original, nonlinear, fitting problem with respect to the solution found in the linearized problem.

If you want to compute the residual sum of squares of the linearized problem "by hand", you can do so as follows:

logY := log~(Y);
fitted := LinearFit([1, x], X, logY, x);
evalf(residualsumofsquares(fitted, X, logY, x); # returns 8.0527587...

So to answer your questions:
- The log transform can be used if it transforms the problem to a linear problem, which is the case for exponential and power functions (they're the same).
- If you are calculating R^2 and for that a residual sum of squares, first decide for which problem to compute them. I would think that if you can linearize the problem, then it's often best to do that first.

Hope this helps,

Erik Postma
Maplesoft

PS: in my code I used a Maple 15 addition, the kernel function ?numelems. I see that you are using ?ArrayTools/NumElems, which was available before but is a little slower. A good idea if you want to be compatible with earlier Maple versions.

Thanks

Andreas Madsen — Fri, 20 May 2011 14:18:32 Z

@epostma

Thanks Erik

With your help I think I have created a procedure there allow me to calculate a R^2 or Pseudo-R^2 in almost any cases.
It looks like this:

Rsquared := proc (fnType::string, inFormular, X::{array, list, rtable}, inY::{array, list, rtable}, T::symbol)
local N, Y, formular, ssRes, ssTotal;
N := ArrayTools:-NumElems(inY):
Y := inY:
formular := inFormular:
if (fnType = "exp" or fnType = "exponential" or fnType = "power") then
Y := map(ln, Y):
formular := ln(formular):
end if;
ssRes := add((Y[i]-(eval(formular, T = X[i])))^2, i = 1 .. N):
ssTotal := N*Statistics:-CentralMoment(Y, 2):
return evalhf(1-ssRes/ssTotal);
end proc:

And is used this way:
X := <seq(i, i = 1 .. 20)>;
Y := <0.07, 2, .16, .24, .36, .5, .8, 1.2, 1.8, 8, 4, 6, 9, 15, 20, 30, 43, 66.9, 100, 150>;
fitFn := ExponentialFit(X, Y, x);
R^2 = Rsquared("exp", fitFn, X, Y, x);

Since this is my first question in mapleprimes.com I don't know how to mark this tread answered – if I need to do so.