MaplePrimes - answers and comments on Question, draw a polygon with labeled vertex

Manually

Alec Mihailovs — Sun, 22 May 2011 23:49:37 Z

Manually.

For example, in Classic Maple,

with(plottools):
with(plots):
display(polygon([[0,0], [3,4], [3,1]]), 
textplot({[0.4,0.3,1],[2.87,3.6,2],[2.87,1.18,3]}),
axes=none);

In Standard Maple that produces a polygon filled black, so you have to add color=white in the polygon arguments, to make it white.

Alec

labelledpolygon

Robert Israel — Mon, 23 May 2011 10:53:02 Z

You might try this one. 

> labelledpolygon:= proc(L::list,r::positive,col)
# L is a list of 2D points, possibly including labels as the third elements
# r the distance from the vertices to the labels
# col the colour for the polygon
  uses plots;
  local V, T,P1,V2,i,a,b,c,n;
  V:= map(t -> [t[1],t[2]],L);
  if nops(L[1]) = 3 then T:= map(t -> t[3],L)
  else T:= map(convert,[$1..nops(L)],string)
  end if; 
  P1:= pointplot([op(V),V[1]],style=line,colour=col);
  n:= nops(V); b:= V[1]-V[n]; b:= evalf(b/sqrt(b[1]^2+b[2]^2));
  for i from 1 to n do
    a:= b;
    if i = n then b:= V[1]-V[n] else b:= V[i+1]-V[i] end if;
    b:= evalf(b/sqrt(b[1]^2+b[2]^2));
    c:= evalc([Re,Im](-(a[1]+I*a[2])*sqrt(-(b[1]+I*b[2])/(a[1]+I*a[2]))));
    V2[i]:= [op(V[i]+r*c),T[i]];
  end do;
  display(P1,textplot(convert(V2,list)),scaling=constrained,_rest); 
end proc;

Then for example:

> labelledpolygon([[1,2,"a"],[2,5,"b"],[4,0,"c"]],0.5, blue);

> labelledpolygon([seq([cos(i*Pi/4),sin(i*Pi/4)],i=0..7)],0.2,red,axes=box);

Another possibility

Alec Mihailovs — Tue, 24 May 2011 05:24:48 Z

Another possibility of what "numbers which are inside of that polygon" could mean is that the numbers could be located "inside" vertices, in which case the GraphTheory:-DrawGraph can be used as in ?GraphTheory[SpecialGraphs][IcosahedronGraph] examples.

Alec

automatic

tiepdinhvan — Mon, 23 May 2011 00:37:31 Z

I want draw tiles of the plan, but every tile is a triangle with labeled vertex, SO that, i want to label automatically.There are a lots of tile? THanks

Implement a procedure

Alec Mihailovs — Mon, 23 May 2011 01:08:27 Z

@tiepdinhvan

Since such a procedure doesn't exist in Maple, one has to write it himself/herself, or ask somebody to do that for him/her, in which case more information is needed for what you want to do exactly, accompanied with an example (or a couple of examples). Adding a work that you did yourself and a description of a problem that you are having not being able to finish it yourself also might be helpful.

Alec

Thanks you for your answer more.

tiepdinhvan — Mon, 23 May 2011 01:45:11 Z

Thanks you for your answer more.