Range

Markiyan Hirnyk — Fri, 01 Jul 2011 22:27:22 Z

How about this?

>Digits:=30:

> with(Student[Calculus1]):
> Roots(x^3-3*2^x+3 = 0, numeric, x = -20 .. 20);

[-1.18997974644791115395551991240, 0., 2.22698301030074546285345802418,

6.59261938334871573971866937479]

RootFinding

Axel Vogt — Fri, 01 Jul 2011 22:41:15 Z

restart;
interface(version);
StringTools:-FormatTime("%Y-%b-%d"); # now
Digits:=floor(evalhf(Digits));

  Classic Worksheet Interface, Maple 15.01, Windows, Jun 1 2011, Build ID 635520
                            "2011-Jul-01"
                             Digits := 15

g:=x^3 - 3*2^x + 3;
B:=[RootFinding:-Analytic( g, x, re=-100..100, im=-100..100 )]:
plots:-complexplot(B,  style=point, symbolsize=20);

methods

acer — Sat, 02 Jul 2011 08:09:26 Z

The Roots command uses fsolve and its `avoid` option internally to do its work.

The methods fsolve will bring to bear are mostly all iterative schemes whose success depend on the chosen initial point. And, internally, fsolve may use some finite number of initial starting points.

But when the specified candidate range gets large, and when there are roots close enough together, then it becomes possible that for a particular root none of the generated initial starting points will converge to it. This can be true for a set (uniform, or other) collection of initial points, and it can also become likely if the initial points are generated randomly.

In other words, for a large interval in the domain the relative size of a basin of convergence for some particular root might be relatively very small. And with a fixed number of generated initial points it may be that (few or) none converge to the given root.

Hence, one possible rule to try and follow would be to keep the stated range (in the variable, in the domain) as short as reasonably possible.

An alternative is to use RootFinding:-NextZero, which searches for the very next root while moving to the right (in the direction +infinity on the real axis).

I think that the NextZero routine has improved in recent releases. Maybe it should be considered for use in Student:-Calculus1:-Roots.

Here is a simple procedure which uses NextZero to try and find all real roots of expression `expr` within the real range `a` to `b`. When it works, it seems to be quite a bit faster than Roots.

restart:

findroots:=proc(expr,a,b,{guard::posint:=5,maxtries::posint:=50})
local F,x,sols,i,res,start,t;
   x:=indets(expr,name) minus {constants};
   if nops(x)>1 then error "too many indeterminates"; end if;
   F:=subs(__F=unapply(expr,x[1]),__G=guard,proc(t)
      Digits:=Digits+__G;
      __F(t);
   end proc);
   sols,i,start:=table([]),0,a;
   to maxtries do
      i:=i+1;
      res:=RootFinding:-NextZero(F,start,
                                 'maxdistance'=b-start);
      if type(res,numeric) then
         sols[i]:=fnormal(res);
         if sols[i]=sols[i-1] then
            start:=sols[i]+1.0*10^(-Digits);
            i:=i-1;
         else
            start:=sols[i];
         end if;
      else
         break;
      end if;
   end do;
   op({entries(sols,'nolist')});
end proc:

findroots(x^3-3*2^x+3, -1000, 1000);

          -1.189979747, -0., 2.226983010, 6.592619383

[edited: I edited the maxdistance value in the call to NextZero above, to make it simpler and to better handle the first time in the loop.]

Almost any practical numerical rootfinding scheme can be broken. Hence, while suggestions for improvements are welcome, there's no bounty for examples which break this scheme. With that in mind, here is a performance example. The first columns is the total number of roots, the second column is the number of roots found, the third column is the maximal forward error by resubstituting the roots into the expression, and the fourth column is the elapsed time.

V:=LinearAlgebra:-RandomVector[row](100,generator=-1.0..1.0):

for i from 1 to 10 do
  expr:=expand( mul((4.3)^x-(4.3)^V[j],j=1..i) );
  d1:='d1':d2:='d2':d3:='d3':gc():
  st:=time();
  sol:=Student:-Calculus1:-Roots(expr,x=-1..1,numeric);
  maxerr:=max(seq(abs(eval(expr,x=X)),X=sol));
  print([i,nops(sol),nprintf("%.1e",evalf[2](maxerr)),time()-st]);
end do:

                     [1, 1, 0.0e+00, 0.094]
                     [2, 2, 1.0e-10, 0.203]
                     [3, 3, 2.0e-10, 1.107]
                     [4, 4, 4.0e-10, 1.638]
                     [5, 5, 7.0e-10, 1.186]
                     [6, 6, 1.4e-08, 1.872]
                     [7, 7, 8.7e-06, 2.449]
                     [8, 8, 5.2e-06, 4.352]
                     [9, 9, 1.5e-04, 5.008]
                    [10, 10, 5.9e-05, 7.425]

for i from 1 to 10 do
  expr:=expand( mul((4.3)^x-(4.3)^V[j],j=1..i) );
  d1:='d1':d2:='d2':d3:='d3':gc():
  st:=time();
  sol:=findroots(expr,-1,1,guard=7);
  maxerr:=max(seq(abs(eval(expr,x=X)),X=[sol])):
  print([i,nops([sol]),nprintf("%.1e",evalf[2](maxerr)),time()-st]);
end do:

                      [1, 1, 1.0e-10, 0.]
                      [2, 2, 0.0e+00, 0.]
                      [3, 3, 2.0e-10, 0.]
                      [4, 4, 3.0e-10, 0.]
                     [5, 5, 7.0e-10, 0.016]
                     [6, 6, 4.1e-07, 0.015]
                      [7, 7, 5.1e-07, 0.]
                      [8, 8, 7.5e-06, 0.]
                      [9, 9, 1.4e-04, 0.]
                    [10, 10, 5.9e-05, 0.016]

NB. It's quite possible that the findroots procedure is not as careful as it might be about avoiding a runaway situation wherein its main loop stops only due to the maxtries parameter.

acer

no range

Christopher2222 — Sun, 03 Jul 2011 13:58:31 Z

@erik10

It is odd that specifying a range too large reduces the number of solutions found. It is almost as if we should specify a higher numpoints value which isn't allowed anyway.

Why do we need to specify a range? Leaving out the range, Maple finds all 4 solutions.

Method 5: Using the SolveEquations command in a DirectSearch package

mois — Tue, 05 Jul 2011 15:51:03 Z

SolveEquations command from DirectSearch package finds all four solutions in one step:

DirectSearch:-SolveEquations(x^3-3*2^x+3=0, AllSolutions);

the picture

Axel Vogt — Fri, 01 Jul 2011 23:44:14 Z