MaplePrimes - answers and comments on Question, starting an animation in a non-standard way

PlotComponent

acer — Tue, 05 Jul 2011 23:48:20 Z

You can do this with a PlotComponent.

Here is a simple example. There's a lot of choice in how to do it. (ie. Toggle buttons, buttons which change their own captions between "Play" and "Pause" and do multiple duty, etc, etc.)

Right-click on the button and the checkbox to see their underlying code (Action when Clicked) which in both cases are just simple calls to the two routines RunMe and PauseMe.

restart:

# You only need to set up these procedures once.
# You can hide this in your StartUp region, or in a
# Code Edit Region.

RunMe:=proc(plotcomp, checkcomp)
uses DocumentTools;
   SetProperty(checkcomp,'value',"false");
   SetProperty(plotcomp,'play',"true");
end proc:

PauseMe:=proc(plotcomp, checkcomp)
uses DocumentTools;
   if GetProperty(checkcomp,'value')="true" then
      SetProperty(plotcomp,'play',"false",'refresh'=true);
   else
      SetProperty(plotcomp,'play',"true",'refresh'=true);
   end if;
end proc:

>	# Create the animation. anim:=plots:-animate(plot,[sin(x*a),x=-20..20], a=-10..10):

>	# Insert the animation into a Plot Component. DocumentTools:-SetProperty('Plot0','value',anim,'refresh'=true);

>	RunMe('Plot0','CheckBox0'); # runs it programmatically

Download component_anim.mw component_anim.mw

acer

Thank You

matejo — Wed, 06 Jul 2011 21:58:53 Z

This is exactly what I was looking for, but somehow I missed the relevant portion of maple help (I really did look there first :-) )

reading acer

PatrickT — Fri, 19 Aug 2011 00:30:01 Z

This is great help acer, I'd been wanting to do this for quite some time. Wouldn't life be easier if one could simply append these "play=true" options to an animation? It doesn't seem to be possible to do e.g.

plots:-display(mypreviouslycreatedanimatedplot, 'play'=true, 'continuous'=true);

I hope it will be possible to do just that in future versions of Maple, it's so intuitive.

Since I came to this post not knowing a thing about "embedded components", let me sum up here, for easy reference, what I have learned by following up on acer's link.

This is how to create the plot component. I had never done that before, indeed I had never used the palettes before.

Toggle the palette on the left-hand side of the worksheet.
Under the "components" tab, select the picture of a plot. This inserts a plot into the worksheet. The plot is blank and named "Embedded Plot Window."
Right-click on the plot and select its "component properties" tab. The "component properties" opens up a window named "Plot Properties" (weird).
In "Plot Expression" enter the name of your animated plot, which in acer's example is simply anim. The blank box will soon fill with the animation.

I personally detest having to use the mouse and pull down menus and stuff. The way I would set it up then is to add

   SetProperty(plotcomp,'continuous',"true");

to acer's RunMe procedure. This way it will play for as long as you care to watch. You won't need to keep pressing RunMe. And then to define the following simple StopMe procedure.

StopMe:=proc(plotcomp, checkcomp)
uses DocumentTools;
      SetProperty(plotcomp,'play',"false",'refresh'=true);
end proc:

This way, you can have:

RunMe('Plot0','CheckBox0'); # runs it programmatically

StopMe('Plot0','CheckBox0'); # stops it programmatically

Upon the first press of "enter" on the keyboard, the animation will run, upon the second press of "enter" it will stop.

Thanks again acer, great tips.