MaplePrimes - answers and comments on Question, Freezing or fixing a parameter at time of function definition

unapply and curry

Joe Riel — Sun, 17 Jul 2011 19:19:34 Z

The usual way to do this is with ?unapply. For example,

t := 3:
f := unapply(x*t, x):

However, for that to work one generally needs an expression (here x*t) to convert to a procedure. That can be a bit tricky when, instead, you have a procedure. One way is to use the curry procedures (?curry and ?rcurry).

g := (x,y) -> x*y:
t := 3:
f := curry(g,t):

In the template you gave we can do

MyProcedure := proc(list_of_values)
local l_funcs;
    l_funcs := map2(curry, SomeFunction, list_of_values);
    plot(l_funcs, 0..10);
end proc:

Another idea

Alex Smith — Sun, 17 Jul 2011 23:38:56 Z

Why not use a sequence to fill in the parameters like this:

f:=(t,x)->t*x;

list_of_values:=[1,2,3,4]:

plot([seq(f(list_of_values[i],x),i=1..4)],x=0..1);

subs

Robert Israel — Mon, 18 Jul 2011 03:57:07 Z

It can be done using subs. Thus:

> f := x -> x*t;
   f3:= subs('t' = 3, eval(f));
   t:= 4;
   f3(x);

The quotes are only needed if the variable t has been assigned a value when f3 is being defined.

premature evaluation

Joe Riel — Mon, 18 Jul 2011 00:35:10 Z

That only works if f permits a symbolic x parameter. Consider

 f := proc(k,x) if x < 1 then k else -k end if end proc:
plot([seq(f(k,x),k=[1,2,3])], x=0..3);
Error, (in f) cannot determine if this expression is true or false: x < 1

You can delay the evaluation of f by using forward quotes:

plot([seq('f'(k,x),k=[1,2,3])], x=0..3);