MaplePrimes - answers and comments on Question, Plot zeros of an ODE

sprintf

Joe Riel — Mon, 18 Jul 2011 18:55:39 Z

Try the ?sprintf function. For example

filename := sprintf("parameter-name=%a.txt", value);

Here is a light weight approach

epostma — Mon, 18 Jul 2011 22:36:18 Z

Here is an alternative approach that is fully in-memory. It won't give you a very beautiful plot, but the idea is there. My example (in Maple 15) uses the ODE with parameter a.

Actually, in production code, I'd use option cache rather than remember because it is less likely to blow up with memory use. However, here option remember will use less memory than the plot structures involved, so it will do for this example.

sys := [a*diff(f(x), x, x) + diff(f(x),x) + f(x) = 0, f(0)=0, D(f)(0) = 1];
solver := dsolve(sys, numeric, parameters=[a]):
solvedf := x -> eval(f(:-x), solver(x));

zerolist := proc(aa)
global solver, solvedf, parameters, a;
option remember;
local x0, result;
  solver(parameters=[a=aa]);
  x0 := RootFinding:-NextZero(solvedf, 0);
  result := Vector(0);
  while x0 < 20 do
    result(numelems(result) + 1) := x0;
    x0 := RootFinding:-NextZero(solvedf, x0);
  end do;
  return result;
end proc;

dispatcher := i -> proc(aa)
local result;
  result := zerolist(aa);
  if numelems(result) >= i then
    return result[i];
  else
    return NULL;
  end if;
end proc;

plot(dispatcher(1), 1/5 .. 5):
# This does adaptive plotting, populating the remember table of zerolist in an appropriate way.
rememberedXValues := sort([indices(op(4, eval(zerolist)), 'nolist')]);
maxlength := max(map(numelems, [entries(op(4, eval(zerolist)), 'nolist')]));

plot([seq(dispatcher(i), i = 1 .. maxlength)], 1/5 .. 5, 'sample' = rememberedXValues, 
     'adaptive = false', 'view = [DEFAULT, 0..15]');

This results in the following graph:

Hope this helps,

Erik Postma
Maplesoft.

Verification

Markiyan Hirnyk — Mon, 18 Jul 2011 23:10:55 Z

How does your light weight approach conform with the exact solution?

> sys := [a*(diff(f(x), x, x))+diff(f(x), x)+f(x) = 0, f(0) = 0, (D(f))(0) = 1]:

> sol := dsolve(sys, f(x));

          f(x)= - sqrt(1-4*a)*a*exp(1/2*(-1+sqrt(1-4*a))*x/a)/(-1+4*a)+ sqrt(1-4*a)*a*exp(-1/2*(-1+sqrt(1-4*a))*x/a)/(-1+4*a)

> solve(rhs(sol) = 0, x, AllSolutions = true);

                                 2 I Pi _Z1 a
                              - --------------
                                         (1/2)
                                (1 - 4 a)
> plot(eval(rhs(sol), a = .1), x = -10 .. 10, y = -.5 .. .5);

Edit. In the RHS of f(x)

Error

Markiyan Hirnyk — Tue, 19 Jul 2011 05:58:43 Z

Executing your code, I got an error:

Download roots.mw

no errors with Maple15

PatrickT — Tue, 19 Jul 2011 18:30:40 Z

@Markiyan Hirnyk

tested epostma's code, it worked here (Windows Vista, 32bits, Maple 15, standard)

No answer to my comment

Markiyan Hirnyk — Thu, 11 Aug 2011 08:44:32 Z

Dear Erik,

I am worried by no reply of you. I believe that the civilized people use to answer the questions. BTW, as far as I know it, your code doesn't work in Maple 15 under WindowsXP SP 3.

Sincerely, Markiyan

PS. Duplicated in a private message to Erik Postma.