MaplePrimes - answers and comments on Question, why not cancelling?

normal

longrob — Mon, 29 Aug 2011 10:56:17 Z

I think it's normal behaviour by Maple.

For example,

(a*c+c)/(b*c+c);
                            a c + c
                            -------
                            b c + c

Force cancellation

Preben Alsholm — Mon, 29 Aug 2011 15:54:20 Z

If on the surface of it you see common factors you could force factorization by a procedure like the following.

sfactor:=proc(u) local i,F,S,p;
if not hastype(u,`+`) then return u end if;
if not type(u,`+`) then return evalindets(u,`+`,procname) end if;
for i to nops(u) do
if not type(op(i,u),`*`) then
    F[i]:={op(i,u)}
else
    F[i]:={op(op(i,u))}
end if
end do;
S:=`intersect`(seq(F[i],i=1..nops(u)));
if S={} then
   u
else
   p:=`*`(op(S));
   p*map(`/`,u,p)
end if
end proc;

#Test on your example.
u:=(Pi^2*(c+(1+Pi)/Pi)^2+Pi^2)/((c-(-1+Pi)/Pi)^2*Pi^2+Pi^2);
T:=op(1,u);
sfactor(T);
sfactor(u);

Reference

Markiyan Hirnyk — Mon, 29 Aug 2011 16:23:15 Z

It was asked and answered here:http://www.mapleprimes.com/questions/36354-Help-Maple-Doesnt-Cancel-Common-Factors . This link can be found by the "cancel" search in MaplePrimes at the top of this page.

easy with a transformation rule

Alejandro Jakubi — Wed, 31 Aug 2011 09:08:33 Z

A common factor of type constant as here can easily be cancelled out by a transformation rule that iteratively extracts the factor out from a sum by taking pairs of summands, and applying it to the subexpressions of type `+`, like:

fac3:=A::constant*B::algebraic+A::constant*C::algebraic=A*(B+C):
ex:=(Pi^2*(c+(1+Pi)/Pi)^2+Pi^2)/((c-(-1+Pi)/Pi)^2*Pi^2+Pi^2):

subsindets(ex,`+`,x->applyrule(fac3,x));

                          /    1 + Pi\2
                          |c + ------|  + 1
                          \      Pi  /
                          ------------------
                          /    -1 + Pi\2
                          |c - -------|  + 1
                          \      Pi   /

The simple pattern above will not work for coefficients of type constant. So, a rule specific for the factor at hand may be better:

p:=identical(Pi^2):
fac0:=A::p*B::algebraic+A::p*C::algebraic=A*(B+C):
subsindets(ex,`+`,x->applyrule(fac0,x));

                          /    1 + Pi\2
                          |c + ------|  + 1
                          \      Pi  /
                          ------------------
                          /    -1 + Pi\2
                          |c - -------|  + 1
                          \      Pi   /

That's a different case, as it can be easily

Thomas Richard — Tue, 30 Aug 2011 10:40:47 Z

That's a different case, as it can be easily handled by simplify or normal. Axel's example with Pi^2 as the common factor is more difficult.

Thx, I like it !

Axel Vogt — Mon, 29 Aug 2011 22:17:12 Z

Preben, thank you - I like it!