MaplePrimes - answers and comments on Question, dsolve, events: how to build an efficient loop

Use a discrete variable in events

Joe Riel — Wed, 14 Sep 2011 18:46:27 Z

Is this what you want:

sys := { NULL
         , diff(y(t),t) + y(t) = 0
         , y(0) = 1
         , s(0) = 1
       }:

integ := dsolve( sys
                 , 'numeric'
                 , 'events' = [[y(t)=10^(-s(t)), [s(t)=s(t)+1]]]
                 , 'discrete_variables' = [s(t)]
               );

plots:-odeplot(integ, [s(t),t], 0..10);

Another approach

PatrickT — Sat, 17 Sep 2011 13:36:59 Z

Here is another approach, shown to me by Allan, based on eventfired, see below

http://www.mapleprimes.com/questions/125273-Dsolve-Events-How-To-Control-For-A-Sign-Change#comment125426

This approach also relies on reinitializing the integrator, there seems to be no way to record event dates on the fly.

I am reporting about here for the record, for myself and (hopefully) someone else.

Here is the system on which I based my tests:

t0:=0: t1 := 25:
Sol := dsolve( 
  [ diff(y(t),t) = -y(t), y(t0) = 1, p(t0) = 1/10 ]
  , 'type' = numeric
  , 'discrete_variables' = [ p(t)::float ]
  , 'events' = [ [ y(t) = p(t), [ p(t) = p(t)/10, 'halt' ] ]  ]
) ;

The main loop suggested by Allan goes as follows:


A := Array([0]):
Sol(1e-6):
while A[-1] < tf do
  Sol(t1):
  A(ArrayNumElems(A)+1) := Sol(eventfired=[1])[1]:
  Sol(eventclear):
end do;


A slightly more versatile loop may be written, to allow for integration forward and backward.

RecordEventDates := proc(dsol,range)
  local A,ts,tf;
  description "the first argument is the output of dsolve
    , the second argument is the range of integration
    , based on suggestions by Erik Postma, Joe Riel, Allan Wittkopf" ;
  interface(warnlevel=0);
  ts:=lhs(range); tf:=rhs(range);
  A := Array([0]);
  if tf>ts then 
    dsol(ts+1e-6); # may need tweaking
  elif tf<ts then 
    dsol(ts-1e-6); 
  else break; 
  end if;
  while A[-1] < tf do
    dsol(tf):
    A(ArrayNumElems(A)+1) := dsol(eventfired=[1])[1]:
    if dsol(eventstop)=1 then 
      dsol(eventclear);
    elif dsol(eventstop)=0 then 
      break; 
    end if;
  end do;
  if ArrayNumElems(A) < 3 then 
    A := []; A;
  else 
    A := convert(A,list); A[2..-2]; 
  end if;
end proc:
A := RecordEventDates(Sol,t0 .. t1);

This works on a small number of examples I have tested. It probably needs tweaking, especially the part where the integration is reinitialized. If I've done it right, it will return an empty list if the event has not triggered. It caters only for one event right now, the bit eventfired=[1] would need to be changed to accommodate for more events. I bet there are some redundant lines of code, but at this time it's doing the job I need, I think. I hope.

For determining the time at which this happens slightly more easily

epostma — Wed, 14 Sep 2011 23:32:27 Z

I would tweak your (nice) solution a little bit, Joe:

sys := { NULL
         , diff(y(t),t) + y(t) = 0
         , y(0) = 1
         , s(0) = 0
         , p(0) = 0.1
       }:

integ := dsolve( sys
                 , 'numeric'
                 , 'events' = [[y(t)=p(t), [s(t)=t, p(t) = p(t)/10]]]
                 , 'discrete_variables' = [s(t), p(t)]
               );

plots:-odeplot(integ, [t, p(t)], t=0..25, axis[2]=[mode=log]);
plots:-odeplot(integ, [t, s(t)], t=0..25);

This way p(t) holds the next "boundary" to be tested against, and s(t) holds the time at which the last boundary was achieved.

Hope this helps,

Erik Postma
Maplesoft.

nice

Joe Riel — Thu, 15 Sep 2011 00:00:32 Z

@epostma Nice extension. Saving the event-time explicitly is a useful technique.

creating a list

PatrickT — Thu, 15 Sep 2011 00:35:26 Z

Thanks Joe, Thanks Erik,

your suggestion Joe has helped me a great deal in understanding how to use discrete variables. I was getting ready to post a follow-up question just as Erik posted his suggestion. Seeing Erik's suggestion I'm pleased to see that I was on the right track. But I got stuck at the point of trying to make a list of the dates. And having spent an hour (at least) on this without success, I turn to you again for advice.

I had adapted Joe's code like this:

Sol :=
dsolve( [ diff(y(t),t) = -y(t), y(0) = 1, p(0) = 1, s(0) = 0 ]
    , 'type' = numeric
    , 'discrete_variables' = [ p(t), s(t) ]
    , 'events' = [ [ y(t) = 10^(-p(t)), [ p(t) = p(t)+1, s(t) = t ] ] ]
    , 'output' = listprocedure
) ;

in order to extract time like this:

tSol := subs(Sol, s(t));
plot(tSol, 0..10);

I didn't use odeplot because I'm primarily interested in extracting the data in a list. Using listprocedure is the method that I'm aware of.

It's also very helpful to see Erik's different way of setting up the p(t).

But here I got stuck. The values of time I want to extract are in the procedure named tSol. I tried strange things like trying to solve tSol=t, but didn't manage to get it to work. I would like to have a list of the dates at which p(t) changes.

thanks a lot,

Patrick.

NULL

PatrickT — Thu, 15 Sep 2011 00:37:16 Z

Oh and I also wanted to ask,

what is the purpose of having NULL in the definition of the ODE system?

thanks.