MaplePrimes - answers and comments on Question, How do I create histogram for a discrete probability distribution?

One way

Markiyan Hirnyk — Tue, 27 Sep 2011 15:09:56 Z

It can be done as follows.

> restart; with(Statistics):
> P := [1/8, 0, 1/4, 0, 1/2, 0, 1/8, 0];

                          [1     1     1     1   ]
                          [-, 0, -, 0, -, 0, -, 0]
                          [8     4     2     8   ]

> X := RandomVariable(ProbabilityTable(P));
> ProbabilityFunction(X, 7);

                                     _R
                                      1
                                      -
                                      8

> plot(ProbabilityFunction(X, t+1/2), t = 0 .. 10, thickness = 3);

Procedure

Kitonum — Sat, 05 Mar 2016 17:35:02 Z

The simple procedure Hist builds a histogram for any lists X and P and the width h . The options are: C is the color of filling (by default blue) and V is the view of the plot.

Hist := proc (X::list, P::list, h::numeric, C::{string, symbol} := blue, V::list := [X[1]-0.6*h .. X[-1]+0.6*h, 0 .. max(P)])

local n, S, A, B;

n := nops(X);

S := seq(piecewise(X[i]-(1/2)*h <= x and x <= X[i]+(1/2)*h, P[i]), i = 1 .. n);

A := plot([S], x = X[1]-(1/2)*h .. X[n]+(1/2)*h, color = C, filled);

B := plot([S], x = X[1]-0.51*h .. X[n]+0.51*h, tickmarks = [default, [seq(P[i] = P[i], i = 1 .. n)]], color = black, thickness = 2);

plots:-display(A, B, view = V);

end proc:

The initial example:

Hist([1, 3, 5, 7], [1/8, 1/4, 1/2, 1/8], 1.8);

The second example with 2 used options:

Hist([1, 2, 3, 4], [1/8, 1/4, 1/2, 1/8], 0.8, cyan, [-0.5 .. 5.2, -0.05 .. 0.6]);

Simply with Histogram

Carl Love — Sat, 05 Mar 2016 19:13:41 Z

I prefer to achieve results similar to Kitonum's simply by using the Statistics:-Histogram command. In the code below, the 10000 can be any similar large number, and the .5 in the binbounds can be adjusted as needed.

X:= [1, 3, 5, 7 ]:
P:= [1/8, 1/2, 1/4, 1/8]:
Statistics:-Histogram(
zip(`$`, X, round~(10000*P)),
binbounds= (x-> (x-.5, x+.5))~(X),
tickmarks= [X, P =~ P]
);

See ?Statistics,Histogram, ?$, ?zip, ?plot,tickmarks, and ?plot,typesetting.

numbers on x-axis

AdVen1935 — Sat, 05 Mar 2016 14:45:19 Z

For the vertical bars the numbers are now 1, 3, 5, 7.

What should I do if I want them to be 1, 2, 3, 4?

Thanks a lot for your very helpful answers. Now I ...

AdVen1935 — Sun, 06 Mar 2016 14:35:52 Z

Thanks a lot for your very helpful answers.

Now I have still a last question.

For that question I have to show you my Maple sheet, but I do not know how to copy and pate my Maple sheet here.

Perhalps you can tell em how to dothis.

Thanks a lot. I have still one smal question. For ...

AdVen1935 — Sun, 06 Mar 2016 14:38:39 Z

Thanks a lot. I have still one smal question. For that questopon I like to show my Maple sheet. I do not know how to do this. Copy and paste does nit work. Do you know how to do this?