MaplePrimes - answers and comments on Question, integrals with large limits

int

Robert Israel — Sun, 09 Oct 2011 12:23:48 Z

There are basically two ways to deal with a definite integral in Maple: symbolic and numeric. For a symbolic integral, you want an exact formula for the result. This will be calculated, if possible, by int, but the result might be extremely complicated. Usually an endpoint of 1000 wouldn't make much difference, if any. For a numeric integral, you want a decimal approximation to the result. This can be done by evalf(Int(...)), avoiding any attempt at a symbolic solution. Usually this is quite fast, although there may be problems e.g. if your integrand oscillates a lot.

We might be able to give better advice if you gave us a specific example of the type of integral that's giving you trouble.

By interpolation of the integrand

Markiyan Hirnyk — Sun, 09 Oct 2011 21:32:53 Z

I don't succeed to evaluate the integral under consideration directly. Because of this I apply the idea stated by acer in
http://www.mapleprimes.com/questions/123533-Maple-Can-Integrate-But-Cant-Plot#comment123562
and interpolate the integrand by splines:
> ydata := [seq(1/HH((1091.3*(1/2000))*j), j = 0 .. 2000)]:

> xdata := [seq((1091.3*(1/2000))*j, j = 0 .. 2000)]:

> Func := x -> CurveFitting:-ArrayInterpolation(xdata, ydata, x, method = spline);

x -> CurveFitting:-ArrayInterpolation(xdata, ydata, x, method = spline)
> int(Func, 0 .. 1091.3);
1.033704574
> plot([1/HH, Func], 0 .. 1091.3, view = [0 .. 10, 0 .. 2], color = [red, blue], thickness = 2);

int_by_interp.mw

for example

Axel Vogt — Sun, 09 Oct 2011 22:36:45 Z

I hate that *.mw sheets ...

Being not much used to DE, especially to their numerical solutions, I have not
looked closer how the solution may be improved - it seems to be very slow to
be evaluated.

Just used it (15 Digits):

G:=proc(z) 1.0/HH(z); end proc;
Int(G, 0 .. 10)+Int(G, 10 .. 100)+Int(G, 100 .. 1091.3);
evalf[8](%);
                   4.5667205

Unfortunately one can not use 'method = _d01akc' in a direct way

PS hating: in a real sheet (export as Maple input, *.mpl) it crashes.
Sh... lost patients to work with that.

relaxing the tolerances (of both dsolve/numeric and evalf/Int)

acer — Mon, 10 Oct 2011 07:45:15 Z

restart:

Digits:=15:

b:=-95: `ε`:=1/4: h:=.69: n:=9.2: om:=.7:

ode1 := diff(Omega(z),z)
        +(Omega(z)*(1-Omega(z))*(3-2*sqrt(Omega(z))*(1+z)/n)
        +Omega(z)*(1-Omega(z))*`ε`
        *b*(1+z)*(diff(phi(z),z)))/(1+z)=0:
ode2 := diff(phi(z),z)+sqrt((2*(1+z))*sqrt(Omega(z))/(3*n)
             +(1-Omega(z))*(1+z)*b*`ε`
             *(diff(phi(z),z))/(3*Omega(z)))/((1+z).H(z))=0:
a := solve(ode2, diff(phi(z),z)):
ode22 := diff(phi(z),z) = a[1]:
ode3 := diff(H(z),z)+H(z)*((3/2)*Omega(z)
        -(1+z)*Omega(z)^(3/2)/n+(1/2*(1-Omega(z)))*(1+z)*b*`ε`
        *(diff(phi(z),z))-3/2)/(1+z)=0:

sys := {ode1,ode22,ode3}:
ics := {H(0)=.69, phi(0)=0, Omega(0)=.7}:

sol := dsolve(`union`(sys, ics), numeric, relerr=1e-5,
              output=listprocedure):
HH := subs(sol, H(z)):

st := time():
evalf(Int(z->1/HH(z), 0..1091.3, epsilon=1e-5)):
evalf[7](%);
                            4.566725

time()-st;
                             2.481

sol := dsolve(`union`(sys, ics), numeric, relerr=1e-5,
              output=listprocedure, stiff=true):
HH := subs(sol, H(z)):

st := time():
evalf(Int(z->1/HH(z), 0..1091.3, epsilon=1e-5)):
evalf[7](%);
                            4.566721

time()-st;
                             9.906

acer

Thanks for your reply. For example after

goli — Sun, 09 Oct 2011 12:55:31 Z

Thanks for your reply. For example after solving an ODE system I want to obtain the result of an integral as follows:

> b := -95; `ε` := 1/4; h := .69; n := 9.2; om := .7:

> ode1 := diff(Omega(z), z)+(Omega(z)*(1-Omega(z))*(3-2*sqrt(Omega(z))*(1+z)/n)+Omega(z)*(1-Omega(z))*`ε`*b*(1+z)*(diff(phi(z), z)))/(1+z) = 0:

> ode2 := diff(phi(z), z)+sqrt(2*(1+z)*sqrt(Omega(z))/(3*n)+(1-Omega(z))*(1+z)*b*`ε`*(diff(phi(z), z))/(3*Omega(z)))/((1+z).H(z)) = 0:

> a := solve(ode2, diff(phi(z), z)):

> ode22 := diff(phi(z), z) = a[1]:

> ode3 := diff(H(z), z)+H(z)*((3/2)*Omega(z)-(1+z)*Omega(z)^(3/2)/n+(1/2)*(1-Omega(z))*(1+z)*b*`ε`*(diff(phi(z), z))-3/2)/(1+z) = 0:

> sys := {ode1, ode22, ode3}:

ics := {H(0) = .69, phi(0) = 0, Omega(0) = .7}:

sol := dsolve(`union`(sys, ics), numeric, output = listprocedure, stiff = true):

> HH := subs(sol, H(z));

The integral I want to solve is:

> R := h*evalf(sqrt(1-om)*(int(1/HH(z), z = 0 .. 1091.3)));

Enlarge the system

Robert Israel — Mon, 10 Oct 2011 10:32:58 Z

@goli :Since you're already solving an ODE system, I think the simplest solution might be
to add a new dependent variable to the system: the derivative of this variable is the integrand.

> newde:= diff(r(z),z) = h*sqrt(1-om)/H(z);
newic:= r(0) = 0;
sol:= dsolve(sys union ics union {newde, newic}, stiff=true);
sol(1091.3);

So your desired R is 1.72589404761241.