MaplePrimes - answers and comments on Question, How do I make Maple do this bit of calculus?

one approach

Joe Riel — Sat, 22 Oct 2011 08:25:04 Z

Maple doesn't normally handle "naked" differentials (dx, dy), though some packages may permit it. You could formulate the original equation as a standard Maple differential equation, then use ?dsolve to solve it:

deq := deq := A=B*x*diff(y(x),x):
dsolve({deq, y(x1)=y1});

                               A ln(x)        A ln(x1)
                        y(x) = ------- + y1 - --------
                                  B              B

some steps

pagan — Sat, 22 Oct 2011 09:06:53 Z

As Joe mentions, the most natural and easiest way is to use dsolve. But it's a fun exercise to try and automate the steps (if only to help appreciate how much subtlety there must be within dsolve).

restart:

eq := A = B*x*diff(y(x),x);

                               / d      \
                       A = B x |--- y(x)|
                               \ dx     /

eq := expand(eq/x); # how to automate this? frontend?

                        A     / d      \
                        - = B |--- y(x)|
                        x     \ dx     /

map(int, eq, x=x1..x2, continuous) assuming x1>0, x2>x1;

           -A ln(x1) + A ln(x2) = -B y(x1) + B y(x2)

eval(%,[y(x1)=y1, y(x2)=y2]);

              -A ln(x1) + A ln(x2) = -B y1 + B y2

combine(%) assuming x1>0, x2>x1 ;

                        /x2\               
                    A ln|--| = -B y1 + B y2
                        \x1/               

simplify(%, size);

                        /x2\               
                    A ln|--| = -B (y1 - y2)
                        \x1/               

collect(sort(%, B), B);

                        /x2\               
                    A ln|--| = B (-y1 + y2)
                        \x1/

more manual labor

Joe Riel — Sat, 22 Oct 2011 19:12:39 Z

Following pagan's lead, here's another manual approach. I used the naked differentials, but removed them before integrating. Years ago I wrote a Maple package that could integrate such one-forms...some day I should revive it.

deq := A=B*x*d(y)/d(x);
                              B x d(y)
                          A = --------
                                d(x)  
isolate(deq,x);
                          x       A   
                         ---- = ------
                         d(x)   B d(y)
map(`/`,%);
                         d(x)   B d(y)
                         ---- = ------
                          x       A   
eval(%,d=1);
                             1   B
                             - = -
                             x   A
int(lhs(%),x=x1..x2) = int(rhs(%),y=y1..y2) assuming positive;
                                    B (y2 - y1)
                 -ln(x1) + ln(x2) = -----------
                                         A     
combine(%,ln) assuming positive;
                        /x2\   B (y2 - y1)
                      ln|--| = -----------
                        \x1/        A

Okay......

Edo Karura — Sun, 23 Oct 2011 07:19:49 Z

This is going in the right direction but I've got a couple questions.

1. What is a "naked differential"?

2. Why are you guys defining a function called "deq"? Why not handle the the equation as itself using labels, palletes, and context menus?

3. Why do your posts look like that? Is it because they are in 1-D and Worksheet Mode? Can't I use 2-D, palletes, context menus, Document Mode, etc? I tried to copy n paste then execute them but nothing happened.

I tried to do it Joe Riel's way and this is what I got. int_v_dsolve.mw

Thanks guys!

Edo

Remark

Markiyan Hirnyk — Sat, 22 Oct 2011 10:49:53 Z

In my opinion, x=x1..x is more exactly.

what's in a name

pagan — Sat, 22 Oct 2011 18:05:59 Z

@Markiyan Hirnyk

I was trying to make it be closer to what the poster had in his hand-written note, as opposed to say how Joe had it.

But I see the point.