Transparency

Markiyan Hirnyk — Fri, 18 Nov 2011 01:31:59 Z

This can be done in such a way:
>with(plots):
>f := eval(((x*cos(theta[j])+y*sin(theta[j])-r)^2+(x*sin(theta[j])-y*cos(theta[j])-r)^2
+z^2+a^2-b^2)^2-4*a^2*((x*cos(theta[j])+y*sin(theta[j])-r)^2+z^2) = 0,[r = 2, a = 3, theta[j] = (1/4)*Pi, b = 1]):
>p1 := implicitplot3d(f, x = -6 .. 6, y = -6 .. 6, z = -5 .. 5,
numpoints = 30000, scaling = constrained, color = brown, style = surface):#plot of the first torus
>g := eval(((x*cos(theta[j])+y*sin(theta[j])-r)^2+(x*sin(theta[j])-y*cos(theta[j])-r)^2+z^2+a^2-b^2)^2
-4*a^2*((x*cos(theta[j])+y*sin(theta[j])-r)^2+z^2) = 0, [r = 2, a = 3, theta[j] = (1/3)*Pi, b = 1]):
>p2 := implicitplot3d(g, x = -6 .. 6, y = -6 .. 6, z = -5 .. 5, numpoints = 30000,
scaling = constrained, axes = frame, color = blue, style = surface):#plot of the second torus
>h := eval(((x*cos(theta[j])+y*sin(theta[j])-r)^2+(x*sin(theta[j])-y*cos(theta[j])-r)^2
+z^2+a^2-b^2)^2-4*a^2*((x*cos(theta[j])+y*sin(theta[j])-r)^2+z^2) = 0, [r = 2, a = 3, theta[j] = (1/2)*Pi, b = 1]):
>p3 := implicitplot3d(h, x = -6 .. 6, y = -6 .. 6, z = -5 .. 5, numpoints = 30000,
scaling = constrained, axes = frame, color = green, style = surface):#plot of the third torus
>p4 := intersectplot(f, g, x = -6 .. 6, y = -6 .. 6, z = -5 .. 5, numpoints = 1000,
scaling = constrained, thickness = 4, axes = frame, grid = 35):
#plot of the intersection of the first torus and second torus
>display([p1, p2, p3, p4], transparency = .8);# display of all four plots together

Of course, you can plot another intersection instead of p4.
See ?intersectplot and transparency in ?plot3d/option for more details.

Another plot

Markiyan Hirnyk — Fri, 18 Nov 2011 01:57:14 Z

Putting theta[j]=Pi/6 istead of Pi/4 in f, we obtain

Intersection

Markiyan Hirnyk — Fri, 18 Nov 2011 02:21:07 Z

First, find the intersection of the three tori:

> sol := evalf(solve({f, g, h}, [x, y, z]));# with Pi/6 in f

[[x = 0., y = 0., z = 2.508286790 + 2.071594222 I],

[x = 2.958929915, y = 0.1178637253, z = 2.111127872]]
> p5 := pointplot3d({map(c -> rhs(c), sol[2])}, symbol = solidsphere, symbolsize = 30, color = red):

> display(p1, p2, p3, p5, transparency = .5);

Thank You

abarua — Fri, 18 Nov 2011 02:58:41 Z

@Markiyan Hirnyk

Thank you so much! I have learned so much from your post. This is very helpful. Again thank you very much.

MaplePrimes - answers and comments on Question, How to plot the intersection of three surfaces

Transparency

Another plot

Intersection

Thank You