MaplePrimes - answers and comments on Question, do loop ...on error goto?

try..catch

pagan — Wed, 25 Jan 2012 11:32:01 Z

Do you want something like this?

SPV := proc (values::list, b::integer)
local a, N, const, value, res;
  N := nops(values);
  const := convert([seq(x || i, i = 1 .. N)], `+`) <= b;
  value := convert([seq(x || i*values[i], i = 1 .. N)], `+`);
  for a to 100 do
    res:='res'; # wasn't sure whether you wanted final result. if not, get rid of res.
    try
      res := Optimization:-LPSolve(value, {value = a, const}, assume = {nonnegint},
                                  depthlimit = 200, maximize);
    catch "no feasible integer point found":
      return a+1;
    catch "no feasible point found for LP subproblem":
      return a+1;
    catch: # all other errors
      error; # rethrow the error
    end try;
  end do;
  NULL;
end proc:

SPV([1, 2, 5, 7], 13);

                               89

SPV([1, 4, 12, 21], 5);

                               73

SPV([1, 2, 7, 12, 50], 5);

                               42

SPV([1, 2, 5, 20], 7);

                               79

another one - try..catch

brian bovril — Mon, 30 Jan 2012 09:44:39 Z

thx Pagan, it works well.

I have another, related problem. this time it needs to stay looping while errors are generated, to find the one or two "real" answers. i hope the worksheet is self explanatary

subset_sum_proble.mw

another one

pagan — Mon, 30 Jan 2012 10:47:56 Z

@brian bovril If it survives the try..catch then it augments the table of successes. If it hits an acceptable error (no solution found) then it advances to the next loop iteration. If it hits any other error then it rethrows the error so that the procedure can itself stop with that error. And it returns a sequence of the table entries.

restart:

SSP := proc(values::list)
local a, N, const, sumv, res, allsols, x;
  N := nops(values);
  const := add(x || i, i = 1 .. N);
  sumv := add(x || i*values[i], i = 1 .. N);
  for a to N do
    try
      res := Optimization:-LPSolve(sumv, {const = a, sumv = 0},
                                   assume = {binary}, depthlimit = 200);
    catch "no feasible integer point found":
      next;
    catch "no feasible point found for LP subproblem":
      next;
    catch: error;
    end try;
    allsols[a]:=res;
  end do;
  return seq([x,allsols[x]], x in indices(allsols,nolist));
end proc:

SSP([-7, -3, -2, -5, 5]);

      [2, [0, [x1 = 0, x2 = 0, x3 = 0, x4 = 1, x5 = 1]]], 

        [3, [0, [x1 = 0, x2 = 1, x3 = 1, x4 = 0, x5 = 1]]]

SSP([-7, -3, -2, 5, 8]);

       [3, [0, [x1 = 0, x2 = 1, x3 = 1, x4 = 1, x5 = 0]]]

try-catch

brian bovril — Fri, 03 Feb 2012 10:12:08 Z

thx Pagan, works well