MaplePrimes - answers and comments on Question, dsolve,numeric: "Error, (in dsolve/numeric/BVPSolve) matrix is singular". Why?

dsolve,numeric

Adri vanderMeer van der Meer — Wed, 01 Feb 2012 19:40:33 Z

There is an unassigned parameter l in the ODE.

If you change the command in:

sol := dsolve({bc, eqn}, numeric, parameters=[l]);

you get the errormessage:

Error, (in dsolve/numeric) cannot numerically solve a parametric boundary value problem

Additionally: there are 5 ic/bc's and that results in an inconsistent system of equations if you try to solve for the constants in the general solution.
Numerical solutions can be found for 4 initial conditions.

Solving for L

Preben Alsholm — Wed, 01 Feb 2012 21:08:29 Z

As Adri van der Meer points out there are too many conditions.

Assuming therefore that what you want is to determine L (l) so that the conditions are satisfied you can do like the following, where numerical solution of the ode is not used.

restart;
eqn := diff(Y(x), x$4) = l^4*Y(x);
bc1 := Y(0) = 0, D(Y)(0) = 1, D(D(Y))(0) = 0, Y(.5) = 0;
#bc := Y(0) = 0, (D(Y))(0) = 1, (D(D(Y)))(0) = 0, Y(.5) = 0, (D(Y))(.5) = 0;

sol := dsolve({bc1, eqn});

diff(sol,x);
eval(rhs(%),x=1/2);
#Numerator and denominator:
nm,dn:=(numer,denom)(normal(%));
plot(nm,l=0..10,-1..1);
#Here is one solution:
L:=fsolve(nm,l=7.9);
#Just making sure that the denominator is not also zero:
eval(dn,l=L);
#Plotting the solution:
eval(sol,l=L);
plot(rhs(%),x=0..1/2);
#Checking the derivative of Y at x = 1/2:
eval(diff(sol,x),{x=.5,l=L});

Numerical solution

Preben Alsholm — Thu, 02 Feb 2012 20:39:09 Z

Here is a numerical solution. The "matrix singular" situation is avoided basically by replacing l^4 by the name l4, but also by introducing l4 as a constant function:

eqn2 := diff(Y(x), x$4) = l4(x)*Y(x),diff(l4(x),x)=0;
bc := Y(0) = 0, D(Y)(0) = 1, D(D(Y))(0) = 0, Y(.5) = 0, D(Y)(.5) = 0;
sol2 := dsolve({bc, eqn2},{Y(x),l4(x)},numeric,output=listprocedure);
plots:-odeplot(sol2,[x,Y(x)]);
plots:-odeplot(sol2,[x,l4(x)^(1/4)]);
L2:=subs(sol2,l4(x)^(1/4));
L2(0);
L2(.5);

Thanks for your reply. So Maple's dsolve/numeric

Lars282 — Wed, 01 Feb 2012 20:17:36 Z

Thanks for your reply.

So Maple's dsolve/numeric cannot solve a parametric bvp?