MaplePrimes - answers and comments on Question, jumble word permute

jumble

acer — Fri, 03 Feb 2012 11:54:52 Z

How's this?

It's no better than the quality of the dictionary being used. And there are some words missing from the builtin dictionary. One can, however, read in one's own set of words and assign it to the variable `words`, which the routine `findall` below accesses as a global variable.

restart:

with(StringTools):
with(PatternDictionary):

bid:= Create(`builtin`):
words:= [seq](Get(bid,i),i=1..Size(bid)-1):

unwith(PatternDictionary):
unwith(StringTools):

findall:=proc(input::string,char::string,lo::posint,hi::posint)
global words;
local i, all, pos, final;
uses StringTools;
   if length(char)<>1 then
      error "expecting single character for 2nd argument";
   end if;
   if hi>length(input) then
      error "expecting 4th argument to be posint at most the length of 1st argument";
   end if;
   all:=Explode(input);
   pos:=Search("r",input);
   if pos>0 then
      all := [all[1..pos-1][],all[pos+1..-1][]];
   end if;
   for i from lo to hi do
      final[i]:=seq(Anagrams(Implode([x[],char]),words),
                    x in {combinat:-choose(all,i-1)[]});
   end do;
   eval(final);
end proc:

findall("speak", "k", 2, 4);

              table([2 = (), 3 = "ask", 4 = ("peak", "sake")])

findall("collapsing", "p", 4, 9);

              table([4 = ("pica", "clap", "capo", "pang", "gasp", "pail", "pain", "pall",
                          "plan", "opal", "slap", "span", "snap", "soap", "clip", "ping",
                          "pong", "pill", "lisp", "slip", "pion", "snip", "spin", "ipso",
                          "poll", "plop", "slop"),
                     5 = ("panic", "clasp", "scalp", "plain", "piano", "spill", "spoil",
                          "polis"),
                     6 = ("gallop", "spinal", "poplin"),
                     7 = ("scallop", "sapling"),
                     8 = (),
                     9 = ()])

convert(%,list);

              ["pica", "clap", "capo", "pang", "gasp", "pail", "pain", "pall",

                "plan", "opal", "slap", "span", "snap", "soap", "clip", "ping",

                "pong", "pill", "lisp", "slip", "pion", "snip", "spin", "ipso",

                "poll", "plop", "slop", "panic", "clasp", "scalp", "plain",

                "piano", "spill", "spoil", "polis", "gallop", "spinal",

                "poplin", "scallop", "sapling"]

findall("iocmrelae", "r", 4, 9):

convert(%,list);

              ["race", "care", "acre", "cram", "real", "earl", "ream", "mare",

                "lair", "rail", "liar", "oral", "roam", "rice", "core", "leer",

                "reel", "mere", "mire", "rime", "lore", "role", "more", "roil",

                "clear", "cream", "carol", "coral", "macro", "realm", "moral",

                "molar", "relic", "crime", "micro", "moire", "morel", "cereal",

                "oracle", "morale", "miracle", "calorie"]

acer

mistake somewhere

Christopher2222 — Sun, 05 Feb 2012 02:51:46 Z

There is a mistake somewhere

findall("speak",s",5,5)

table([5 = ("speak", "passe")])

passe shouldn't be there, speak doesn't contain 2 s's

A great word database is sowpods.zip a scrabble dictionary of 267,751 words as compared to the builtin of 25,950 which hasn't changed since at least Maple 9.

sorry

acer — Sun, 05 Feb 2012 05:49:08 Z

@Christopher2222 Sorry, when turning the code into a procedure I inadvertantly left the Search to be hard-coded for the letter "r". The Search line ought to be,

    pos:=Search(char,input);

So the procedure would be,

restart:

with(StringTools):
with(PatternDictionary):

bid:= Create(`builtin`):
words:= [seq](Get(bid,i),i=1..Size(bid)-1):

unwith(PatternDictionary):
unwith(StringTools):

findall:=proc(input::string,char::string,lo::posint,hi::posint)
global words;
local i, all, pos, final;
uses StringTools;
   if length(char)<>1 then
      error "expecting single character for 2nd argument";
   end if;
   if hi>length(input) then
      error "expecting 4th argument to be posint at most the length of 1st argument";
   end if;
   all:=Explode(input);
   pos:=Search(char,input);
   if pos>0 then
      all := [all[1..pos-1][],all[pos+1..-1][]];
   end if;
   for i from lo to hi do
      final[i]:=seq(Anagrams(Implode([x[],char]),words),
                    x in {combinat:-choose(all,i-1)[]});
   end do;
   eval(final);
end proc:

findall("speak","s",5,5);

                                table([5 = "speak"])

findall("speak","s",3,5);

         table([3 = ("sea", "ask", "spa", "sap"), 4 = ("sake", "apse"), 5 = "speak"])

large database

Christopher2222 — Sun, 05 Feb 2012 06:30:39 Z

Thanks acer, works nicely now.

Now I mentioned a nice free word database sowpods.txt (found on sourceforge) which is only 2 Mb when unzipped but reading it into Maple causes Maple to use about 27Mb's. That's using the command readdata("g:/sowpods.txt",string,1).

Are there other ways to read in large databases while consuming less memory or I should say more efficiently?

Or I suppose what I mean is, and this is probably really a second question, is there a way (and how) using Maple to search the database without actually loading it into Maple to conserve memory?

fine tuning

Christopher2222 — Mon, 06 Feb 2012 04:48:23 Z

> findall("speak", "t", 4, 5);

TABLE([5 = ("stake", "steak", "skate", "paste", "spate", "septa"), 4 = (

"take", "tape", "peat", "pate", "seat", "east", "skat", "task", "spat",

"past", "kept", "pest", "sept", "step")])

trivially and explicitly we could add

if Search(char,input)=0 then
error "expecting 2nd argument to be part of 1st argument"
end if;

>findall("speak", "t", 4, 5);
Error, (in findall) expecting 2nd argument to be part of 1st argument

considered it (re: fine tuning)

acer — Mon, 06 Feb 2012 06:03:08 Z

@Christopher2222 I considered that case but figured that the original post was slightly ambiguous on the issue and (much more importantly) that if I has misinterpreted then it didn't matter since a pre-check would be so trivial that anyone could write it.