MaplePrimes - answers and comments on Question, sequence of matrices

rtable_eval

pagan — Wed, 08 Feb 2012 00:31:26 Z

rtables (ie. Vector, Array, Matrix) evaluate differently. Partly, this is so that they don't get evaluated as full copies when passed as arguments to procedures (thus allowing efficiency, and also allowing inplace operations).

restart:

formula:=Vector([3*i]);
                              formula := [3 i]


seq(formula,i=4..7);
                         [3 i], [3 i], [3 i], [3 i]


seq(rtable_eval(formula),i=4..7);
                           [12], [15], [18], [21]

And using the given example,

formula:=Vector(3, [3,y,11-4*y]);

                                       [   3    ]
                                       [        ]
                            formula := [   y    ]
                                       [        ]
                                       [11 - 4 y]


seq(formula,y=0..10);

  [   3    ]  [   3    ]  [   3    ]  [   3    ]  [   3    ]  [   3    ]  
  [        ]  [        ]  [        ]  [        ]  [        ]  [        ]  
  [   y    ], [   y    ], [   y    ], [   y    ], [   y    ], [   y    ], 
  [        ]  [        ]  [        ]  [        ]  [        ]  [        ]  
  [11 - 4 y]  [11 - 4 y]  [11 - 4 y]  [11 - 4 y]  [11 - 4 y]  [11 - 4 y]  

    [   3    ]  [   3    ]  [   3    ]  [   3    ]  [   3    ]
    [        ]  [        ]  [        ]  [        ]  [        ]
    [   y    ], [   y    ], [   y    ], [   y    ], [   y    ]
    [        ]  [        ]  [        ]  [        ]  [        ]
    [11 - 4 y]  [11 - 4 y]  [11 - 4 y]  [11 - 4 y]  [11 - 4 y]


seq(rtable_eval(formula),y=0..10);

     [ 3]  [3]  [3]  [ 3]  [ 3]  [ 3]  [  3]  [  3]  [  3]  [  3]  [  3]
     [  ]  [ ]  [ ]  [  ]  [  ]  [  ]  [   ]  [   ]  [   ]  [   ]  [   ]
     [ 0], [1], [2], [ 3], [ 4], [ 5], [  6], [  7], [  8], [  9], [ 10]
     [  ]  [ ]  [ ]  [  ]  [  ]  [  ]  [   ]  [   ]  [   ]  [   ]  [   ]
     [11]  [7]  [3]  [-1]  [-5]  [-9]  [-13]  [-17]  [-21]  [-25]  [-29]

You could also do it in a more usual manner by creating a procedure.

formula:=Vector(3, [3,y,11-4*y]):

func:=unapply(formula,:-y):
seq(func(y),y=0..10);

As function

Kamel Boughrara — Wed, 08 Feb 2012 01:05:54 Z

@Jarekkk

A:=y-><3, y, 11-4*y>: seq(A(y),y=0..10);

I see, thank you very much.

suitangi — Wed, 08 Feb 2012 01:08:32 Z

I see, thank you very much.

a comment

pagan — Fri, 10 Feb 2012 09:31:51 Z

@suitangi I'd like to add a comment

Even though evaluation of rtables is different from evaluation of lists and other expressions, when passed as arguments to procedures, access to individual rtable entries done inside procedures will still get a useful level of evaluation.

restart:
M:=Matrix([[s]]):

s:=77:

f:=proc(R) lprint(R); ToInert(R); end proc:

f(M); # f receives a M and not a fully evaluated copy of M

Matrix(1, 1, {(1, 1) = s}, datatype = anything, storage = rectangular, order = Fortran_order, shape = [])
_Inert_MATRIX(_Inert_RANGE(_Inert_INTPOS(1), _Inert_INTPOS(1)), 

  _Inert_RANGE(_Inert_INTPOS(1), _Inert_INTPOS(1)), _Inert_SET(_Inert_EXPSEQ(

  _Inert_EQUATION(_Inert_EXPSEQ(_Inert_INTPOS(1), _Inert_INTPOS(1)), 

  _Inert_ASSIGNEDNAME("s", "INTPOS")))), _Inert_EQUATION(

  _Inert_NAME("datatype"), _Inert_NAME("anything", _Inert_ATTRIBUTE(

  _Inert_NAME("protected", _Inert_ATTRIBUTE(_Inert_NAME("protected")))))), 

  _Inert_EQUATION(_Inert_NAME("storage"), _Inert_NAME("rectangular")), 

  _Inert_EQUATION(_Inert_ASSIGNEDNAME("order", "PROC", _Inert_ATTRIBUTE(

  _Inert_NAME("protected", _Inert_ATTRIBUTE(_Inert_NAME("protected"))))), 

  _Inert_NAME("Fortran_order")))

f:=proc(R) R[1,1]; end proc:

f(M); # access to entries of R get useful evaluation, nonetheless
                                     77


restart:
M:=[s]:  # a list!

s:=77:

f:=proc(R) dismantle(R); ToInert(R); end proc:

f(M); # 

LIST(2)
   EXPSEQ(2)
      INTPOS(2): 77


                _Inert_LIST(_Inert_EXPSEQ(_Inert_INTPOS(77)))

So accessing individual entries of Matrix R (Matrix M) inside the procedure f gets the assigned value of s.

It boils down to this question: how many entries of a Matrix will you want to access, inside f? If you want to access only a few, then it would be terrible for procedure performance if Maple had made the effort to fully evaluate all entries of Matrix argument R. Better to evaluate entries only on demand. The rtable_eval command provides finer grained control, in case this is not your scenario.