local variable

Joe Riel — Fri, 10 Feb 2012 06:37:22 Z

I didn't see the call to f in conscongs, but no matter. The error message that Maple is raising is informative:

final value in for loop must be numeric or character.

In f, the final value of the for loop is the variable numccs. That variable is local to conscongs, so its value will be unknown to f. Actually, in the context of f, numccs is a global variable (because it wasn't declared), one that is different from the variable of the same name that is local to conscongs. You could declare numcss as a global variable inside of conscongs, however, that usually isn't the best way to go.

some methods

pagan — Fri, 10 Feb 2012 08:54:48 Z

As Joe mentions, your implementation is not allowing f to see the value of numccs which was assigned inside conscongs (where it is declared as a local).

There are a number of different ways to deal with that. Here are four below, following a shortened version of the failed attempt. (I would prefer the first two workarounds over the last two.)

restart: # your failure
c:=proc() local numccs;
     numccs:=1;
     f();
   end proc:
f := proc() local i;
       for i from 1 to numccs do print(ok);
       end do;
     end proc:

c();
Error, (in f) final value in for loop must be numeric or character

restart: # passing value
f := proc(num) local i;
       for i from 1 to num do print(ok);
       end do;
     end proc:
c:=proc() local numccs;
     numccs:=1;
     f(numccs);
   end proc:

c();
                               ok

restart: # module local
m:=module() export c, f; local numccs;
   c:=proc() numccs:=1; f(); end proc:
   f := proc() local i;
          for i from 1 to eval(numccs) do print(ok);
          end do;
        end proc:
end module:

m:-c();
                               ok

restart: # lexical scoping
c:=proc() local numccs, f;
     f := proc() local i;
            for i from 1 to eval(numccs) do print(ok);
            end do;
         end proc:
     numccs:=1;
     f();
   end proc:

c();
                               ok

restart: # global
f := proc() global numccs; local i;
       for i from 1 to numccs do print(ok);
       end do;
     end proc:
c:=proc() global numccs;
     numccs:=1;
     f();
   end proc:

c();
                               ok

MaplePrimes - answers and comments on Question, Stuck! I can't get a numeric value from my table.

local variable

some methods