A solution using coeffs (and zip, select, and map2)

Doug Meade — Sun, 04 Nov 2012 07:11:35 Z

Satya,

This was fun. The key to my approach is the coeffs command. Not only does it return all coefficients of a multinomial polynomial but it can also return the term for each coefficient. I zip the two lists together and then select all pairs whose first term (coefficient) matches the given value. My final implementation is presented in the following procedure - with two test cases.

restart;

Terms := proc( f, vars, coef )
  local c, t, T;
  c := coeffs( f, vars, 't' );
  T := zip( (x,y)->[x,y], [c], [t] );
  return map2( op, 2, select( C->evalb( C[1]=coef ), T ) );
end proc:

f := 3*x^3 + 5*x^4 + 5*x^44;
                         3      4      44
                      3 x  + 5 x  + 5 x  
Terms( f, x, 5 );
                           [ 4   44]
                           [x , x  ]
Terms( f, x, 4 );
                               []
Terms( f, x, 3 );
                              [ 3]
                              [x ]

f2 := 3*x^3*y + 4*x^2 + 5*y^33;
                        3        2      33
                     3 x  y + 4 x  + 5 y  
Terms( f2, [x,y], 5 );
                             [ 33]
                             [y  ]
Terms( f2, [x,y], 4 );
                              [ 2]
                              [x ]
Terms( f2, [x,y], 3 );
                             [ 3  ]
                             [x  y]

Does this do what you request?

I hope this is helpful. I encourage you to consult the Maple help documents for coeffs, zip, select, and map2 (in particular) if you need help understanding what each command does.

Doug

---------------------------------------------------------------------
Douglas B. Meade  <><
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu

Thank you Doug for the timely help

satya123999 — Sun, 04 Nov 2012 15:04:53 Z

This will help me.

MaplePrimes - answers and comments on Question, How do I extract the corresponding variables given the list of coefficients ?

A solution using coeffs (and zip, select, and map2)

Thank you Doug for the timely help