MaplePrimes - answers and comments on Question, is there a member() function for Vectors ?

Lookup table

Joe Riel — Wed, 14 Nov 2012 21:29:37 Z

You might try creating a table that does reverse-lookup.

BasisIndex := table([seq(basis[i] = i, i=1..upperbound(basis,1))]):

Then, to get the index of Vector v, do BasisIndex[v]. Because v may not be in the basis, you might do

if assigned(BasisIndex[v]) then
   indx := BasisIndex[v];
else
   whatever is appropriate
end if;

Another way

Markiyan Hirnyk — Wed, 14 Nov 2012 22:10:18 Z

Download ind.mw

binary search

Joe Riel — Thu, 15 Nov 2012 06:45:23 Z

Here's the idea I suggested. It uses ?ListTools[BinarySearch] to quickly search a list of "basis" vectors (here a random collection of Vectors). The basis is sorted using the same procedure (lessthan) used in the binary search.

lessthan := proc(v,w)
local i,n;
    n := upperbound(v,1);
    for i to n while v[i] = w[i] do end do;
    i<=n and v[i] < w[i];
end proc:

equal := proc(v,w)
local i,n;
    n := upperbound(v,1);
    for i to n while v[i] = w[i] do end do;
    evalb(i>n);
end proc:
     
# Generate a list of 50 random vectors with dimension 5       
L := [seq(rtable(1..5, random(1..10)), i=1..50)]:
# Use lessthan to sort the Vectors
B := sort(L,lessthan);

# Choose a member from B, and find it in B
ListTools:-BinarySearch(B, B[34], lessthan, equal);
                              34

Not 100% working

luigidavinci — Wed, 14 Nov 2012 22:35:47 Z

Thanks Joe, that was a neat solution, just what I needed. Unfortunately, it does not seem to work if I am querying the BasisIndex table with a separetly created vector which is element-wise identical to one vector in the basis structure. Like in this example:

basis:=Vector(1..4):

basis[1]:=Vector([4,0,0,0]): basis[2]:=Vector([3,2,0,0]): basis[3]:=Vector([2,0,0,2]): basis[4]:=Vector([1,1,2,0]):

BasisIndex := table([seq(basis[i] = i, i=1..upperbound(basis,1))]):

v:=basis[1]: v2:=Vector([4,0,0,0]):

if assigned(BasisIndex[v]) then BasisIndex[v]; else print("Not assigned"): end if;
1
if assigned(BasisIndex[v2]) then BasisIndex[v2]; else print("Not assigned"): end if;
"Not assigned"

If I do is(v=v2), I get a false, so I am not surprised that it is not working but, why does this happen? I have created both vectors in the same exact way so they should be identical, shouldn't they ?

Cheers.

mea culpa

Joe Riel — Wed, 14 Nov 2012 23:34:09 Z

@luigidavinci I feared this might be an issue and should have mentioned it originally. Maple Vectors are mutable data structures; as such, two Maple Vectors can have identical content but have different addresses. That is not the case for, say, lists. As such, one cannot generally use a table to lookup a Vector, as I suggested, because the indexing is done on the address of the index, not on its content.

A method I suggested below is to sort the collection of Vectors by norm, then use that to restrict a search to a subset. That assumes the Vectors have different norms. Another possibility, probably faster, is to sort the Vectors lexicographically, using the slots of the Vectors.

Difference

Markiyan Hirnyk — Thu, 15 Nov 2012 00:10:12 Z

@Joe Riel As far as I understand it, the usage of the LinearAlgebra:-Norm command for indexing does not require all norms to be different.

PS.

> sort(basis, lexorder);
Error, invalid input: a string/name Vector is expected for sort method `lexorder`