MaplePrimes - answers and comments on Question, Maximizing a derivative in Maple

Numerical approach

Preben Alsholm — Fri, 16 Nov 2012 05:38:21 Z

You must use a numerical approach. One that seems to work OK here is infnorm from the numapprox package.

infnorm finds the maximum of the absolute value, so you have to take care of that problem:

restart;
u:=diff(ln(cosh(t)),t$15);
Digits:=20:
M:=numapprox:-infnorm(u,t=0..50,'tm');
tm;
eval(u,t=%);
#The infnorm was attained at a value of t for which u is negative. Therefore the next step:
numapprox:-infnorm(u+M,t=0..50,'tm')-M;
tm;

exact?

acer — Fri, 16 Nov 2012 12:15:37 Z

It looks doubtful that an exact result is forthcoming. But (effectively) you can compute an arbitrary number digits of an approximate floating-point solution.

restart:

r:=arccosh(RootOf(8*_Z^7-65532*_Z^6+7108920*_Z^5-123513390*_Z^4
                  +697296600*_Z^3-1645944300*_Z^2+1702701000*_Z
                  -638512875, index = 2)^(1/2)):

evalf[20](r);

                           0.47649585654800266209

u:=diff(ln(cosh(t)),t$15):

evalf[100]( eval(u,t=r) ): # for better accuracy

evalf[10](%); # and displayed shorter

                                             7
                               9.858206439 10 

Optimization:-Maximize( u, t=0..50, method=branchandbound,
                        evaluationlimit=1000 );

               [                   7                         ]
               [9.85820643880540 10 , [t = 0.476495856343965]]

acer

polynomial

Axel Vogt — Fri, 16 Nov 2012 19:10:41 Z

'diff(ln(cosh(t)),t$15)'; 
`` = convert(%, tanh);

subs(tanh(t)=x, %): factor(%): sort(%); 
P:=unapply(rhs(%),x);
plot(P(x), x=-1 .. 1);

Now find the maximum in x = tanh(t), which means to find D(P)(x)=0
and then test for the second derivative.

I get x0 = -RootOf(-929569+50307087*_Z-507350025*_Z^2+2087700615*_Z^3-
4339860525*_Z^4+4838508675*_Z^5-2766889125*_Z^6+638512875*_Z^7,index = 1)^(1/2)

and the maximum as ~ 184543792.966350, x0 ~ -0.15, t0 ~ -.153487305042586.

The derivative of P is irreducible (in terms of x^2), so the root will not be
in more simple form without a good idea.