MaplePrimes - answers and comments on Question, Can I make variables appear in DSolve numeric output

Parameters option

Preben Alsholm — Sun, 18 Nov 2012 20:24:32 Z

Will this do what you want:

dsol := dsolve({eq1, eq2, x(0) = 0, y(0) = 0, D(x)(0) = Vx,D(y)(0) = Vy}, numeric, output = listprocedure,parameters=[Vx,Vy]);
X,Y:=op(subs(dsol,[x(t),y(t)]));
Xp:=proc(t,V,theta)
if not type([t,V,theta],list(realcons)) then return 'procname(_passed)' end if;
dsol(parameters=[V*cos(theta),V*sin(theta)]);
X(t)
end proc;
#And similarly you can define Yp if desired.

constants et al

brian bovril — Wed, 21 Nov 2012 18:25:30 Z

That solves it!

The enclosed worksheet is my interpretation of the physical problem. DROPvLEAP.mw

I'm not sure how you got k=Pi*27/1625/2. I stuffed up one of my parameters in the original dt, but i have corrected it so now your dt is closer to my dt.

Direct Seach with parameters

brian bovril — Mon, 19 Nov 2012 18:09:36 Z

numeric_de_code3.mw

Thankyou Sir, for the code. it answers my initial Q.

But now I have another problem. I'm trying to optimize V and theta ST constraints (eq=0, horizontal distance travelled>=60) using Direct Search and i've had difficulties. (after output 26).

implicitplot

Preben Alsholm — Mon, 19 Nov 2012 22:15:12 Z

@brian bovril

I don't know where the expression dt came from, nevertheless I tried the following.

restart;
eq1 := diff(y(t), t, t) = -49/5-0.1350000000e-2*Pi*sqrt((diff(x(t), t))^2+(diff(y(t), t))^2)*diff(y(t), t);
eq2 := diff(x(t), t, t) = -0.1350000000e-2*Pi*sqrt((diff(x(t), t))^2+(diff(y(t), t))^2)*diff(x(t), t);
dsol := dsolve({eq1, eq2, x(0) = 0, y(0) = 0, D(x)(0) = V*cos(theta),D(y)(0) = V*sin(theta)}, numeric, output = listprocedure,parameters=[V,theta]);
#The version above didn't work in Maple 12, which I used for my original answer, but it works in Maple 16.
X,Y:=op(subs(dsol,[x(t),y(t)]));
dt := -(25/126)*ln(-(-2+exp(-(324/1625)*Pi+(27/1625)*Pi*yp)+2*sqrt(1-exp(-(324/1625)*Pi+(27/1625)*Pi*yp)))/exp(-(324/1625)*Pi+(27/1625)*Pi*yp))*sqrt(78)/sqrt(Pi);
x0 := 45:
EQ:=proc(V,theta) local tp,drpt;
   if not type([V,theta],list(realcons)) then return 'procname(_passed)' end if;
   dsol(parameters=[V,theta]);
   tp:=fsolve(X(t) = x0, t);
   if not type(tp,numeric) then return undefined end if;
   drpt := evalf(eval(dt,yp = Y(tp)));
   tp-drpt
end proc:
EQ(25,1.3);
plots:-implicitplot(EQ(V,theta),V=0..50,theta=0..Pi/2);
th:=fsolve(EQ(40,theta)=0,theta=0.2..0.3);
dsol(parameters=[40,th]):
plots:-odeplot(dsol,[x(t),y(t)],t=0..2);

parameters in de

brian bovril — Tue, 20 Nov 2012 18:09:11 Z

thanks for that.

it seems you supply a value for V (in this case 40) and it calculates theta. i really wanted the optimal V and theta but thats alright. explaining myself is not easy.

dt is dropping time for a coconut. its based on this problem but factoring in air resistance for monkey and coconut.

http://www.maplesoft.com/support/help/Maple/view.aspx?path=MathApps/TheMonkeyAndTheCoconut

as you can see you can modify the angle and the speed. and if its not fast enough she'll fall in the river!

If I were the monkey, I would just climb the tree and get it, that’s what monkeys are good at! My monkey is highly athletic, jumping 60 m!!! . and it travels at 150km/hr! Anyway to do otherwise would spoil the maths.

Worksheet

Preben Alsholm — Tue, 20 Nov 2012 22:38:52 Z

@brian bovril Thanks for the reference. I have uploaded a worksheet. It doesn't use the parameters option in dsolve/numeric, since I seem to be getting inconsistent results using that option in this problem. At this point I don't understand why results are inconsistent.

'implicitplot' takes much longer, but plotting is just used for guidance.

MonkeyAndCoconut.mw

Addendum:

The inconsistency results in the parameters version apparently is due to fsolve remembering results.

Below the problem is shown (in p1) together with two solutions to the problem (p2 and p3).

But first the simple problem is solved analytically.

In p2 X is a local variable, in p3 X is global, but the statement forget(fsolve); is inserted before fsolve gets to work.

The parameters version will work fine also for the the original problem e.g. by inserting the statement forget(fsolve); as below in p3.

restart;
eq := diff(x(t), t) = a*x(t);
dsolve({eq, x(0) = 1});
solve(rhs(%)=2,t);
#############################################
restart;
eq := diff(x(t), t) = a*x(t);
dsol := dsolve({eq, x(0) = 1}, numeric, output = listprocedure,parameters=[a]);
X:=subs(dsol,x(t));
p1:=proc(a) local tp;
   if not type(a,realcons) then return 'procname(_passed)' end if;
   dsol(parameters=[a]);
   tp:=fsolve(X(t) = 2, t);
   if not type(tp,numeric) then undefined else tp end if
end proc:
plot(p1(a),a=0..50);
p1(10);
p1(200);
#############################################
restart;
eq := diff(x(t), t) = a*x(t);
dsol := dsolve({eq, x(0) = 1}, numeric, output = listprocedure,parameters=[a]);
p2:=proc(a) local tp,X;
   if not type(a,realcons) then return 'procname(_passed)' end if;
   dsol(parameters=[a]);
   X:=subs(dsol,x(t));
   tp:=fsolve(X(t) = 2, t);
   if not type(tp,numeric) then undefined else tp end if
end proc:
plot(p2(a),a=0..50);
p2(10);
p2(200);
restart;
eq := diff(x(t), t) = a*x(t);
dsol := dsolve({eq, x(0) = 1}, numeric, output = listprocedure,parameters=[a]);
X:=subs(dsol,x(t));
p3:=proc(a) local tp;
   if not type(a,realcons) then return 'procname(_passed)' end if;
   dsol(parameters=[a]);
   forget(fsolve);
   tp:=fsolve(X(t) = 2, t);
   if not type(tp,numeric) then undefined else tp end if
end proc:
plot(p3(a),a=0..50);
p3(10);
p3(200);