MaplePrimes - answers and comments on Question, How many divisors

Brute force search won't work

Carl Love — Sun, 02 Dec 2012 03:45:36 Z

So, from your code, I'm guessing that for each integer i from 1 to 100, you want to find the smallest n such that tau(n) = i. In other words, you want a partial inverse of the tau function. (Note to other readers: tau(n) is the number of positive integer divisors of n.) But your method won't work because for i = 97, n will have 29 decimal digits, and the whole age of the universe wouldn't be enough time to get to that number if you work by counting up from 1. I don't want to say what that 29-digit number is, because it would give too much of a hint.

Hint: You are correct that the prime factorization of n is the key to computing tau(n). Indeed, the primes themselves don't matter; it can be computed just from the exponents in the factorization. Take a look at showstat(numtheory:-tau). It's a very short procedure; only the last actual line of code matters here; the other lines are just there to quickly handle the trivial cases. Once you know what you want the exponents to be, just pick the prime bases that minimize the product.

Solution

Kitonum — Thu, 06 Dec 2012 23:06:00 Z

The next procedure solves the problem:

Divs:=proc(n)

local L, M, Div, k, i, K, j, T, P;

uses numtheory;

if n=1 then return [1,1] else

L[1]:=[[n]];

M:=[];

Div:=divisors(n) minus {1, n};

for k in Div while n/k>=k do

M:=[op(M), [n/k, k]];

od;

L[2]:=M;

for i from 3 to bigomega(n) do

K:=[];

for j from 1 to nops(L[i-1]) do

Div:=divisors(L[i-1][j,1]) minus {1, L[i-1][j,1]};

for k in Div while L[i-1][j,1]/k>=k and k>=L[i-1][j,2] do

K:=[op(K),[L[i-1][j, 1]/k, k, op(L[i-1][j][2..nops(L[i-1][j])])]];

od; od;

L[i]:=K;

od;

L:=[seq(L[i], i=1..bigomega(n))];

M:=[]; T:=[seq(ithprime(k), k=1..bigomega(n))];

for i from 1 to nops(L) do

P[i]:=[seq(T[k], k=1..i)];

for j from 1 to nops(L[i]) do

M:=[op(M), mul(P[i][t]^(L[i][j,t]-1), t=1..nops(P[i]))];

od: od:

[n, min(M)]; fi;

end proc:

Example:

[seq(Divs(n), n=1..100)];

Another solution

Carl Love — Fri, 07 Dec 2012 00:02:36 Z

Here's my solution:

> restart;
    invtau:= proc(n::posint)
   # Inverse tau: Returns the smallest positive integer r such
   # tau(r) = n, where tau(r) is the number of positive integer
   # divisors of r (see ?numtheory,tau).
   local pair, r:= 1, r_prime:= 1, exponent;
     for pair in ListTools:-Reverse(sort(ifactors(n)[2])) do
         exponent:= pair[1] - 1;
           to pair[2] do
       r_prime:= nextprime(r_prime);
               r:= r*r_prime^exponent
           od
       od;
       r
end proc:

> st:= time():
> [seq]([n,invtau(n)], n= 1..100);

[[1, 1], [2, 2], [3, 4], [4, 6], [5, 16], [6, 12], [7, 64], [8, 30], [9, 36], [10, 48], [11, 1024], [12, 60], [13, 4096], [14, 192], [15, 144], [16, 210], [17, 65536], [18, 180], [19, 262144], [20, 240], [21, 576], [22, 3072], [23, 4194304], [24, 420], [25, 1296], [26, 12288], [27, 900], [28, 960], [29, 268435456], [30, 720], [31, 1073741824], [32, 2310], [33, 9216], [34, 196608], [35, 5184], [36, 1260], [37, 68719476736], [38, 786432], [39, 36864], [40, 1680], [41, 1099511627776], [42, 2880], [43, 4398046511104], [44, 15360], [45, 3600], [46, 12582912], [47, 70368744177664], [48, 4620], [49, 46656], [50, 6480], [51, 589824], [52, 61440],
[53, 4503599627370496], [54, 6300], [55, 82944], [56, 6720], [57, 2359296], [58, 805306368], [59, 288230376151711744], [60, 5040], [61, 1152921504606846976], [62, 3221225472], [63, 14400], [64, 30030], [65, 331776], [66, 46080], [67, 73786976294838206464], [68, 983040], [69, 37748736], [70, 25920], [71, 1180591620717411303424], [72, 13860], [73, 4722366482869645213696], [74, 206158430208], [75, 32400], [76, 3932160], [77, 746496], [78, 184320], [79, 302231454903657293676544], [80, 18480], [81, 44100], [82, 3298534883328], [83, 4835703278458516698824704], [84, 20160], [85, 5308416], [86, 13194139533312], [87, 2415919104], [88, 107520], [89, 309485009821345068724781056], [90, 25200], [91, 2985984], [92, 62914560], [93, 9663676416], [94, 211106232532992], [95, 21233664], [96, 60060], [97, 79228162514264337593543950336], [98, 233280], [99, 230400], [100, 45360]]

> time()-st;
0.031

mul(x[2]+1,x = ifactors(n)[2])

Eryndis — Sun, 02 Dec 2012 16:27:44 Z

So, I have work with mul(x[2]+1,x = ifactors(n)[2]). I tried a lot, but it still doesn't want to do, what I want. Can you give me a little bit more help, please? Thanks in advance

What exactly do you want?

Carl Love — Sun, 02 Dec 2012 20:22:35 Z

@Eryndis Well, tell me what exactly you want. Was I correct in guessing that for each i you want the smallest positive n such that tau(n) = i (a partial inverse of tau)? Would any positive n, not necessarily the smallest, such that tau(n) = i be good enough?

My hint about that line of code was not that you would use it in a program, but that you would use it to understand how tau is computed. Once you know how tau is computed, it should be relatively easy to figure out how to write code for a partial inverse that runs in a short amount of time.

Hint 2: For a bunch of different numbers n, look at ifactors(n) and ifactors(tau(n)). What is the pattern?

Here is a related, but simpler, exercise: What are necessary and sufficient conditions for tau(n) to be odd? This one is a standard in mathematical puzzle collections for the general public, although it is always stated in more fanciful form referring to a long hallway of numbered locker doors or pull-chain lights. See http://www.algebra.com/algebra/homework/word/misc/Miscellaneous_Word_Problems.faq.question.51262.html

The smallest

Eryndis — Mon, 03 Dec 2012 01:46:07 Z

@Carl Love
I need the smallest.