MaplePrimes - answers and comments on Question, error in solving two coupled ode equations

Parameter option for initial value problem

Preben Alsholm — Wed, 05 Dec 2012 20:57:03 Z

It is sometimes easier to solve this by turning it into an initial value problem and by using the parameters option in dsolve. I have often suggested this for systems looking very similar to the one you have.
But here it is:

sol:=dsolve({ode1,ode2,D(f)(0) = 0, f(0) = 0, (D@D)(f)(0) = f2, g(0) = 1, D(g)(0) = g1},
numeric,parameters=[g1,f2],output=listprocedure);
F1,G:=op(subs(sol,[diff(f(x),x),g(x)]));
p1:=proc(g1,f2) sol(parameters=[g1,f2]); F1(6) end proc;
p2:=proc(g1,f2) sol(parameters=[g1,f2]); G(6) end proc;
p1(0.4,1);
p2(0.4,1);
fsolve([p1,p2],[0.4,1]);
sol(parameters=%);
plots:-odeplot(sol, [[x,diff(f(x),x)],[x, g(x)]], 0 .. 6, color = [blue,black]);
#Check:
F1(6);
G(6);
#And now that we have a solution we could use that as an 'approximate sloution':
dsn := dsolve(sys, numeric,approxsoln=sol);
plots:-odeplot(dsn, [[x,diff(f(x),x)],[x, g(x)]], 0 .. 6, color = [blue,black]);

Try option 'continuation' for BVPs with Newton convergence issues

Carl Love — Thu, 06 Dec 2012 03:39:59 Z

There is a way to solve this without resorting to commands outside of dsolve. The help page ?dsolve,numeric_bvp,advanced gives advice on how to apply dsolve's options to resolve some error messages given by `dsolve/numeric/bvp`. For messages related to Newton iteration convergence, it suggests the 'continuation' option, which is defined on help page ?dsolve,numeric,bvp (with two examples of its use given on the former help page).

To use the method, one introduces a parameter λ into the problem such that λ can vary continuously from 0 to 1, with λ=0 yielding a relatively easier BVP and λ=1 giving the desired BVP. The parameter can appear anywhere in the problem: in the ODEs, or the boundary conditions, or both. There is some subtlety required in deciding where and how to place λ. I tried this two ways with the problem at hand, and they both worked.

My first idea was to have λ=0 eliminate the convolution of f(x) and g(x), so I applied it to the g(x) term in the first ODE and to the term containing f(x) in the second ODE.

restart;
ode1:= ( (D@@3)(f) + 3*f*(D@@2)(f) - 2*D(f)^2 ) (x) + lambda*g(x) = 0;
ode2:= (D@@2)(g)(x) + lambda*3*10*(f*D(g))(x) = 0;
bcs1:= D(f)(0) = 0, f(0) = 0, D(f)(6) = 0;
bcs2:= g(0) = 1, g(6) = 0;
sys:= {bcs1, bcs2, ode1, ode2}:
dsn:= dsolve(sys, numeric, continuation= lambda);
plots:-odeplot(dsn, [x, g(x)], 0 .. 6, color= black);

I recommend plotting the interval 5.7 .. 6 separately because there is an interesting fluctuation there which is not visible at the g-axis scale of the overall plot.

My second idea was to use λ=0 to "level" the boundary conditions so that everything starts and ends at 0 on the vertical axis. In this case, that simply means changing g(0)=1 to g(0)=λ.

restart;
ode1:= ( (D@@3)(f) + 3*f*(D@@2)(f) - 2*D(f)^2 + g ) (x) = 0;
ode2:= ( (D@@2)(g) + 3*10*f*D(g) ) (x) = 0;
bcs1:= D(f)(0) = 0, f(0) = 0, D(f)(6) = 0;
bcs2:= g(0) = lambda, g(6) = 0;
sys:= {bcs1, bcs2, ode1, ode2}:
dsn:= dsolve(sys, numeric, continuation= lambda);
plots:-odeplot(dsn, [x, g(x)], 0 .. 6, color = black);

Same plot, of course.

correction in problem @ Vanta5

Noreen cute — Thu, 06 Dec 2012 12:30:25 Z

Dear @vanta5,

i suggest the mention boundry condtions are not well posed, because f'(0)=1

and u should adjust the code in this formet

b := 1;
ode1 := diff(f(x), x, x, x)+3*f(x)*(diff(f(x), x, x))-2*(diff(f(x), x))^2+g(x) = 0;
ode2 := diff(g(x), x, x)+(3*10)*f(x)*(diff(g(x), x)) = 0;
bcs1 := (D(f))(0) = 1, f(0) = 0, (D(f))(b) = 0;
bcs2 := g(0) = 1, g(b) = 0;
sys := {bcs1, bcs2, ode1, ode2};
dsn := dsolve(sys, numeric);
print(plots:-odeplot(dsn, [x, diff(f(x), x)], 0 .. b, color = black))
print(plots:-odeplot(dsn, [x, g(x)], 0 .. b, color = black))

thank you

vanta — Thu, 06 Dec 2012 22:35:48 Z

thank you all dear friends your comments were very helpfull i appreciate that.

@Preben Alsholm

@Markiyan Hirnyk

@Carl Love

@Noreen cute

thank you all again

References

Markiyan Hirnyk — Wed, 05 Dec 2012 21:30:19 Z

PS. And to http://www.mapleprimes.com/questions/136745-How-To-Calculate-Dual-Solution-Problem#comment136767 , where further references are.

Quite so!

Preben Alsholm — Wed, 05 Dec 2012 21:38:02 Z

@Markiyan Hirnyk Quite so, thanks.