MaplePrimes - answers and comments on Question, The catcher in the rye

Completely in Maple

Carl Love — Sun, 09 Dec 2012 06:39:19 Z

restart;
`convert/range`:= proc(ineqs::{set,list})
# Convert a pair of simple inequalities to form x= a..b.
local ab:= indets(ineqs, numeric);
indets(ineqs, name)[]= min(ab)..max(ab)
end proc:
n:= 1..3:
s1:= (x-1)*(y-x):
s2:= (7-y)*(1-x):
s3:= (x-y)*(y-7):
feas:= [solve](({s||n} >=~ 0) union {-2<=x,x<=3, 0<=y,y<=11}, {x,y});

[{y = x, 0 <= x, x <= 1}, {y = 7, 1 <= x, x <= 3},
{x = 1, 1 <= y, y <= 7}]

z:= add(sqrt(s||i), i= n):
m:= 1..nops(feas):
zr||m:= seq(eval(z, indets(feas[i], `=`)), i= m):
seq(maximize(zr||i, convert(indets(feas[i], `<=`), range)), i= m);

(1/2) (1/2) (1/2)
7 , 8 , 9

So the answer is sqrt(9), or 3.

3, and x=1, y=4

acer — Sun, 09 Dec 2012 06:48:36 Z

I found it tough to get Maple to look at y=7, x=1..3 as one of the canditate ranges for which the objective is purely real. I was trying to code it in such a way as to give Maple as little help and prodding as I could.

One thing that made this tougher than it ought to be is that I wasn't sure how hard I should try and get Maple to go from something like, {x>=1,x<=3} to x=1..3. (See the member of newS in the attached worksheet, which correspondes to this.) This aspect makes a difference because, Optimization:-Maximize seems to go awry when this restriction is passed as a pair of constraints, but succeeds when it is passed as simple bounds. See end of attached worksheet.

restart:

>	interface(warnlevel=0):

>	obj:=sqrt((x-1)(y-x))+sqrt((7-y)(1-x))+sqrt((x-y)*(y-7));

>	plot3d([Re,Im](obj), x=-2..3, y=0..11, color=[red,blue], axes=box);

>	S:=[solve(evalc(Im(obj)))]: # takes a little while

>	newS:={seq(solve(s union {x>=-2,x<=3,y>=0,y<=11}),s in S)};

>	for s in newS do try seql,sineq:=selectremove(type,s,`=`); ans:=Optimization:-Maximize(eval(obj,seql), sineq, initialpoint=[x=1/2,y=1/2]); print(ans[1],[ans[2][],seql[]]); catch: end try: end do;

>	for s in newS do try seql,sineq:=selectremove(type,s,`=`); ans:=Optimization:-Maximize(eval(obj,seql), sineq, initialpoint=[x=1,y=5]); print(ans[1],[ans[2][],seql[]]); catch: end try: end do;

>	#plots:-display(Array([ # plot([Re,Im](eval(obj,x=1)),y=0..11,view=0..5), # plot([Re,Im](eval(obj,y=7)),x=-2..3,view=0..5), # method above missed this one # plot([Re,Im](eval(obj,x=y)),y=0..1,view=0..5) ]));

Download toughopt1.mw

For some reason maplenet is not inlining the resst of the sheet. See the link for a bit more.

acer

My answer

Markiyan Hirnyk — Sun, 09 Dec 2012 09:05:48 Z

Making use of the idea by Axel Vogt and the answer by Sergey Moiseev in http://www.mapleprimes.com/questions/138835-Where-Do-You-Think-Youre-Going#comment138836 , I obtain

Download penalty.mw

with Optimization:-Maximize

PatrickT — Sun, 09 Dec 2012 22:56:22 Z

My contribution here is to give the perspective of an average user (student?) confronted with the problem. It appears to be very difficult to get the solution with Optimization:-Maximize, even tweaking the options, unless you pretty much know where the solution is, and even then ...

Here are some steps that take you to the right place, but the journey is fraught with peril.

It's natural to guess that the solution might be on the 1..7 range, from there trial and error... it takes a few steps and some good intuition...

Note the erroneous solution: [2.23606797749978981, [x = 1., y = 2.]]

restart;
f := sqrt((x-1)*(y-x))+sqrt((7-y)*(1-x))+sqrt((x-y)*(y-7)):

Optimization:-Maximize(f
, x = 1 .. 7
, y = 1 .. 7
, 'initialpoint' = [x=1,y=2]
) ;

Warning, undefined value encountered
Error, (in Optimization:-NLPSolve) number expected for float[8] parameter, got HFloat(HFloat(undefined))+HFloat(HFloat(undefined))*I

Optimization:-Maximize(f
, x = 2 .. 7
, y = 2 .. 7
, 'initialpoint' = [x=1,y=2]
) ;

Error, (in Optimization:-NLPSolve) complex value encountered

Optimization:-Maximize(f
, x = 1 .. 7
, y = 2 .. 7
, 'initialpoint' = [x=1,y=2]
) ;

Warning, no iterations performed as initial point satisfies first-order conditions
[2.23606797749978981, [x = 1., y = 2.]]

Optimization:-Maximize( subs(y=2,f)
, x = 1 .. 7
, y = 2 .. 7
, 'initialpoint' = [x=1,y=2]
) ;

Warning, no iterations performed as initial point satisfies first-order conditions
[2.23606797749978981, [x = 1., y = 2.]]

Optimization:-Maximize( subs(x=1,f)
, x = 1 .. 7
, y = 2 .. 7
, 'initialpoint' = [x=1,y=2]
) ;

[3., [x = 1., y = 4.]]

There's no way you could be confident to have found the max after all this.

But, as Axel pointed out, the plots do help.

Without penaltymethod

Markiyan Hirnyk — Sun, 09 Dec 2012 09:57:42 Z

This works.

Im(objective)=0 as constraint(s)

acer — Mon, 10 Dec 2012 00:09:19 Z

I did not really need to use plots, in my approach using Optimization:-Maximize. If you read Carl's, Markiyan's, and my answers you can see similarities in the approaches. I'f I'm not mistaken, we all relied on using Im(objective)=0 as extra known information (eg. as constraint, or constraints plural). Carl used exact `maximize`, Markiyan used the add-on DirectSearch package, and I used the Optimization package.

The feasible set ends up being (the union of) three disjoint line segments, and the answer is the largest of the maximum for each. Not all the approaches listed had to examine those separately, or even explicitly.

Feasible sets which have measure zero (in the domain to be searched) can be hard for optimizers.

Carl got nice exact results. It might seem that his code relies of inspection of the objective, and manual extraction of the three extra conditions. But it should be simple to automate that, so I do not consider it a flaw. Note the helper proc that he wrote, though. Markiyan's answer (improving on what he might have reported as tried in his original Question) is very simple and straightforward. My approach worked harder and was most complicated, generating a set of "simple" extra constraints so as to get multiple calls to local `Maximize` over the finite collection of candidate regions. (There is obviously stuff for Optimization to learn from DirectSearch's way of handling such domains, and I accomodated an inequality->range conversion to get coverage of all the feasible domain.)

acer