MaplePrimes - answers and comments on Question, collect and sqrt

collect by rule

Alejandro Jakubi — Thu, 13 Dec 2012 07:17:12 Z

Using a transformation rule may be the easier way like:

r:=A::algebraic*sqrt(a::algebraic)+B::algebraic*sqrt(a::algebraic)=(A+B)*sqrt(a):
ex:=(-14+9*(2-2*cos(mux))^(1/2))*cos(mu*x)+62+27*(2-2*cos(mux))^(1/2):
applyrule(r,expand(ex));
                                              1/2
           (27 + 9 cos(mu x)) (2 - 2 cos(mux))    + 62 - 14 cos(mu x)

And as an alternative to having in store a factorization rule specific to sqrt expressions, you may just keep a procedure generating factorization rules for diverse expressions:

fac:=proc(p)
A::identical(p)*B::algebraic+A::identical(p)*C::algebraic=A*(B+C):
end proc:

applyrule(fac((2-2*cos(mux))^(1/2)),expand(ex));
                                              1/2
           (27 + 9 cos(mu x)) (2 - 2 cos(mux))    + 62 - 14 cos(mu x)

Note that I dislike retyping input from an image. Just use the preformatted mode.

frontend or freeze and thaw

Preben Alsholm — Thu, 13 Dec 2012 17:46:12 Z

ex:=(-14+9*(2-2*cos(mux))^(1/2))*cos(mu*x)+62+27*(2-2*cos(mux))^(1/2);
(Thanks to Alejandro for typing).
s:=op(indets(ex,`^`(anything,1/2)));
subs(s=freeze(s),ex);
collect(%,freeze(s));
thaw(%);
#Or use frontend:
frontend(collect,[ex,s], [{`+`,`*`},{}]);

Shorter frontend command

Carl Love — Thu, 13 Dec 2012 20:11:08 Z

Preben's example of frontend uses the default value of the third parameter, [{`+`,`*`}, {}], so one could just use the user-friendlier-looking frontend(collect, [ex,s]).

I often forget about this powerful command simply because the name is so vague. IgnoreIndets would be a better name, as it seems closely related to subsindets and evalindets.

Thanks all

Mac Dude — Thu, 13 Dec 2012 23:39:10 Z

Thanks to all for your good suggestions, which will solve probems of this nature. Maple is a complex beast & I still have a lot to learn.

Alejandro's suggestion of a distributive rule reminds me that my problem is structurally similar to one I had some time ago, involving sums, which was solved right here on Mapleprimes with a similar approach. Some of us need to be taught more than once, I guess :-)

frontend, freeze and thaw are completely, utterly new to me. Thanks for pointing these out.

As for the output format: I was aware that pasting 2-d output is not optimal but did not know how to fix it. I was looking for the equivalent of InputForm in Mma, but Maple does not have that. Well, lprint is it, so next time I will have to use a different excuse.

M.D.