MaplePrimes - answers and comments on Question, Help with procedures needed asap!

Example

Markiyan Hirnyk — Fri, 14 Dec 2012 00:18:33 Z

restart;
for a from 0.1e-1 by 0.1e-1 to 7.11 do
for b from 0.1e-1 by 0.1e-1 to 7.11 do
if (abs(a+b-7.11) < 0.2e-1 and abs(a*b-7.11) < 0.2e-1)
then print(a, b, a+b, a*b) end if
end do
end do;

                    1.20, 5.91, 7.11, 7.0920
                    1.20, 5.92, 7.12, 7.1040
                    1.21, 5.89, 7.10, 7.1269
                    5.89, 1.21, 7.10, 7.1269
                    5.91, 1.20, 7.11, 7.0920
                    5.92, 1.20, 7.12, 7.1040

problems in your proc

PatrickT — Fri, 14 Dec 2012 09:51:34 Z

1. main suggestion: use indentation to make sure every "if" has an "end if;" and every "do" has an "end do;"
2. don't forget to place an : or ; after each execution group
3. don't use protected symbols, like sum, product, add, etc..
4. no colon or semicolor after proc(), but instead after the locals are declared.
5. debug/test your proc by checking what each line does, this can be done by commenting out and using print or returning the current value

sum := 1;
Error, attempting to assign to `sum` which is protected

To illustrate indenting and debugging, consider:

myproc := proc()
local a,b,c,d,i,j,k,s,p,l,r,u;
r:=7.11: u:=0.1: # for debugging purposes, change the values here
for i by u to r do
a := i;
for j by u to r do
b := j;
for k by u to r do
s := a+b+c+d;
p := a*b*c*d;
c := k;
d := r-a-b-c;
if p=s and s=r then
print(`When a=`,a,`b=`,b,`c=`,c,`and d=`,d);
print(`a+b+c+d=a*b*c*d=r`);
else print("not working") # testing here
end if;
end do;
end do;
end do;
end proc:

myproc();

Markiyan showed you how to get the results.

Solution of the problem

Kitonum — Fri, 14 Dec 2012 23:15:24 Z

Because your system contains two redundant unknowns is easy to check that it has infinitely many solutions in four-dimensional space. But you do not look for solutions in the whole space, and on a discrete finite set a=0.01 ... 7.11 by 0.01 and so on. I think that there does not exist exact solutions on this set.

Natural formulation of the problem: on a given set of numbers to find a quartet [a, b, c, d] , for which the left-hand sides of the system have the least differencies from the right-hand sides. As a measure of the difference consider (7.11-(a+b+c+d))^2+(7.11-a*b*c*d)^2 . The procedure consists of two stages. To speed up work on the first stage we consider the wider step=0.1, and step=0.01 on the second stage near the optimum point of the first stage.

restart:

R:=[infinity, []]: # First stage

for a from 0.1 by 0.1 to 7.11 do

for b from a by 0.1 to 7.11 do

for c from b by 0.1 to 7.11 do

for d from c by 0.1 to 7.11 do

delta:=(7.11-(a+b+c+d))^2+(7.11-a*b*c*d)^2;

if delta<0.01 and delta<R[1] then R:=[delta, [a, b, c, d]]: fi:

od: od: od: od:

a0:=R[2,1]: b0:=R[2,2]: c0:=R[2,3]: d0:=R[2,4]: # Second stage

for a from a0-0.09 by 0.01 to a0+0.09 do

for b from b0-0.09 by 0.01 to b0+0.09 do

for c from c0-0.09 by 0.01 to c0+0.09 do

for d from d0-0.09 by 0.01 to d0+0.09 do

delta:=(7.11-(a+b+c+d))^2+(7.11-a*b*c*d)^2;

if delta<R[1] then R:=[delta, [a, b, c, d]]: fi:

od: od: od: od:

[.11296e-3, [.8, 1.8, 1.9, 2.6]] # Result of the first stage

[.266342400e-7, [.80, 1.76, 1.92, 2.63]] # Result of the second stage

Verification:

7.11-convert([.80, 1.76, 1.92, 2.63],`+`);

7.11-convert([.80, 1.76, 1.92, 2.63],`*`);

0.00016320

Exact solution

Kitonum — Sat, 15 Dec 2012 09:58:42 Z

Found an error in my previous solution. Offer exact solution found by the exhaustive search, pre considerably narrowed the search area.

Rewrite the system as follows {a+b=7.11-c-d, a*b=7.11/c/d} . Therefore, for the specified values of c and d , the values a and b satisfy the quadratic equation z^2+(c+d-7,11)*z+7,11/c/d=0 . Discriminant is equal to (c+d-7.11)^2-4*7.11/c/d >=0 .

Build the domain:

plots[implicitplot]([c*d*(c+d-7.11)^2-4*7.11, c+d=7.11], color=[red, blue],c=0..7.11, d=0..7.11, numpoints=10000);

It is clearly seen that each variable must be in the range 0.7..3.2

restart;

R:=[infinity, []]:

for a from 0.7 by 0.01 to 7.11/4 do

for b from a by 0.01 to (7.11-a)/3 do

for c from b by 0.01 to (7.11-a-b)/2 do

for d from c by 0.01 to min(3.2,7.11-a-b-c) do

delta:=(7.11-(a+b+c+d))^2+(7.11-a*b*c*d)^2;

if delta

od: od: od: od:

[0., [1.20, 1.25, 1.50, 3.16]]

Use elementary number theory

Carl Love — Sat, 15 Dec 2012 17:25:23 Z

Here's another solution, which uses elementary number theory (in particular the Fundamental Theorem of Arithmetic) to substantially reduce the search space, and thus get the answer in under 0.1 seconds.

restart;
st:= time():

If we multiply each of a,b,c,d by 100, then the sum is 711, and the product is

N:= 711*100^3:

and now the problem is strictly about positive integers. Henceforth, a,b,c,d will only refer to these integerized values.

Each of a,b,c,d must be a divisor of N, so let's look at the prime factorization of N:

ifactor(N);
6 2 6
(2) (3) (5) (79)

There is a prime factor that only appears to the first power. That will speed this up a lot. Let's get the divisors of N, which will be our search space.

divs:= numtheory:-divisors(N):

Since the sum is 711, we restrict the search to divisors less than 711.

divs:= select(`\<`, divs, 711)

(Ignore the backslash in the above line. Maple ignores it, and the MaplePrimes editor in my web browser won't display the rest of the line without it.)

Exactly one of a,b,c,d must be a multiple of 79---we'll make it a---so we partition the remaining divisors based on that.

d79, divs:= selectremove(x-> x mod 79 = 0, divs):

Now loop through these sets. After each x is chosen, the remaining solutions must divide N/x, so we reduce the search space accordingly in each inner loop.

proc()
    local Na, divsa, divsb, Nb, a, b, c, d, sol;
   for a in d79 do
    Na:= N/a;
        divsa:= divs intersect numtheory:-divisors(Na);
    for b in divsa do
           Nb:= Na/b;
           divsb:= divsa intersect numtheory:-divisors(Nb);
               for c in divsb do
         if a+b+c+Nb/c = 711 then sol[a,b,c]:= {a,b,c,Nb/c} fi
               od
        od
     od;
   convert(sol, set)
end proc
();
                          { {120, 125, 150, 316} }

Finally, divide each of those by 100 to get the desired answers. I put each solution in a set so that permutations would be condensed. If there was a solution with repeated values, it would appear as a set with fewer than four members, and we'd have to do a little work to figure out which values were repeated. But, there is no such solution.

time()-st;

0.031

In a separate run, I counted the number of executions of the innermost loop. It was 8520. I also tried the above without separating the multiple-of-79 divisors as special. Then I got 58,938 iterations in 0.109 seconds, so maybe it wasn't worth it to separate them.

A note on coding style: I use an anonymous procedure above, i.e. a procdeure with no name. I invoke the procedure immediately by placing () after its definition.

Improvement

Markiyan Hirnyk — Fri, 14 Dec 2012 00:35:59 Z

restart;
for a from 0.1e-1 by 0.1e-1 to 7.11 do
for b from a by 0.1e-1 to 7.11 do
if (abs(a+b-7.11) < 0.2e-1 and abs(a*b-7.11) < 0.2e-1)
then print(a, b, a+b, a*b) end if
end do
end do;
1.20, 5.91, 7.11, 7.0920
1.20, 5.92, 7.12, 7.1040
1.21, 5.89, 7.10, 7.1269