MaplePrimes - answers and comments on Question, How to sum in maple?

Solution

Kitonum — Mon, 07 Jan 2013 14:56:21 Z

restart;

n:=3:

ode:=diff(T(x),x$2)-T(x)^2=0;

bc:=T(0)=1,T(n)=0;

V:=dsolve({ode, bc}, numeric);

AverageT:=evalf(Int(x->rhs(V(x)[2]), 0..3))/n;

`T`:=[seq(rhs(V(x)[2]), x=1..3, 1)];

theta:=sqrt(add((`T`[i]-AverageT)^2, i=1..3)/(n-1))/AverageT;

More generally

Kitonum — Mon, 07 Jan 2013 21:11:44 Z

In my code, I relied on your formula, in which the number n determines the size of the segment of the boundary value problem and the number of parts into which divided this segment. If we divide these two parameters, we obtain a slightly more general problem. The number theta can also be considered discretely as in your formula, and it can more accurately be considered by the integral, if your last formula to the limit as n tends to infinity. In the example below 0.001 step corresponds to the division of the interval from 0 to 3 per 3000 parts:

restart;

a:=3: n:=3000:

ode:=diff(T(x),x$2)-T(x)^2=0;

bc:=T(0)=1,T(a)=0;

V:=dsolve({ode, bc}, numeric):

AverageT:=evalf(Int(x->rhs(V(x)[2]), 0..a))/a;

`T`:=[seq(rhs(V(x)[2]), x=a/n..a, a/n)]:

Int_theta:=evalf(sqrt(Int(x->(rhs(V(x)[2])-AverageT)^2, 0..a)/a)/AverageT);

theta:=sqrt(add((`T`[i]-AverageT)^2, i=1..n)/(n-1))/AverageT;

If n increases, the theta will be close to Int_theta .

step size?

J4James — Mon, 07 Jan 2013 16:29:55 Z

thx for your kind response. For high accuracy if we want to take the step size of the interval [0 3] 0.001 then calculate the average and sum, will this have any effects on the output?

A variation

Preben Alsholm — Mon, 07 Jan 2013 20:29:23 Z

@J4James Changing slightly the answer by Kitonum you could do the following.

restart;
n:=3:
ode1:=diff(T(x),x$2)-T(x)^2=0;
ode2:=diff(S(x),x)=T(x); #To find the T average
bc:=T(0)=1,T(n)=0,S(0)=0;
V:=dsolve({ode1,ode2, bc}, numeric,output=listprocedure);
VT,VS:=op(subs(V,[T(x),S(x)]));
AverageT:=VS(n)/n;
dx:=1/1000;
Tseq:=seq(VT(i),i=0..n,dx):
N:=nops([Tseq]);
theta1:=sqrt(add((Tseq[i]-AverageT)^2, i=1..N)/(N-1))/AverageT;
#N is roughly
n/dx;
#so you could integrate instead of sum:
theta2:=sqrt( evalf(Int((VT(x)-AverageT)^2,x=0..n))/n)/AverageT;

No difference between T and `T`

Preben Alsholm — Tue, 08 Jan 2013 01:00:26 Z

Notice that there is no difference between the name T and the name `T`.
However, something like `T ` (i.e. a space after T) would be different from T. That is why in my comment above I called the same quantity Tseq.