MaplePrimes - answers and comments on Question, Trouble with RK4 (Runge-Kutta)!

Several problems

Preben Alsholm — Fri, 11 Jan 2013 21:03:07 Z

Your system seems to be {diff(x(t), t) = v(t), and diff(v(t), t) = a(x(t), v(t))}, where a is a function of two variables. However, that function is never made concrete.

The multiplication sign in Maple is *, not a dot (used for matrix multiplication though).

What are v and a in the lines xn := xo+v.dt; and vn := vo+a.dt; ?

There may be more problems.

Preben Alsholm 3425

gabrielmp — Sat, 12 Jan 2013 05:50:27 Z

Thanks for your help. Preben. As you said, i changed things a little bit in the program. Now it looks like this:

restart;

A := Matrix();

dt := 0.1e-2;

diff(xo(t), t) := vo;

diff(vo, t) := a(xo(t), vo);

xo(t) := 1; vo := 0;

for i to 1000 do

xn := xo(t)+vo*dt; vn := vo+a*dt;

dx1 := vn*dt; dv1 := a*dt;

dx2 := (vn+(1/2)*dv1)*dt; dv2 := a(x+(1/2)*dx1, (1/2)*dv1)*dt;

dx3 := (vn+(1/2)*dv2)*dt; dv3 := a(xn+(1/2)*dx2, vn+(1/2)*dv2)*dt;

dx4 := (vn+dv3)*dt; dv4 := a(xn+dx3, vn+dv3)*dt;

xn := evalf((xo(t)+dx1+2*dx2+2*dx3+dx4)*(1/6)); vn := evalf((vo+dv1+2*dv2+2*dv3+dv4)*(1/6));

A(i, 1) := xn; A(i, 2) := vn; A(i, 3) := i*dt;

xo(t) := xn;

vo := vn

end do;

ExportMatrix("RK4.txt", A)

One thing I didn't understand is what do you mean with "a" not being concrete.

Thanks once again

Corrected code and an example

Preben Alsholm — Sat, 12 Jan 2013 18:45:33 Z

restart;
a:=(x,v)->-x-0.1*v; #Example only
xo := 1; vo := 0;
sys:={diff(x(t), t) = v(t), diff(v(t), t) = a(x(t), v(t)),x(0)=xo,v(0)=vo}; #Your system
dsolve(sys); #For comparison later
X:=subs(%,x(t));
plot(X,t=0..50);
#Now the corrected algorithm
xo := 1; vo := 0:
A := Matrix():
dt := 0.1e-2:
A(1, 1) := xo; A(1, 2) := vo; A(1, 3) := 0;
for i from 2 to 1001 do
   xn := xo+vo*dt; vn := vo+a(xo,vo)*dt;
   dx1 := vn*dt; dv1 := a(xo,vo)*dt;
   dx2 := (vn+(1/2)*dv1)*dt; dv2 := a(xn+(1/2)*dx1,vn+(1/2)*dv1)*dt;
   dx3 := (vn+(1/2)*dv2)*dt; dv3 := a(xn+(1/2)*dx2, vn+(1/2)*dv2)*dt;
   dx4 := (vn+dv3)*dt; dv4 := a(xn+dx3, vn+dv3)*dt;
   xn := evalf(xo+(dx1+2*dx2+2*dx3+dx4)*(1/6)); vn := evalf(vo+(dv1+2*dv2+2*dv3+dv4)*(1/6));
   A(i, 1) := xn; A(i, 2) := vn; A(i, 3) := ( i-1)*dt;
   xo := xn;
   vo := vn
end do:
A[1,..];
#The submatrix consisting of the third and first column can be obtained in two ways:
#LinearAlgebra:-SubMatrix(A,[1..-1],[3,1]);
# or
#A[1..-1,[3,1]];
plot(A[1..-1,[3,1]]);
prk:=%:
plot(X,t=0..1,color=blue):
plots:-display(prk,%);
#Comparing values at t = 1:
A[-1,..];
evalf(eval(X,t=1));

Edited: 1000 changed to 1001 and A(i, 3) := i*dt changed to A(i, 3) := ( i-1)*dt

Thanks

gabrielmp — Mon, 14 Jan 2013 17:32:31 Z

Thank you very much for your help Preben. I probably wouldn't have done it without you. I appreciate it !

See my other answer

Preben Alsholm — Sat, 12 Jan 2013 18:49:24 Z

You are using 'a' as a function of two variables (x and v), but it is never defined as such. However, you also use it without arguments, so you are not being consistent. In any case for the algorithm to run you have to define 'a'.