MaplePrimes - answers and comments on Question, BubblePlot plotting view

Use plottools:-transform like an eraser

Carl Love — Fri, 18 Jan 2013 02:04:02 Z

We can use plottools:-transform like an eraser on an existing PLOT structure by converting points outside a desired view to undefined. Then they will stay undefined if the VIEW is subsequently enlarged. (I'm using all caps for certain words because that's how they appear in the PLOT structure.)

a:= Statistics:-BubblePlot([4, 5, 2, 3], [1, 2, 7, 8], [8, 1, 3, 2]):
Eraser:= (x,y)-> [x, `if`(4 <= y and y <= 9, y, undefined)]:
a1:= plottools:-transform(Eraser)(a):
plots:- display(a1);

[plot not shown in post]

plots:-display(a1, view= [default, 0..9]);

[plot not shown in post]

The above procedure Eraser is ad hoc, for your particular view; but I can easily generalize it so that it will extract the range(s) from the VIEW option of an existing PLOT.

Note that however you change the view in a BubblePlot, the circles will be distorted to ellipses because they are created as POLYGONs, rather than as single points. This also means that they may be cut by an invisible horizontal or vertical line. If you want to erase points without changing the axes (which means that circles would stay circles), I'll have to think of something else.

Yes, with indets and op

Carl Love — Fri, 18 Jan 2013 05:11:56 Z

Indeed, here is the procedure. It takes a PLOT structure containing a VIEW as input and returns the PLOT structure with the appropriate points erased.

Eraser:= proc(P::specfunc(function,PLOT))
# Uses the VIEW specification of a PLOT structure to erase points outside the view.
   local
      x1,x2,y1,y2
     ,View:= indets(P, specfunc(anything, VIEW))
   ;
   if nops(View) = 0 then return P end if;
   if nops(View) > 1 then error "Multiple VIEWs found: %1", View end if;
   View:= View[];
   PLOT(
      op(
         plottools:-transform(
            subs(
               [x1,x2,y1,y2] =~ [op](map(op, subs(DEFAULT= -infinity..infinity, View)))
              ,(x,y)-> `if`(`or`(x1 > x,x > x2, y1 > y,y > y2), [undefined$2], [x,y])
            )
         )(P)
      )
     ,View
   )
end proc:

Modification so that the axes don't change

Carl Love — Fri, 18 Jan 2013 12:52:25 Z

I've modified the above so that the axes don't change due to the erasure, and the original axes will be restored if the VIEW is reverted to default by a subsequent display. So it is now more like erasing part of a blackboard (and circles will remain circles), whereas before it was like cutting off part of the blackboard. I do this by keeping track of the extreme upper, lower, left, and right points as they pass through the transformer procedure. Then I add an invisible (color= white) plot of the two extreme points: lower left and upper right.

It probably goes without saying that this procedure should work for any 2D plot, not just BubblePlot.

Eraser:= proc(Plot::specfunc(function,PLOT))
# Uses the VIEW specification of a PLOT structure to erase points outside the view.
# Input: PLOT structure with VIEW; Output: The PLOT structure, modified.
   local
      x1,x2,y1,y2,newPlot
     ,minx:= infinity, miny:= infinity, maxx:= -infinity, maxy:= -infinity
     ,View:= indets(Plot, specfunc(anything, VIEW))
   ;
   if View = {} then return Plot end if;
   if nops(View) > 1 then error "Multiple VIEWs found: %1", View end if;
   View:= View[];
   newPlot:=
      plottools:-transform(
         subs(
            [x1,x2,y1,y2] =~ [op(1..4, map(op, subs(DEFAULT= -infinity..infinity, View)))]
           ,proc(x,y)
               if not(x::numeric and y::numeric) then return [args][1..2] end if;
               if x < minx then minx:= x end if; if x > maxx then maxx:= x end if;
               if y < miny then miny:= y end if; if y > maxy then maxy:= y end if;
               `if`(`or`(x1 > x,x > x2, y1 > y,y > y2), [undefined$2], [x,y])
            end proc
         )
      )(Plot)
   ;
   # Add two invisible (white) points at extreme corners of original plot so axes don't change.
   # plottools:-transform removes VIEW, so put it back.
   plots:-display(
   [plots:-pointplot([[minx,miny],[maxx,maxy]], color= white), newPlot]
    ,view= [op(1..2, View)]
)
end proc:

indets

Christopher2222 — Fri, 18 Jan 2013 04:56:44 Z

I suppose that could do. Not to bring our options to an end.

Regarding pulling the data out of the graph for a generalization, I suppose you would mean using indets and op, so something like this if

a:= Statistics:-BubblePlot([4, 5, 2, 3], [1, 2, 7, 8], [8, 1, 3, 2],view=[default,0..9]):

myrange:=op(indets(a, specfunc(anything, VIEW)))

myx:=op(myrange)[1]
myy:=op(myrange)[2]

Bug in 16.02 Standard GUI

Carl Love — Sun, 20 Jan 2013 06:21:35 Z

A bug just introduced into the Maple 16.02 Standard GUI plot renderer makes it appear that the above procedure doesn't work with regular plots: The entire plot appears blank. But if you use the context menu "Manipulator" to "Pan" the plot, the curve will appear.