Use the ?seq command or a ?for loop. I like seq(

John May — Mon, 21 Jan 2013 20:38:10 Z

Use the ?seq command or a ?for loop. I like seq() personally:

with(geom3d):
L:=[[-5, -5, 8], [-5, -1, 10], [-5, 3, 10], [-5, 7, 8], [-5, 8, -5], [-5, 8, 7], [-5, 10, -1], [-5, 10, 3], [-1, -5, 10], [-1, 7, 10], [-1, 10, -5],
  [-1, 10, 7], [3, -5, 10], [3, 7, 10], [3, 10, -5], [3, 10, 7], [7, -5, 8], [7, -1, 10], [7, 3, 10], [7, 7, 8], [7, 8, -5], [7, 8, 7], [7, 10, -1], 
  [7, 10, 3], [8, -5, -5], [8, -5, 7], [8, 7, -5], [8, 7, 7], [10, -5, -1], [10, -5, 3], [10, -1, -5], [10, -1, 7],
  [10, 3, -5], [10, 3, 7], [10, 7, -1], [10, 7, 3]];
seq(point(cat(`A_`,i),op(L[i])),i=1..nops(L));
eqS:=Equation(sphere(S,(x-1)^2 + (y-1)^2 +(z-1)^2 -121=0,[x,y,z],'centername'=T));
seq(TangentPlane(cat(`P_`,i),S,cat(`A_`,i)),i=1..nops(L));
seq(sort(Equation(cat(`P_`,i),[x,y,z])),i=1..nops(L));

John

You can reuse object labels

Carl Love — Mon, 21 Jan 2013 21:19:19 Z

It is a nuisance that geom3d requires you to label every object. The object model used in that package is much older than the modern one based on modules. In the modern module model, an object "is what it is", so to speak, regardless of what, or even if, you name it; in the older model, an object's properties are based on looking it up by name. (To "deconstruct" it, it seems that the evolution of the object model is analogous to the evolution of social classes.) But you can reuse the labels in geom3d, so the easiest way to do what you want is

[seq](sort(Equation(TangentPlane(P, S, point(A, pt[])), [x,y,z])), pt in L);

(where all points are named A and all planes are named P).

If you do require distinct names for each object (so that you can look up their properties without recreating them), it is possible to construct names based on the numerical values of the point using nprintf:

[seq](
       sort(
            Equation(TangentPlane(nprintf("P%a",pt), S, point(nprintf("A%a", pt), pt[])), [x,y,z])
       )
      ,pt in L
);

Unique names can also be created with cat, which is what John May did.

MaplePrimes - answers and comments on Question, How to write all tangent of planes of a sphere from a list?

Use the ?seq command or a ?for loop. I like seq(

You can reuse object labels