MaplePrimes - answers and comments on Question, Create a count from a list?

One way

Markiyan Hirnyk — Fri, 25 Jan 2013 02:53:01 Z

> r := [3, 3, 3, 3, 4, 4, 4, 3, 3, 3, 3, 3, 3, 3, 3, 2, 4, 3, 1];
> with(Statistics):
> T := Tally(r);

[1 = 1, 2 = 1, 3 = 13, 4 = 4]
> lhs(op(select(c-> is(rhs(c) = max(map(rhs, T))), T)));
3

See ?Tally , ?lhs , ?rhs , ?map , and ?select for more details. Also see the results of the "frequency" (PS. and "count") search in MaplePrimes at the top of this page.

Procedure

Kitonum — Fri, 25 Jan 2013 03:15:50 Z

P:=proc(L::list)

local M, F, Max, S, i;

M:=convert(L, set);

F:=[seq([M[i], ListTools[Occurrences](M[i], L)], i=1..nops(M))];

print(F);

Max:=max(seq(F[i, 2], i=1..nops(M)));

S:=[];

for i in F do

if i[2]=Max then S:=[op(S), i[1]]; fi;

od;

op(S);

end proc:

Example:

L:=[3,3,3,3,4,4,4,3,3,3,3,3,3,3,3,2,4,3,1]:

P(L);

[[1, 1], [2, 1], [3, 13], [4, 4]]

ListTools:-Classify and ListTools:-Categorize

Carl Love — Fri, 25 Jan 2013 03:31:44 Z

Another way --- one of many.

restart;
r:= [3,3,3,3,4,4,4,3,3,3,3,3,3,3,3,2,4,3,1]:
T:= ListTools:-Classify(nops, [ListTools:-Categorize](`=`, r));

T := TABLE([1 = {[1], [2]}, 4 = {[4, 4, 4, 4]}, 13 = {[3, 3, 3, 3, 3, 3, 3, 3, 3, 3, 3, 3, 3]}])

m:= max(indices(T));

m := 13

op ~ (T[m])[];

I wrote the above to cleanly handle the multi-modal case (as Kitonum also did), which adds a bit of complexity.

Answer by Christian Wolinski

Markiyan Hirnyk — Mon, 11 Jan 2016 19:38:45 Z

Here is the answer by Christian Wolinski

which was deleted by me because of misunderstanding. I am very sorry of that.

Comment

Kitonum — Fri, 25 Jan 2013 03:29:46 Z

Your code does not work, if the list r contains several elements with the same maximum frequency:

r := [3, 3, 3, 3, 4, 4, 4, 3, 3, 3, 3, 3, 3, 3, 3, 2, 4, 3, 1$13];

with(Statistics):

T := Tally(r);

lhs(op(select(c-> is(rhs(c) = max(map(rhs, T))), T)));

r := [3, 3, 3, 3, 4, 4, 4, 3, 3, 3, 3, 3, 3, 3, 3, 2, 4, 3, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1]

T := [1 = 13, 2 = 1, 3 = 13, 4 = 4]

Error, invalid input: lhs expects 1 argument, but received 2

More exactly

Markiyan Hirnyk — Fri, 25 Jan 2013 05:46:07 Z

Thanks. A simple adjustment: