MaplePrimes - answers and comments on Question, programming issue

copy, ArrayTools, and ?rtable_indexing

Carl Love — Thu, 31 Jan 2013 05:21:43 Z

First off, please do not use the old lowercase constructor commands matrix, array, vector. The new constructors are capitalized---Matrix, Array, Vector---and they are much more efficient and versatile. I will not help you anymore if you continue to use the lowercase constructors, as I'd rather just forget about them. The rest of this post will deal strictly with the newer versions. Also, anything that I say below about Arrays could equally well be said about Matrices or Vectors.

You wrote:

for l to 5 do: for i to 6 do: for j to 6 do: L[i,j] := P[i,j,l]: od: od: V[l]:=L: od:
The code fails in that V[1]=V[2]=...v[5] = P[i,j,5].

The immediate problem is that V[l]:= L needs to be V[l]:= copy(L); however, assigning individual entries in a loop is an inefficient way to do this (see below for a more efficient way). The reason the copy is needed is a somewhat arcane topic. You can read some about it at ?copy, but the topic requires a moderate amount of computer programming knowledge to understand. The take-away is Don't directly assign one Array to another (unless you understand the consequences); it does not make an independent copy of the Array.

There are many commands in the ?ArrayTools package for efficiently handling things like changing dimensions, copying parts of Arrays, etc.

You wrote:

Also, given a matrix, is there a way to extract a column vector from that matrix? I.e. in FORTAN is M is a matrix, M(:,3) would return the third column of M. Is there a similar command in Maple?

Yes, and the syntax is almost identical: M(.., 3) or M[.., 3]. The available combinations for selecting and rearranging subparts of Arrays is vast, and discussed at ?rtable_indexing.

So, applying this subpart selecting to your original loop, you could do the whole job as

V:= Array(1..5, i-> P[.., .., i]);

Try this

Preben Alsholm — Thu, 31 Jan 2013 05:40:15 Z

restart;
P:=Array(1..6,1..6,1..5,(i,j,k)->i*j*10^k); #Example

P[1..6,1..6,1];
Array([seq(P[1..6,1..6,i],i=1..5)]);

#Your code just needs 'copy':
L:= Matrix(1..6,1..6):

V:=Array(1..5):

for l to 5 do
for i to 6 do
    for j to 6 do
      L[i,j] := P[i,j,l]
    od
od;
V[l]:=copy(L)
od:

V;

subtype

acer — Thu, 31 Jan 2013 08:11:15 Z

As written, the 2-dimensional rtable entries of V are of type Array rather than of type Matrix. It's not clear from the original post which is wanted or needed, and perhaps it won't matter. But for some uses it will matter, eg. behaviour w.r.t. the `.` operator, or in a release before Maple 16 when the LinearAlgebra package got coercion, etc. If it matters, then this aspect can be efficiently toggled in-place on the V[i], ie.

for i from 1 to 5 do rtable_options(V[i],subtype=Matrix); end do:

After doing so V[i] will be a Matrix instead of a 2-dimensional Array, and V[i][..,k] will be a column Vector instead of a 1-dimensional Array.

acer

Alternatively

Joe Riel — Thu, 31 Jan 2013 09:49:13 Z

@acer That seems esoteric, though an inplace conversion is handy. Clearer, at least to me, is

V:= Array(1..5, i-> Matrix(P[.., .., i]));