MaplePrimes - answers and comments on Question, trigonometric series

a way using a parametrical rule

Alejandro Jakubi — Sun, 10 Feb 2013 10:54:22 Z

You may try a procedure that generates a parametric transformation rule extracting the coefficient for a 1-D mode given the function (sin or cos), the numeric label of the mode and the variable name (here x or z):

fc1d:=proc(f::name,n::posint,v::name)
a::And(algebraic,Not(specfunc(algebraic,{sin,cos})))*f(n*v)+b::algebraic=a:
end proc:

S:= A*cos(2*x)*sin(3*z) + B*cos(7*x)*sin(4*z) + C*sin(3*z)+K*sin(4*z)+cos(7*x):

applyrule(fc1d(sin,3,z),S);
                                       C
applyrule(fc1d(sin,4,z),S);
                                       K
applyrule(fc1d(cos,7,x),S);
                                       1

Another way

Kitonum — Sun, 10 Feb 2013 13:46:06 Z

S:= A*cos(m*x)*sin(n*z) + B*cos(k*z)*sin(q*x) + sin(s*z) + C*cos(p*z)+E*sin(t*z)^2:

L:=[]:

for i in [op(S)] do

if (nops(i)=1 and (is(op(0,i)=sin) or is(op(0,i)=cos))) or

(nops(i)=2 and (is(op([-1,0],i)=sin) or is(op([-1,0],i)=cos)) and

(type(op(1,i),constant) or type(op(1,i),symbol))) then

if nops(i)=1 then L:=[op(L), [1,i]] else L:=[op(L), [op(1, i),i]]: fi:

fi:

od:

[[1, sin(s*z)], [C, C*cos(p*z)]]

Using coeffs (or frontend)

Preben Alsholm — Sun, 10 Feb 2013 21:36:04 Z

restart;
#Taking Alejandro Jakubi's example:
S:= A*cos(2*x)*sin(3*z) + B*cos(7*x)*sin(4*z) + C*sin(3*z)+K*sin(4*z)+cos(7*x);

#Using frontend:
eval(frontend(coeff,[S,sin(3*z)]),{cos=0,sin=0});
eval(frontend(coeff,[S,cos(7*x)]),{cos=0,sin=0});
########
Edited: I have kept my first version of a procedure for this task below, but here is a much shorter one using coeffs and no freezing:

p:=proc(S::`+`) local cs,T;
   cs:=[coeffs(S,indets(S,specfunc(anything,{sin,cos})),'T')];
   select(type,`[]`~([T],cs),[specfunc(anything,{sin,cos}),anything])
end proc;
p(S);

############
Original version:

Making a procedure to find all. This is in parts like my answer to
http://www.mapleprimes.com/questions/142564-Extracting-Coefficients-From-A-Fourier-Series

p:=proc(S::`+`) local L,Lf,cs,ff,ffcs;
   L:=convert(S,list);
   Lf:=evalindets(L,specfunc(anything,{sin,cos}),freeze);
   cs:=eval(L,{sin=1,cos=1});
   ff:=Lf/~cs;
   ffcs:=`[]`~(ff,cs);
   thaw(remove(type,ffcs,[`*`,anything]))
end proc;

p(S);