MaplePrimes - answers and comments on Question, E with one random variable

An experimental attempt

Preben Alsholm — Mon, 18 Feb 2013 21:44:50 Z

I don't quite see in your code any attempt to implement the piecewise defined A at the top. Presumably (t,365) is meant as t-floor(t/365)*365.

Knowing nothing about stochastic differential equations the following should be taken as an experiment.
The example used is only somewhat similar to yours.

Added: A somewhat simpler looking way at the bottom.

restart;
#The ode considered is
ode:=diff(U(t),t)=-(Ap(t)+r(t)+B*U(t))*U(t);
#where Ap is a piecewise defined function, B is a constant, and r is a random variable here defined as:

r:=RandomTools:-Generate(distribution(Normal(0, .5)), makeproc=true);
#We shall not use ode at all, but use procedural input to dsolve/numeric:

p:=proc(N,t,Y,YP) local Ap,B;
   B:=.1;
   Ap:=piecewise(t<=1,.1+ 0.4*t,0.5+ 0.004*t);
   YP[1]:=-(Ap+r(t)+B*Y[1])*Y[1]
end proc;
#It appears to me that the only reasonable method is a forward method with no error corrections.
#Thus I use the simple Euler method classical[foreuler].
#Choose some stepsize consistent with the application we have in mind.
#Here chosen arbitrarily to 0.01.
res:=dsolve(numeric,procedure=p,number=1,initial=Array([1]),start=0,procvars=[U(t)],method=classical[foreuler],stepsize=0.01);
plots:-odeplot(res,[t,U(t)],0..2);

#########################################
##Another way and I guess simpler looking.
restart;
ode:=diff(U(t),t)=-(Ap(t)+r(t)+B*U(t))*U(t);
R:=RandomTools:-Generate(distribution(Normal(0,.5)), makeproc=true);
r:=proc(t)
if not type(t,numeric) then return 'procname(_passed)' end if;
R()
end proc;
Ap:=t->piecewise(t<=1,.1+ 0.4*t,0.5+ 0.004*t);
B:=0.1:
res:=dsolve({ode,U(0)=1},numeric,known=r(t),method=classical[foreuler],stepsize=0.01);
plots:-odeplot(res,[t,U(t)],0..2);

Thank you for your replay. I was going wrong

reemeaaaah — Tue, 19 Feb 2013 00:41:37 Z

Thank you for your replay. I was going wrong using rand().

I am trying to run the code that you provided but I have problem on this part:

Ap:=piecewise(t YP[1]:=-(Ap+r(t)+B*Y[1])*Y[1]

I get: Error, unable to match delimiters

I added delimiter Ap:=piecewise(t YP[1]):=-(Ap+r(t)+B*Y[1])*Y[1]

I get: Error, `:=` unexpected

The second code works.

Thank you so much for your helpful replay. I will carefully go through it to understand the process.

The MaplePrimes editor has a problem

Preben Alsholm — Tue, 19 Feb 2013 05:21:42 Z

@reemeaaaah The MaplePrimes editor very often leaves out everything on a line after <.
That is quite a nuissance.
I corrected it. I hope it is OK now.

@Preben Alsholm It works thank you so much

reemeaaaah — Tue, 19 Feb 2013 08:10:58 Z

@Preben Alsholm

It works thank you so much