MaplePrimes - answers and comments on Question, How do I extract elements from a string

A first step

Carl Love — Thu, 21 Feb 2013 22:59:55 Z

(A much-simplified version of what I posted earlier.)

List the positions of all substrings of the given string that match a chemical element symbol.

BreakBad:= module()
   uses ST= StringTools, ST_PD= StringTools:-PatternDictionary, SC= ScientificConstants;

   #PatternDictionary is case sensitive. Thus, all text is uppercased for searching.

   local
       #Periodic (remember) Table of Elements:
       #Map from uppercase elem symbs to standard capitalized symbs.
       PTE:= proc(EL::string) option remember; ST:-Capitalize(EL) end proc,

       #Dictionary of uppercased elem symbs.
       Dict:= ST_PD:-Create(ST:-UpperCase ~ ([SC:-GetElements()])),

       #ST_PD:-Search returns seq of 2-member lists, with 2nd member
       #being the dict. id# of found pattern. RetStr is operator that turns that id#
       #into standard elem symbol.
       RetStr:= curry(applyop, curry(PTE@ST_PD:-Get, Dict), 2)
   ;
   export ModuleApply:= (S::string)-> RetStr ~ ([ST_PD:-Search](Dict, ST:-UpperCase(S)));
end module;

Testing it:

BreakBad("The Cat Molly");

[[2, "H"], [1, "Th"], [2, "He"], [5, "C"], [5, "Ca"], [6, "At"], [10, "O"], [9, "Mo"], [13, "Y"]]

So this says that "H" occurs at position 2, "At" at position 6, etc.

For next step, we need to decide what to highlight because there are overlapping choices. For the simple example string above we have 9 matches; it would be quite a mess to highlight them all. Perhaps we should select at random. For the final display, I'm considering doing it as a textplot. That way highlights can be done with color easily under programmatic control

convention

brian bovril — Wed, 27 Feb 2013 17:08:21 Z

@Carl Love made the point about the searches needing to be case sensitive....

@Joe Riel thx for worksheet. Sorry to bang on about this. maybe i didn't fully explain the nuances of the problem.

Given the convention should be

1) one element per word (identified randomly or otherwise- if it exists)

2) keep the original case of the word, except for the 1 or 2 letter element (bold),

example:

i/p: "anna aaron dean Mitte zt michael sherry au Lynne"

o/p: "anNa aAron deaN MitTe zt micHael sherrY Au LynNe"

do you mind modifying your workbook to reflect the above?

MathML

Joe Riel — Fri, 22 Feb 2013 11:19:38 Z

Nice start. Rather than using textplot I think using Maple's mathml formatting might be a better approach. Here I've added some functionality to your module to do that. The output will only display properly in Standard Maple. I used a crude method to avoid collisions in the matches, it can be improved.

BreakBad := module()

uses ST = StringTools
    , ST_PD= StringTools:-PatternDictionary
    , SC= ScientificConstants
    , LT = ListTools
    ;

export ModuleApply;


    # PatternDictionary is case sensitive. Thus, all text is uppercased for searching.

local Dict, Format, RetStr;
    # Periodic (remember) Table of Elements:
    # Map from uppercase elem symbs to standard capitalized symbs.
#    PTE := proc(EL::string) option remember; ST:-Capitalize(EL) end proc

    # Dictionary of uppercased elem symbs.
#    , Dict:= ST_PD:-Create(ST:-UpperCase ~ ([SC:-GetElements()]))
    Dict := ST_PD:-Create(map2(cat,"",[SC:-GetElements()]));

    # ST_PD:-Search returns seq of 2-member lists, with 2nd member
    # being the dict. id# of found pattern. RetStr is operator that turns that id#
    # into standard elem symbol.
    RetStr := curry(applyop, curry(ST_PD:-Get, Dict), 2);
    Format := proc(txt,wt)
    local s;
        if txt = "" then
            "";
        elif searchtext(" ",txt)<>0 then
            # Spaces at the ends of symbols are elided.
            # This avoids that by converting all spaces
            # to an invisible times operator.
            ST:-Join([seq(`if`(s=""
                               , "mo(&InvisibleTimes;)"
                               , thisproc(s,wt)
                              ), s = ST:-Split(txt))]
                     , ",");
        else
            sprintf("mi(\"%s\",fontweight=\"%s\")", txt, wt);
        end if;
    end proc;

    ModuleApply := proc(S::string)
    local bold,e,elems,mathml,plain,rngs,i,r;
        elems := RetStr ~ ([ST_PD:-Search](Dict, S));
        elems := sort(elems, (a,b) -> evalb(a[1]<=b[1]));
        elems := LT:-MakeUnique(elems, 1, (x,y)->x[1]=y[1]);
        elems := [[1,""], elems[],[0,""]];
        rngs := [seq(op([i,1],elems)+length(op([i,2],elems))..op([i+1,1],elems)-1
                     , i = 1..nops(elems)-1)];
        bold := [seq(Format(e[2],"bold"), e=elems)];
        plain := [seq(Format(S[r],"normal"), r=rngs)];
        mathml := remove(`=`, LT:-Interleave(bold,plain), "");
        nprintf("#mrow(%s)", ST:-Join(mathml, ","));
    end proc;

end module:

Breaking Bad

brian bovril — Fri, 22 Feb 2013 18:24:06 Z

Joe, I couldn't get the code to work in M16. maybe I copied it incorrecty....

element_16.mw

This is the effect I was trying to achieve (bolding the elements)

http://www.youtube.com/watch?v=PVXYgRt63xc

Possibly bolding/enlarding a random element per word. eg "cat", would radomly bold either the C, the Ca, or the At.

1D

Joe Riel — Fri, 22 Feb 2013 21:14:24 Z

@brian bovril The 2D parser is the issue; I'll track that down and file a bug when I get a chance. To work-around it, copy and paste the original code (above) into a Maple input region (1D). The code is fine.

maple worksheet

brian bovril — Sun, 24 Feb 2013 17:52:01 Z

Joe Riel, would you be so kind as to post your 1D worksheet here, because I can't get it to work