MaplePrimes - answers and comments on Question, Plotting an Array

something

acer — Thu, 28 Feb 2013 22:54:25 Z

It's not clear what you want, exactly. But you may be able to adjust this to suit.

restart:

M:=Matrix(10, 10,
 {(1, 1) = 1, (1, 2) = 1, (1, 3) = 1, (1, 4) = 1, (1, 5) = 1, (1, 6) = 1,
 (1, 7) = 1, (1, 8) = 1, (1, 9) = 1, (1, 10) = 1, (2, 1) = 1, (2, 2) = 1,
 (2, 3) = 2, (2, 4) = 2, (2, 5) = 2, (2, 6) = 2, (2, 7) = 1, (2, 8) = 1,
 (2, 9) = 1, (2, 10) = 1, (3, 1) = 1, (3, 2) = 2, (3, 3) = 2, (3, 4) = 2,
 (3, 5) = 2, (3, 6) = 2, (3, 7) = 2, (3, 8) = 2, (3, 9) = 1, (3, 10) = 1,
 (4, 1) = 1, (4, 2) = 2, (4, 3) = 2, (4, 4) = 2, (4, 5) = 2, (4, 6) = 2,
 (4, 7) = 2, (4, 8) = 2, (4, 9) = 1, (4, 10) = 1, (5, 1) = 2, (5, 2) = 2,
 (5, 3) = 2, (5, 4) = 2, (5, 5) = 2, (5, 6) = 2, (5, 7) = 2, (5, 8) = 2,
 (5, 9) = 2, (5, 10) = 1, (6, 1) = 2, (6, 2) = 2, (6, 3) = 2, (6, 4) = 2,
 (6, 5) = 2, (6, 6) = 2, (6, 7) = 2, (6, 8) = 2, (6, 9) = 2, (6, 10) = 1,
 (7, 1) = 2, (7, 2) = 2, (7, 3) = 2, (7, 4) = 2, (7, 5) = 2, (7, 6) = 2,
 (7, 7) = 2, (7, 8) = 2, (7, 9) = 2, (7, 10) = 1, (8, 1) = 2, (8, 2) = 2,
 (8, 3) = 2, (8, 4) = 2, (8, 5) = 2, (8, 6) = 2, (8, 7) = 2, (8, 8) = 2,
 (8, 9) = 2, (8, 10) = 1, (9, 1) = 2, (9, 2) = 2, (9, 3) = 2, (9, 4) = 2,
 (9, 5) = 2, (9, 6) = 2, (9, 7) = 2, (9, 8) = 2, (9, 9) = 2, (9, 10) = 1,
 (10, 1) = 2, (10, 2) = 2, (10, 3) = 2, (10, 4) = 2, (10, 5) = 2, (10, 6) = 2,
 (10, 7) = 2, (10, 8) = 2, (10, 9) = 2, (10, 10) = 1}):

m,n:=LinearAlgebra:-Dimensions(M):

Plines:=plots:-display(
  seq(seq(`if`(M[m+1-j,i-1]<>M[m+1-j,i],
               plottools:-line([i-0.5,j-1+0.5],[i-0.5,j+0.5]),NULL),
          j=1..m),i=2..n),
  seq(seq(`if`(M[m+1-j,i]<>M[m+2-j,i],
               plottools:-line([i-0.5,j-1+0.5],[i-0.5+1,j-1+0.5]),NULL),
          j=2..m),i=1..n),
              view=[1..m,1..n]):

Ppoints:=plots:-display(
  plots:-sparsematrixplot(Matrix(m,n,(i,j)->M[m+1-i,j]-1),color=red),
  plots:-sparsematrixplot(Matrix(m,n,(i,j)->M[m+1-i,j]-2),color=green)):

plots:-display( Plines, Ppoints );

acer

for fun

acer — Thu, 28 Feb 2013 23:00:32 Z

M:=LinearAlgebra:-RandomMatrix(13,13,generator=1..2);

Of course, for larger dimensions it should be built differently, more efficiently. (If your example was meant only as an illustrative toy example then you might consider using `implicitplot`. Or not..)

I didn't state it before, but of course you could view Plines without Ppoints.

acer

modified

acer — Fri, 01 Mar 2013 07:43:01 Z

I suppose that this has been done before... and likely done better too. But I may as well make it into a procedure.

restart:

cellplot:=proc(M::Matrix)
   local colorlist,m,n,i,j,Plines,Ppoints,v,vals;
   uses LinearAlgebra,plots,plottools;
   m,n:=Dimensions(M);
   Plines:=display(
      seq(seq(`if`(M[m+1-j,i-1]<>M[m+1-j,i],
                   line([i-0.5,j-1+0.5],[i-0.5,j+0.5]),NULL),
              j=1..m),i=2..n),
      seq(seq(`if`(M[m+1-j,i]<>M[m+2-j,i],
                   line([i-0.5,j-1+0.5],[i-0.5+1,j-1+0.5]),NULL),
              j=2..m),i=1..n),
      ':-view'=[1-0.48..m+0.48,1-0.48..n+0.48]);
   vals:=[{seq(v, v in M)}[]];
   colorlist:=setcolors();
   Ppoints:=display(
      seq(sparsematrixplot(Matrix(m, n,
                                  (i,j)->`if`(M[m+1-i,j]=vals[k],1,0))
                           ,`if`(nops(colorlist)>=nops(vals),
                                 ':-color'=colorlist[k],NULL)
                           ,':-symbol'=':-solidcircle', tickmarks=[0,0]
                           ,':-symbolsize'=20, ':-legend'=vals[k]
                           , _rest),
          k=1..nops(vals)));
   display( Plines, Ppoints, ':-labels'=[``,``], ':-axes'=':-boxed' );
end proc:

A:=LinearAlgebra:-RandomMatrix(10,generator=-7..-5):

cellplot(A);

cellplot(A, legend=NULL, symbolsize=1);

cellplot(A, legend=NULL, symbol=solidbox, symbolsize=68); # not a great idea

acer

pretty!

PatrickT — Fri, 01 Mar 2013 14:21:34 Z

@acer

and no doubt useful too!