MaplePrimes - answers and comments on Question, Bug in plottools[transform] & Where is transform/object

works in M12

Christopher2222 — Mon, 11 Mar 2013 18:19:09 Z

It works here in M12

nonnumeric input

acer — Mon, 11 Mar 2013 18:38:48 Z

How about having `f` return unevaluated if its arguments are not of type numeric.

restart:                                          

simp:=plot(sin(x), x=0..2*Pi):                    

f:=(xx,yy)->`if`(yy::numeric and xx::numeric,     
                 `if`(yy > 0, [xx,4*yy], [xx,yy]),
                 'procname'(xx,yy)):              

trns:=plottools:-transform(f):                                               

trns(simp);

acer

List

Preben Alsholm — Mon, 11 Mar 2013 18:46:08 Z

The following works for your example:

f:=(x,y)->[x,`if`(y>0,4*y,y)];

or this weirder version:

f:=(x,y)->[`if`(x<1,x^2,x*y),`if`(y>0,4*y,y)];

How to use plottools:-transform

Carl Love — Mon, 11 Mar 2013 20:04:27 Z

Excellent questions, TomM. There is no bug, but the answers to your questions are very poorly documented, if documented at all. It took me several hours on 17-Jan-2013 to figure out the answers to those same questions.

TomM wrote:

On Maple 16.02, plattools[transform] only works for very simple procedures. It does not work for procedures with the `if` function even with the simple arrow definition. or with any if-block in a more general proc definition.

You can use procedures of arbitrary complexity, but it requires a little trick at the beginning of the procedure. Let's call the procedure which is passed to plottools:-transform "the point transformer", and let's call the procedure that plottools:-transform returns "the plot transformer". When the plot transformer is called, the first call that it makes to the point transformer will be with symbolic (i.e. non-numeric) arguments. It does this to check the number of dimensions returned (because plottools:-transform can be used to transform 2D to 3D and vice versa). On this first call, the point transformer must return a list (or other object) with the correct number of elements.

TomM wrote:

simp:= plot(sin(x), x= 0..Pi);
f:=(xx,yy)->`if`(yy > 0, [xx,4*yy], [xx,yy]);
trns:=plottools:-transform(f);
trns(simp);

So, for the above, your point transformer should be written:

f:=(xx,yy)-> `if`(not (xx::numeric and yy::numeric), [xx,yy], `if`(yy > 0, [xx,4*yy], [xx,yy]));

For an example of a much more complex point transformer, see my MaplePrimes post BubblePlot plotting view: Modification so that the axes don't change.

TomM wrote:

From examining op(trns), the error seems to occur in the procedure: `transform/object`. However, I cannot find a way to print out this procedure, even with verboseproc=2, with print or op. Where is this procedure, and how can I print it out?

It is a procedure local to module plottools. So, to print it out, do

kernelopts(opaquemodules= false); #Get access to module locals
interface(verboseproc= 2);
eval(plottools:-`transform/object`);

You can also showstat that procedure, or trace it; which is how I figured out the answer to your first problem.

TomM wrote:

On the other hand, with f:=(xx,yy)-> [xx, 3*max(0,yy)+yy], the transform works and produces the same plot as the non-working sequence above.

It works because the above f will return a list of two elements even if it is passed symbolic arguments. But if it was inside an `if`, then it would just return the unevaluated `if`, which is not a list, and doesn't have two elements.

One doesn't on M16.02 and Two Do But Why?

TomM — Mon, 11 Mar 2013 20:15:08 Z

From Christopher, it would seem that the code worked in Maple 12, but a bug (or undocumented behavior) has been introduced by the time Maple reached Maple 16.02

On the other hand, Acer and Preben have functions which work. What general cases does transform work for? The Help page is quiet on this. The answer seems to lie in the procedure `transform/object`. Acer and Preben, did you have access to the code for that procedure, or did you discover your fixes by quessing and trial and error?

Does anyone know how to see the code for `transform/object`?

PS: I really meant 2*Pi in the plot, but that is not really essential to the "bug".

A somewhat similar version fails

Preben Alsholm — Mon, 11 Mar 2013 19:11:09 Z

I tried this before I saw yours, but my version fails:

f:=proc(x,y) if not type([x,y],list(numeric)) then return 'procname(_passed)' end if;
`if`(y>0,[x,4*y],[x,y])
end proc;

Edited: In the initial version of this comment I forgot 'return' . But the edited is the one intended and it doesn't work.

Edited once again: The version works if _passed is replaced by x,y. Probably because _passed will be arguments passed to another procedure.