MaplePrimes - answers and comments on Question, subroutine calling

Alternatives

Joe Riel — Thu, 21 Mar 2013 05:54:27 Z

There are a few ways you can do this with Maple. One is to mimic Matlab's multiple output method. For example

MyProc := proc(x) return ( x, x+1, x^2 ); end proc:
(a,b,c) := MyProc(3); 
                            a, b, c := 3,4,9

The variables a, b, and c are now assigned 3, 4, and 9, respectively.

That isn't, however, necessarily the best approach, particularly if you are dealing with Matrices. You might be better off passing the output Matrices to the procedure as arguments and have the procedure operate on them directly. For example

MyProc := proc(A :: Matrix, B::Matrix, C::Matrix) 
    B[..,..] := A^2;
    C[..,..] := A+B;
    NULL;
end proc:
X := <1,2;3,4>: Y := Matrix(2): Z := Matrix(2):
MyProc(X,Y,Z):
Y,Z;
          [ 7  10]   [8  12]
          [      ],  [     ]
          [15  22]   [18 26]

New syntax?

Carl Love — Thu, 21 Mar 2013 06:19:09 Z

Does this line have a typo?

X := : Y := Matrix(2): Z := Matrix(2):

Or is there some new syntax that I'm not aware of?

sort of

Joe Riel — Thu, 21 Mar 2013 06:40:03 Z

@Carl Love Don/t know that I'd label it a typo. I used angle brackets to assign a Matrix, preformatted the block, submitted, then later edited the post to fix an actual typo, elsewhere. That invariably elides angle brackets---I invariably forget. Fixed it. Thanks.

multiple assignment

acer — Thu, 21 Mar 2013 06:51:38 Z

I would agree with Joe, that you can probably get what you want by using multiple return values from the procedure, combined with multiple assignment.

At the risk of adding irrelevant detail... Note that you have a choice in handling multiple return values (ie. an expression sequence) from a procedure. You can match it with an equal number of names on the LHS of the assignment statement. Or you can assign the whole sequence to a single name.

restart:

f := proc(x)
     return x, x^2, x^3;
end proc:

r1, r2, r3 := f(3);

                           r1, r2, r3 := 3, 9, 27

r2;

                                      9

s := f(4);

                               s := 4, 16, 64

s;

                                  4, 16, 64

s[2];

                                     16

If you really want to get fancy you can use a feature of procedures to distinguish the number of names on the LHS of an assignment statement in which the procedure gets called. This is related only indirectly to your question, and I mention it mostly because it's not so easy to discover. See the help-page for nresults.

restart:

f := proc(x)
   if _nresults = 1 then
      return x;
   elif _nresults = 2 then
      return x, x^2;
   else
      return x, x^2, x^3;
   end if;
end proc:

r1, r2, r3 := f(3);

                           r1, r2, r3 := 3, 9, 27

p1, p2 := f(4);

                               p1, p2 := 4, 16

p2;

                                     16

s := f(5);

                                   s := 5
s;

                                      5

acer

On nothing

Joe Riel — Thu, 21 Mar 2013 08:29:10 Z

@acer Thanks for mentioning _nresults. It is a curious creature---it seems useful, but I've never found a definitive use for it.

Amusing myself with it I wrote the following:

enough := () -> `if`(_nresults=undefined,NULL,seq(1.._nresults)):
(a,b,c) := enough();
                                 a,b,c := 1,2,3

What surprised me was

() := enough();
                                 :=

That represents

NULL := 'NULL'

Well, sort of. If you enter NULL := 'NULL' an error is raised. But if you do (I'm using tty maple)

(**) interface(prettyprint=0);
(**) () := ();
NULL := 'NULL'

NULL is a protected name that is assigned the empty expression sequence. Attempting to reassign it raises an error. What surprised me was that it was legal to assign an empty sequence to the empty sequence. I suppose that makes sense; probably that is a result of being able to assign sequences to sequences. I don't recall when that feature was introduced (quite a while ago), but suspect that () := () was not legal in earlier versions of Maple.

MTM

acer — Thu, 21 Mar 2013 10:43:51 Z

@Joe Riel The only commands I can think of, offhand, that use _nresults are in the MTM package.

Some of those instances may seem to mimic Matlab functions (especially where the corresponding top Maple command offers an optional side-effect on a name). For example, compare Maple's MTM:-coeffs with Maple's coeffs, and with Matlab's (Symbolic Math Toolbox) coeffs.

That's partly why I mentioned _nresults, because the Question touched on Matlab vs Maple programming. I don't recall, however, whether Matlab allows user-defined functions with that kind of behaviour.