MaplePrimes - answers and comments on Question, Peano-Gosper fractal

flowsnake

Joe Riel — Sat, 27 Mar 2010 20:29:00 Z

Here's one approach. I only approximated the shape, so you'll have to clean up

recursive := proc(s::list, f::list, c::list, depth::posint)
local z,seg,segs;
    segs := seq(map(Transform, z, s, f), z in c);
    if depth = 1 then
        segs[];
    else
        seq(procname(seg[],c,depth-1), seg in segs)
    end if;
end proc:

Transform := proc(z,s,f)
local x,y,x2,y2,mag,theta;
    (x,y) := op(f-s);
    mag := sqrt(x^2+y^2);
    theta := arctan(y,x);
    x2 := z[1]*cos(theta) - z[2]*sin(theta);
    y2 := z[1]*sin(theta) + z[2]*cos(theta);
    [s[1] + mag*x2, s[2]+mag*y2];
end proc:

# These are just a crude approximation

P0 := [0,0]:
P1 := [.3, -.125]:
P2 := [.60,  .125]:
P3 := [.2,   .250]:
P4 := [.15,  .60]:
P5 := [.575,  .5]:
P6 := [0.9,  .40]:
P7 := [1,     0]:

flowsnake := recursive([0,0],[1,0]
                       , [NULL
                          , [P0,P1]
                          , [P2,P1]
                          , [P3,P2]
                          , [P3,P4]
                          , [P4,P5]
                          , [P5,P6]
                          , [P7,P6]
                         ]
                       , 2 # increase to refine
                      );

plot([flowsnake],axes=none,scaling=constrained);

improvement

Joe Riel — Sun, 28 Mar 2010 00:39:57 Z

I found a site, www.mathcurve.com/fractals/gosper/gosper.shtml, that shows how to construct the base curve. Here is an update that gives the precise curve. This can be cleaned up, but I took the easy route from what I'd already done.

recursive := proc(s::list, f::list, c::list, depth::posint)
local z,seg,segs;
    segs := seq(map(Transform, z, s, f), z in c);
    if depth = 1 then
        segs[];
    else
        seq(procname(seg[],c,depth-1), seg in segs)
    end if;
end proc:

Transform := proc(z,s,f)
local x,y,x2,y2,mag,theta;
    (x,y) := op(f-s);
    mag := sqrt(x^2+y^2);
    theta := arctan(y,x);
    x2 := z[1]*cos(theta) - z[2]*sin(theta);
    y2 := z[1]*sin(theta) + z[2]*cos(theta);
    [s[1] + mag*x2, s[2]+mag*y2];
end proc:

# Generate points of base curve
V := [seq([cos,sin](k*Pi/3), k=0..6)]:
E := [seq(V[k+1]-V[k], k=1..6)]:

P[1] := [0,0]:
P[2] := P[1]+E[5]+E[6]:
P[3] := P[2]+E[1]+E[6]:
P[4] := P[3]+E[3]+E[2]:
P[5] := P[4]+E[1]+E[2]:
P[6] := P[5]+E[5]+E[6]:
P[7] := P[6]+E[5]+E[6]:
P[8] := P[7]+E[5]+E[4]:

# Compute point (x,y) which is used to transform
# P[8] to (1,0); that is needed by Transform.

eqs := normal(Transform(P[8], P[1], [x,y]));
sol := solve({eqs[1]=1,eqs[2]=0}, {x,y});
xy := eval([x,y],sol);

# Apply Tranform to vertices
Q := map(Transform, [seq(P[k], k=1..8)], P[1], xy);

# Generate the Peano-Gosper curve
flowsnake := recursive([0,0],[1,0]
                       , [NULL
                          , [Q[1],Q[2]]
                          , [Q[3],Q[2]]
                          , [Q[4],Q[3]]
                          , [Q[4],Q[5]]
                          , [Q[5],Q[6]]
                          , [Q[6],Q[7]]
                          , [Q[8],Q[7]]
                         ]
                       , 3
                      ):

plot([flowsnake],axes=none,scaling=constrained);

Dear Joe, Thank you very

vadim piskun — Sat, 27 Mar 2010 23:33:00 Z

Dear Joe,

Thank you very much for your help!

vadim

Dear Joe, This is

vadim piskun — Sun, 28 Mar 2010 00:44:06 Z

Dear Joe,

This is perfect!,

Thanks again.

vadim