MaplePrimes - answers and comments on Question, BlackJack

creating a list of Maple objects

Doug Meade — Sat, 20 Mar 2010 03:12:50 Z

First piece of advice: let us see exactly what you have already done.

Maple's defaults prevent it from showing output from within many loops. That does not mean the object does not exist and cannot be used for other purposes. I'll illustrate with an example that creates an animation (sequence of plots).

Plist := NULL:
for k from 1 to 5 do
  Pnew := plot( x^k, x=-1..1 );
  Plist := Plist, Pnew;
end do:
plots:-display( Plist );

I must add that this is not an efficient way to create this list. But, I think it can be illustrative when getting started. I'm sure others will show you more efficient ways once we see exactly what you are trying to do, and how you are approaching the problem.

I hope this is of some use to you. If not, show us your code and I think we'll be able to point you in a reasonable direction.

Doug

---------------------------------------------------------------------
Douglas B. Meade  <><
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu

dealing 2-card hands

Doug Meade — Sat, 20 Mar 2010 04:37:00 Z

I'll guess that you got the "too many levels of recursion" because you didn't initialize "list" (to NULL, as in my example).

In most cases I now prefer to use the Generate command from the RandomTools package. Here's an example showing one way to do what you are trying to do.

face := [A,1,2,3,4,5,6,7,8,9,10,J,Q,K]:
suit := [Heart,Diamond,Club,Spade]:
deck := {seq(seq( [f,s], s=suit ), f=face )}:
Sim2 := proc( NumHands::posint, deck )
  local i, card1, card2, hands;
  uses RandomTools;

  hands := Array( 1..NumHands );
  for i from 1 to NumHands do
    card1 := Generate( choose( deck ) );
    card2 := Generate( choose( deck minus {card1} ) );
    hands[i] := [card1,card2]
  end do;
  return hands
end proc:
Sim2(10, deck);
[[[10, Spade], [2, Diamond]], [[5, Club], [1, Heart]], 

  [[1, Club], [K, Heart]], [[K, Diamond], [3, Club]], [[1, Spade], [Q, Club]], 

  [[Q, Club], [10, Heart]], [[Q, Club], [2, Club]], [[J, Heart], [2, Spade]], 

  [[J, Club], [Q, Club]], [[J, Diamond], [8, Heart]]]

You could make deck a global variable, or put its definition inside the proc, but I chose to pass it as an argument to the procedure. Also, instead of building the list one element at a time as in my example, note that it is more efficient to declare the size of the list.

Doug

---------------------------------------------------------------------
Douglas B. Meade  <><
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu

Thank you for the reply,

r.braatz — Sat, 20 Mar 2010 03:49:11 Z

Thank you for the reply, here is what I'm using:

with(Statistics):randomize():
face := [A,1,2,3,4,5,6,7,8,9,10,J,Q,K];
suit := [Heart,Diamond,Club,Spade];
predeck := map(suit,face);
deck :={seq(seq(predeck [ a,b ], a = 1..13),b = 1..4)};
Sim := proc ( hands )
             local n := 0, getindex1, card1, deck1, getindex2, card2;
             while n <= hands
             do n := n +1;
                  getindex1 := rand(1..52);
                  card1 := deck [ getindex1( ) ];
                  deck1 := deck minus {card1};
                  getindex2 := rand (1..51);
                  card2 := deck1 [ getindex2( ) ];
                  print (card1 + card2);
           end do;
           end:

Sim(10); This will give me a print of ten 2-card hands. However, I can't find a way to work with this printout. I'd like to take Sim(1000) or so and then convert these into values by the following functions(see below) so that I can work some statistics on the data to determine most likely hands and other items. I've never had a programming course, so I'm certain that my code is not efficient as I've been trying to copy what others have done; so I apologize for this.
Heart := x->x; Spade:=x->x; Diamond:=x->x; Club:=x->x; A:=11; J:=10; Q := 10; K:=10:

Rather than "print", I've tried the following command on the print line:
list := list, [card1 + card2]
This gives me an output, but I believe "hides" the actualy size. When I try to grab one element from the Sim(10), it gives "too many levels of recursion".

Again, I really just want it to generate black jack hands that I can then work with using some basic stastics. If you have any advice on how to improve the code, I would be very greatful. Thanks again for the previous help.