MaplePrimes - answers and comments on Question, ODE numeric integration

Use odeplot or output=listprocedure

alsholm — Fri, 12 Mar 2010 15:19:51 Z

You can do either one of the following. (I have inserted concrete values for a, b and t0).

The first method uses odeplot.

F := diff(y(x),x,x) + x^2*diff(y(x),x) + sin(x)*y(x) ;
EDF := {F = 0, y(1) = -.1, D(y)(1) = 2};
Snum := dsolve(EDF, y(x), type = numeric);
plots:-odeplot(Snum,[x,y(x)],0..10);
plots:-odeplot(Snum,[x,diff(y(x),x)],0..10);

The second method uses output=listprocedure.

Snum2 := dsolve(EDF, y(x), type = numeric,output=listprocedure);
S:=subs(Snum2,y(x));
S1:=subs(Snum2,diff(y(x),x));
plot(S,0..10);
plot(S1,0..10);

Preben Alsholm

'known' provoques a bug in dsolve ?

raymond_seroul — Fri, 12 Mar 2010 18:25:06 Z

I want to integrate the delayed differential equation

x'(t) = -x(t-1) for t ≥ 0 and x(t) = 1 for -1 ≤ t ≤ 0.

The idea is to evaluate x on [0,1], [1,2], and so on.

The following code works, but is very, very slow si N > 8 :

theta := t -> 1;
P := plot(theta, -1 .. 0);
N := 3;
xx := array(0 .. N+1);
xx[0] := theta;
for n from 0 to N do
xnum := dsolve({x(n) = xx[n](n), x'(t)(t) = -xx[n](t-1)},
x(t), type = numeric, output = listprocedure, 'known' = xx[n]);
xx[n+1] := rhs(xnum[2]);
P := P, plot(xx[n+1], n .. n+1)
od ;

display([P], axes = boxed)

But if I suppress the array xx[0..N+1] to get a better loop and write

theta := t -> 1;
P := plot(theta, -1 .. 0);
N := 3;
xx := theta;
for n from 0 to N do
xnum := dsolve({x(n) = xx(n), x'(t) = -xx(t-1)},
x(t), type = numeric, output = listprocedure, 'known' = xx);
xx := rhs(xnum[2]);
P := P, plot(xx, n .. n+1)
od ;

display([P], axes = boxed);

Maple breaks its connexion with his kernel and became useless.

Raymond Séroul, Université de Strasbourg

The name xx is reused

alsholm — Fri, 12 Mar 2010 19:31:06 Z

The problem may be that the name xx is reused in your second version.

The first of the following corresponds to your first loop and causes no problem.

The second redefines xx to be a procedure that must call a procedure also called xx. This is likely to be the problem.

I wouldn't think that avoiding array or Array would speed up your loop, anyway.

The unproblematic one:

restart;
theta := t -> 1;
xx := theta;
xnum := dsolve({x(0) = xx(0), diff(x(t),t) = -xx(t-1)},
type = numeric, output = listprocedure, 'known' = xx);

xx := rhs(xnum[2]);
xx(.12345);
xnum := dsolve({x(0) = xx(0), diff(x(t),t) = -xx(t-1)},
type = numeric, output = listprocedure, 'known' = xx);

xx1 := rhs(xnum[2]);
xx1(.12345);

The following will cause the loss of connection to the kernel.

Preben Alsholm

numeric intergration and piecewise

raymond_seroul — Fri, 12 Mar 2010 20:33:12 Z

Dear Preben Alsholm,

thank you a lot for your aid.

Avoiding the array was only aesthetic.

I am still enjoying my delayed differential equation. As the previous code est very slow (because of recursive calls),
I tried to use the option 'piecewise'. But the documentatiohn is osbcure and does not help. I tried the code

xx := t -> 1 ;
P := plot(xx, -1 .. 0);

xnum := dsolve({x(0) = xx(0), (D(x))(t) = -xx(t-1)},
x(t), type = numeric, output = piecewise, range = 0 .. 1, 'known' = xx);
yy := unapply(rhs(xnum(t)[2]), rhs(xnum[1]));

P := P, plot(yy, 0 .. 1);

xnum := dsolve({x(1) = ('yy')(1), (D(x))(t) = -('yy')(t-1)},
x(t), type = numeric, output = piecewise, range = 1 .. 2, 'known' = yy);
zz := unapply(rhs(xnum(t)[2]), rhs(xnum[1]));

P := P, plot(zz, 1 .. 2);

P := P, plot(tt, 2 .. 3);
display([P], axes = boxed);

But it does not work : i get the message

"Warning, cannot evaluate the solution further right of 1.9999993, probably a singularity."

Questions :

1) Do output = piecewise really works ?

2) The affectation yy := unapply(rhs(xnum(t)[2]), rhs(xnum[1]));
looks awkward, but I did not discover something more elegant.

3) The real problem is that Maple does not consider a dsolve(..., type = numeric)
as a genuine function. Is there a philosophy ?

Raymond Séroul, Université de Strasbourg

Raymond Séroul

Université de Strasbourg

Your code works

alsholm — Fri, 12 Mar 2010 21:26:50 Z

It seems to me that your code works. The warning is just that. A warning, not an error. It is to be expected since the function xx(t-1) at the time is undefined for t > 2.

Using output=piecewise makes it unnecessary to rename, since there is no recursive calling. In fact you made the right hand side of the differential equation into a concrete function of t given by a formula.

So you could change your code to

restart;
xx := t -> 1 :
P := plot(xx, -1 .. 0):
xnum := dsolve({x(0) = xx(0), (D(x))(t) = -xx(t-1)},type = numeric, output = piecewise, range = 0 .. 1):
xx:=unapply(subs(op(xnum),x(t)),t):
P := P, plot(xx, 0 .. 1):
#Just to see that it works
plots:-display(P);
xnum := dsolve({x(1) = xx(1), (D(x))(t) = -xx(t-1)},type = numeric, output = piecewise, range = 1 .. 2):
xx := unapply(subs(op(xnum),x(t)),t):
#Just to see that it still works
P := P, plot(xx, 1 .. 2):
plots:-display(P);

Preben Alsholm

Other ways

Robert Israel — Fri, 12 Mar 2010 20:43:54 Z

There are many ways to handle delay differential equations. You might look at www.mapleprimes.com/forum/delaylogistic or groups.google.ca/group/sci.math.symbolic/browse_frm/thread/1f04240aa7b3a42c/fcbe7928da2ad9d1