MaplePrimes - answers and comments on Question, Integrating with a numeric solution to a PDE

Integral of pde solution

Robert Israel — Thu, 11 Mar 2010 01:14:43 Z

You can try something like this:

> Sol := pdsolve(pde, ibc, numeric);
  usol:=  subs(Sol:-value(output=listprocedure),u(x,t));

usol is then a function of two variables x and t, which for numerical values of x and t gives the solution at that point. And you should be able to use this in numerical integration, e.g.

> evalf(Int(x * usol(x, 0.2), x = 0 .. 1));

or even

> plot(Int(x * usol(x,t), x = 0 .. 1)/Int(usol(x,t), x = 0 .. 1),
    t = 0 .. 2);

hmm

raggapuffin — Thu, 11 Mar 2010 04:00:48 Z

this looks like a good plan, however when i try the bivariate value(output=listprocedure) its saying "length of output exceeds limit of 1000000". Is this some limitation on my laptop or something thats easily fixed? Ryan

Sure

raggapuffin — Thu, 11 Mar 2010 05:36:59 Z

PDE := diff(u(x, t), t) = g*(diff(u(x, t), x))+diff(u(x, t), x, x) where g := piecewise(t <= 1/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 1/80 < t and t <= 2*(1/80), 0, 2*(1/80) < t and t < 3/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 3/80 < t and t < 4*(1/80), 0, 4*(1/80) < t and t < 5*(1/80), piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 5*(1/80) < t and t < 6*(1/80), 0, 6*(1/80) < t and t < 7/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 7/80 < t and t < 8*(1/80), 0, 8*(1/80) < t and t < 9/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 9/80 < t and t < 10*(1/80), 0, 10*(1/80) < t and t < 11/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 11/80 < t and t < 12*(1/80), 0) (6 cycles of a sawtooth potential turning on and off) IBC := {u(0, t) = 0, u(1, t) = 0, u(x, 0) = exp(-(x-2/3)^2/(2*a^2))/((2*Pi)^(1/2)*a)} where a:=1/100 pds := pdsolve(PDE, IBC, numeric, time = t, range = 0 .. 1, timestep = 1/10000, spacestep = 1/10000, optimize = true) R := pds:-value(output = listprocedure)

YESSS!

raggapuffin — Thu, 11 Mar 2010 19:01:53 Z

Thank you so much, that works great. p.s. I think you must have a much better PC!

length of output

Robert Israel — Thu, 11 Mar 2010 05:06:02 Z

I don't know. Maybe if you post your actual code, somebody could figure out what's causing that.

timestep and spacestep

Robert Israel — Thu, 11 Mar 2010 07:50:00 Z

If you are using spacestep = 1/10000 with a range of 0 .. 1, that means you are calculating that for each time step you have at least 10000 values of u(x,t). With timestep = 1/10000, calculating a value at, say, t = 1 would involve 10^8 values of
u(x,t). This is likely to be rather time-consuming, and if those values are all saved it will consume a huge chunk of memory as well. But this worked for me in Maple 13:


> g := piecewise(t <= 1/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]),
 1/80 < t and t <= 2*(1/80), 0, 2*(1/80) < t and t < 3/80, 
 piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 3/80 < t and t < 4*(1/80),
 0, 4*(1/80) < t and t < 5*(1/80), piecewise(x <= 2/3, k[1], 
 2/3 < x, k[2]), 5*(1/80) < t and t < 6*(1/80), 0, 6*(1/80) < t 
 and t < 7/80, piecewise(x <= 2/3, k[1], 2/3 < x, k[2]), 7/80 < t 
 and t < 8*(1/80), 0, 8*(1/80) < t and t < 9/80, piecewise(x 
 <= 2/3, k[1], 2/3 < x, k[2]), 9/80 < t and t < 10*(1/80), 0, 
 10*(1/80) < t and t < 11/80, piecewise(x <= 2/3, k[1], 2/3 < x,
 k[2]), 11/80 < t and t < 12*(1/80), 0);
 k[1]:= 1; k[2]:= 2; a:= 1/100;
 PDE := diff(u(x, t), t) = g*(diff(u(x, t), x))+diff(u(x, t), x, x);
 IBC := {u(0, t) = 0, u(1, t) = 0, u(x, 0) = exp(-(x-2/3)^2/(2*a^2))/
  ((2*Pi)^(1/2)*a)};
 pds := pdsolve(PDE, IBC, numeric, time = t, range = 0 .. 1, 
   timestep = 1/10000, spacestep = 1/10000, optimize = true);
 R := pds:-value(output = listprocedure);
 uu:= subs(R,u(x,t));
 evalf(Int(uu(x,0.2),x=0..1,method=_Dexp));

0.1435771715

It took about 190 seconds of CPU time on my computer.