MaplePrimes - answers and comments on Question, if and for loops (nested)

I have

plummie — Sat, 27 Feb 2010 19:47:55 Z

I have managed to make the loop work, except that for my first entry of the first loop where E[i]=E[2] I do not get given the correct answer. Can anyone see why it doesn't work as I have no idea? (running this again it gave me all correct entries, unsure why it failed first time as did not edit the code)

for i from 2 to n do

a := abs(E[i]-E[1]);

for j from 2 to n do

if i <> j then

b := abs(E[i]-E[j])

end if;

if b < a

then a := b

end if end do;

N := [op(N), a] end do;

for i to 1 do a := abs(E[i]-E[2]);

for j from 3 to n do

if i <> j then b := abs(E[i]-E[j])

end if;

if b < a

then a := b

end if end do;

N := [op(N), a]

end do;

Also when I add the loop into my calculation, which is inside a loop 'to 500 do' I receive the message 'Error cannot determine if this expression is true or false b<2.9343729273....'

which I don't understand as it will work when I remove the loop around it. Clearly doing the calculations individually 500 times is ridiculously time consuming and unnecessary. Can you help?

minimum difference

Joe Riel — Sat, 27 Feb 2010 21:21:21 Z

If the elements are real, a more efficient technique is to first sort them, then select the minimum adjacent difference:

smallestRealDiff := proc(L :: list)
local sL;
    sL := sort(L);
    min(sL[2..] - sL[..-2])
end proc:

I'm trying to find the

plummie — Sun, 28 Feb 2010 14:58:49 Z

I'm trying to find the minimum distance between two e'values of an nxn matrix. ie. for each e'value E[1]....E[n] i need to work out which other e'value it is closest to and then put the distance in a list.

like so:
N:= [abs(E[1]-E[5]),abs(E[2]-E[21]),abs(E[3]-E[7]),.....etc

This final list N is made up of values from 500+ nxn matrices so that i able to evaluate them statistically. I'm just using the op(N) call to put them all together

So really I am looking for a mindiff but for each e'value.

possibilities

Joe Riel — Sun, 28 Feb 2010 22:35:45 Z

That helps, but I'm still not sure I understand. That is, if E is an nxn matrix, why are you accessing it with one index (E[i])?

I'm going to assume that E is actually a list. Here are two implementation, which may or may not do what you want. The first is a straightforward implementation of your original idea (as I understand it), but using seqs. The algorithm is not particularly efficient. The second procedure uses a method I described here to first create a permutation list that is used to sort the list. That permits looking at adjacent values to find the minimum, which significantly improves the speed. After computing the values, it applies the inverse permutation to return the final list in the desired order.

slow := proc(E :: list)
local i,j,n;
    n := nops(E);
    [seq(min(seq(abs(E[i]-E[j]),j=1..i-1),
             seq(abs(E[i]-E[j]),j=i+i..n)
            )
         , i = 1..n)
    ];
end proc:

fast := proc(E :: list(numeric))
local i, n, P, L, A;
    n := nops(E);
    # compute permutation that sorts E
    P := map(attributes, sort([seq(setattribute(SFloat(E[i]),i), i=1..n)]));
    # apply permutation to sort E
    L := [seq(E[i], i in P)];
    # compute adjacent differences
    L := L[2..] - L[..-2];
    # compute minimum adjacencies
    L := [L[1], seq(min(L[i],L[i+1]), i=1..n-2), L[n-1]];
    # apply inverse permutation to restore order
    A := Array(1..n);
    for i to n do
        A[P[i]] := L[i];
    end do;
    [seq(A[i], i=1..n)];
end proc:

n := 1000:
L := RandomTools:-Generate(list(integer(range=0..5),n)):
time(slow(L));
                                     0.504

time(fast(L));
                                     0.008

do I understand it correctly?

Axel Vogt — Mon, 01 Mar 2010 01:09:35 Z

I'm trying to find the minimum distance between two e'values of an nxn matrix

Then I would do it by sorting (as already discussed), take 1st absolute
differences and sort again. The first element is one minimal solution:


M:=LinearAlgebra[RandomMatrix](3,3,generator=-99..99): # to have an example

V:=convert(M, Vector[row]);
V:=sort(V);

d:=LinearAlgebra[Dimension](V);

f:= (j) -> abs(V[j]-V[j+1]); # you want the minimum, if applied to V
W:=Vector[row](d-1,f);
W:=sort(W);
W[1];

In case used memory is a concern:

While it is easy to re-use W (by using 'map') if the dimension is constant
for V one would have to ponder a bit (but there is some command for a fast
re-arrangement of memory, if I recall correctly).

though that sounds like it

plummie — Sat, 27 Feb 2010 22:19:39 Z

though that sounds like it would be a great idea. I'm not sure how I could implement it as I would have to generate new lists for each i from 1 to n, then put the result of smallestRealDiff into a new list.

I don't think that when I'm generating things for upto i=200 this would work very well as I'd have to write a load of new loops around it and I think that would confuse me more.