MaplePrimes - answers and comments on Question, passing a parameter for initial condition in to my Dsolve.

DEtools[DEplot]

Scott03 — Fri, 26 Feb 2010 01:13:40 Z

The following should solve your problem

> eq:=diff(y(x),x,x)+y(x)^2*x^2=x^2:
> a:=[-0.6,-0.4,2.4,3.4]:
> MyColours:=[red,black,blue,green]:
> MyPlots:=[seq(DEtools[DEplot](eq,y(x),x=0..2,[[y(0)=0,D(y)(0)=a[i]]], linecolor=MyColours[i]),i =1..4)]:
> plots:-display(MyPlots);

The DEplot routine will deal with calling dsolve with your equation and initial conditions along with producing your plot that you are looking for.

Scott
Application Developer
Maplesoft

Alternatives

Joe Riel — Fri, 26 Feb 2010 10:08:44 Z

Here's two alternatives.

eqs := {diff(y(x),x,x)+y(x)^2*x^2=x^2}:
ics := {y(0)=y0, D(y)(0)=dy0}:
integ := dsolve(eqs union ics, numeric, 'parameters'=[y0,dy0]):

Various phase-space plots

integ('parameters' = [0,0]):
plots:-odeplot(integ, [y(x),D(y)(x)], 0..10, 'numpoints'=1000);

integ('parameters' = [0,1]):
plots:-odeplot(integ, [y(x),D(y)(x)], 0..10, 'numpoints'=1000);

Alternative that uses 'initial' to reinitialize the integrator

ics := {y(0)=0, D(y)(0)=0}:
integ := dsolve(eqs union ics, numeric):

plots:-odeplot(integ, [y(x),D(y)(x)], 0..10, 'numpoints'=1000);

integ('initial'); # this will tell you list order
integ('initial' = [0,0,1]):
plots:-odeplot(integ, [y(x),D(y)(x)], 0..10, 'numpoints'=1000);

Yet another way

alsholm — Fri, 26 Feb 2010 10:59:08 Z

You already got some excellent solutions.

Here is another.

eq:=diff(y(x),x,x)+y(x)^2*x^2=x^2;
a:=[-0.6,-0.4,2.4,3.4];
sol:=y1->subs(dsolve({eq,y(0)=0,D(y)(0)=y1},numeric,output=listprocedure),y(x)):
#sol(y1) is the numerical procedure for evaluating y(x) (with D(y)(0)=y1), so that
sol(-0.6)(0.12345);
#will return the value of y(0.12345)
#and
plot([seq(sol(a[i]),i=1..4)],0..2);
# will plot the 4 different solutions in one plot.

Preben Alsholm

Cheers

Dreamracer — Fri, 26 Feb 2010 21:03:19 Z

Thanks people,

Have a good weekend.