MaplePrimes - answers and comments on Question, The Parrondo Paradox

Parrondo

Robert Israel — Thu, 18 Feb 2010 11:37:00 Z

Here's how I'd do it. I'm using the parameter values suggested in the Wikipedia article on Parrondo's paradox.

Game A: payoff is +1 with probability 0.495, -1 with probability 0.505.

Game B: when current fortune is divisible by 3, payoff is +1 with probability .095, -1 with probability .905.
Otherwise payoff is +1 with probability .745, -1 with probability .255.

Game C: play game A when turn number is divisible by 3, otherwise game B.

> with(Statistics):
  Coin1:= Sample(Bernoulli(.495), 20000):
  Coin2:= Sample(Bernoulli(.095), 20000):
  Coin3:= Sample(Bernoulli(.745), 20000):
  A[0]:= 0: B[0]:= 0: C[0]:= 0:
  for t from 1 to 20000 do
    d1:= 2*round(Coin1[t])-1;
    d2:= 2*round(Coin2[t])-1;
    d3:= 2*round(Coin3[t])-1;
    A[t]:= A[t-1] + d1;
    if B[t-1] mod 3 = 0 then
      B[t]:= B[t-1] + d2
    else
      B[t]:= B[t-1] + d3
    end if;
    if t mod 3 = 0 then
      C[t]:= C[t-1] + d1
    elif C[t-1] mod 3 = 0 then
      C[t]:= C[t-1] + d2
    else 
      C[t]:= C[t-1] + d3
    end if
  end do:
 plot([[seq([i,A[i]],i=0..20000)],[seq([i,B[i]],i=0..20000)],[seq([i,C[i]],i=0..20000)]],
   symbol=point,style=point,colour=[red,blue,green]);

Game A results are in red, game B in blue, game C in green.

That is perfect Robert :-)

alex_01 — Thu, 18 Feb 2010 16:20:01 Z

That is perfect Robert :-) Sweet !
I think I now know why my code did not work because I did not specify Game C correctly

"Game C: play game A when turn number is divisible by 3, otherwise game B."

The thing is that I have not found one single reference that have explain that (not even the original flow chart that I posted)
so I am very greatful that you pointed that out :-). I have created a revised flowchart to illustrate the dynamics:

I was just wondering if there are any particular reason why you have p=0.495 for Game A.
Can you put it to p=0.5 or will that change the dynamics ?! Another thing if it is not to much to ask could you please
try to explain why the green curve has a positive slope both in words and in equations.
I mean it is very easy to see that it is the case but why ?

They are taking about Brownian ratchet but it is very difficult to see how such mechanics results in an
upward sloping green line .... humm

wwwex.physik.uni-ulm.de/marti/Dox_sem_2001/thermo-motor/parrodos%20game.pdf

Analysis of Parrondo Paradox

Joe Riel — Fri, 19 Feb 2010 07:17:22 Z

Here's a module that you can use to analyze the Parrondo paradox.

Parrondo := module()
option package;
export ExpectedValue
    ,  Pstationary
    ,  ProbOfEvents
    ,  A, B;
    ;
global e;

    # Define the state-transition matrices.
    # Pij is the probability of going from
    # state i to state j.  
    
    A := Matrix(3, [[   0   , 1/2-e , 1/2+e ],
                    [ 1/2+e ,   0   , 1/2-e ],
                    [ 1/2-e , 1/2+e ,   0   ]]
               );
    
    B := Matrix(3, [[   0   , 1/10-e , 9/10+e ],
                    [ 1/4+e ,   0    , 3/4-e  ],
                    [ 3/4-e , 1/4+e  ,   0    ]]
               );
    
    Pstationary := proc( P :: list(Matrix) )
    local lambda,M,V,y,Y,pos;
    description "Compute the stationary probability vector";
        # M is the transition matrix of the system.
        M := foldl(`.`, P[]);
        # The stationary probability vector is a row vector 
        # that satisfies Ps.M = Ps.  Use Eigenvectors
        # with the transpose of M to compute the tranpose of Ps.
        (lambda,V) := LinearAlgebra:-Eigenvectors(M^%T);
        if not member(1, convert(lambda,list), 'pos') then
            error "cannot find unity eigenvalue";
        end if;
        Y := V[..,pos];
        # Normalize the vector.
        return normal~(Y/add(y, y in Y));
    end proc;
    
    ExpectedValue := proc( P :: list(Matrix) )
    local i,k,bits,evts,val,E,n,Ps;
    description "Compute the expected value";
        Ps := Pstationary(P);
        n := nops(P);
        E := 0;
        for k from 0 to 2^n-1 do
            # Sum value of each possible sequence of evts.
            bits := Bits:-Split(k,':-bits'=n);
            evts := subs(0=-1, bits);
            val := add(e, e in evts);
            if val <> 0 then
                E := E + val*add(Ps[i]*ProbOfEvents(i, evts, P), i = 1..3)
            end if;
        end do;
        return normal(E);
    end proc;
    
    ProbOfEvents := proc(i0::{1,2,3}, evts::list({-1,+1}), P :: list(Matrix))
    description "Compute the probability of a given sequence of events, starting at state i0";
    local i,j,k,p;
        i := i0;
        p := 1;
        for k to nops(evts) do
            j := i + evts[k];
            j := 1 + modp(j-1, 3);
            p := p*P[k][i,j];
            i := j;
        end do;
        return p;
    end proc;
    
end module:

For example, to compute the expected (stationary) value of the game A, A, B, B, do

with(Parrondo):
E := ExpectedValue([A,A,B,B]);
eval(E, e=0);
                                           16/163
plot(E, e=0..0.02);

Thanx Joe exellent stuff

alex_01 — Fri, 19 Feb 2010 21:13:04 Z

Thanx Joe exellent stuff :-)
I think I need to do more research into Markov chains because I have a hard time keeping
up with the terminology ie transition matrix, stationary probability vector, Eigenvectors etc
If you have any free time feal free to try to explain such things. I am not expecting anything though :-)

all right thanx. I have done

alex_01 — Fri, 19 Feb 2010 21:36:14 Z

all right thanx. I have done some other work here (very nice with sliders etc).
but it is difficult to put my finger on the exact mechanics (it does not work properly) that makes it tick..humm

View 8342_ParronXX.mw on MapleNet or Download 8342_ParronXX.mw
View file details

eavesdropping

PatrickT — Sat, 20 Feb 2010 23:51:00 Z

This is a fascinating post, thanks to all the contributors. Robert, this is a very clear explanation of this Parrondo paradox. I wasn't familiar with it (though I'd heard of it), but I'm immediately drawn to it! Like Alex, I also value the verbal descriptions of what's going on.

First question: point of detail. Refer to Robert's post with subject "0.495" above. There it says "Now if you play a turn of game A, even though that is unfavourable in itself, it decreases the probability that your fortune will be 0 mod 3 in the next turns." How does playing game A make it less likely that fortune will be a multiple of 3? Sorry if it's obvious.

And second question: general point. Is it a correct description of the Parrondo game structure to make the following generalization?

Let x,y,z denote state variables (i.e. they evolve over time according to the outcome of the stochastic games). Let x denote wealth and (for simplicity) let y,z denote binary, indicator variables equal to either 1 or 0. Let E(x) denote the expected value of wealth x in a particular subgame.

I write the architecture of the Parrondo game as follows:

if z=0, then [game A]
E(x)<0

if z=1, then                                [game B]

                  if y=1, then            [subgame B1]
                                     E(x)>0
                  if y=0, then      [subgame B2]
                                   E(x)<0

Above, the indicator variable z is "time" (turn number), which evolves deterministically and independently, while the indicator variable y is "the property that x=0 mod 3", which evolves stochastically and also depends on z.

Both game A and game B are losing games when played independently of each other. However, game B contains a winning subgame (subgame B1). The Parondo paradox arises whenever the outcome of game A can bias game B in favor of the winning subgame B1. What turns a combination of losing games into a winning one is that the outcome of game A influences the value of the indicator/state variable y in favor of the winning subgame B1.

Is this a fair description of the general mechanism at work in the Parrondo paradox? And if so, doesn't the paradox arise from the "framing" of game B as one single losing game, rather than framing it as two separate (albeit interdependent) games B1 and B2?

By "framing" I just mean the way the Parrondo game is presented, where bundling subgames B1 and B2 into one single game B obscures the existence of a winning subgame that it is actually possible to play more often than it would first seem possible. No?