MaplePrimes - answers and comments on Question, Is it possible?

n queens problem

Robert Israel — Thu, 11 Feb 2010 10:07:19 Z

Yes, it's quite a nice programming exercise, and there are many ways to do it.
You might look at en.wikipedia.org/wiki/N_queens_problem

solution

Joe Riel — Thu, 11 Feb 2010 12:44:57 Z

Here's one approach. It runs in about 0.1 seconds and is reasonably short. Each line of output consists of the rows in which to place a queen.

queens := module()

export ModuleApply;

local guess
    , init
    , place
    , Solve
    , N,cnt,board
    ;

    ModuleApply := Solve;

    init := proc(n)
        N := n;
        board := Array(1..N,1..N);
        cnt := 0;
        NULL;
    end proc;

    Solve := proc(n)
        init(n);
        guess(1);
        return cnt;
    end proc;

    guess := proc(col)
    local row;
        for row to N do
            if board[row,col] = 0 then
                place(row,col,+1);
                if col = N then
                    cnt := cnt+1;
                    print(_rest,row);
                else
                    procname(col+1,_rest,row)
                end if;
                place(row,col,-1);
            end if;
        end do;
    end proc;

    place := proc(row,col,val)
    local i;
        board[row,col] := -val-1;
        for i from col+1 to N do
            board[row,i] := board[row,i]+val;
        end do;
        for i to min(row-1,N-col) do
            board[row-i,col+i] := board[row-i,col+i] + val;
        end do;
        for i to min(N-row,N-col) do
            board[row+i,col+i] := board[row+i,col+i] + val;
        end do;
    end proc;

end module:

queens(8);

n Queen Problem already in

Thomas Unger — Thu, 11 Feb 2010 18:46:02 Z

Check the help page for the keyword queen (select Search for text), there is already an example that makes use of Maple's Task Programming Feature.

Regards

If i code this in maple

Jabz — Sun, 28 Feb 2010 00:45:00 Z

If i code this in maple would it work for any size grid or will it only work an 8 by 8 grid??

Divide n by 12. Remember the remainder (n is 8 for the eight queens puzzle).
Write a list of the even numbers from 2 to n in order.
If the remainder is 3 or 9, move 2 to the end of the list.
Append the odd numbers from 1 to n in order, but, if the remainder is 8, switch pairs (i.e. 3, 1, 7, 5, 11, 9, …).
If the remainder is 2, switch the places of 1 and 3, then move 5 to the end of the list.
If the remainder is 3 or 9, move 1 and 3 to the end of the list.
Place the first-column queen in the row with the first number in the list, place the second-column queen in the row with the second number in the list, etc.

I just want to create a simple procedure that produces one of the unique solutions.

ok but ??

Jabz — Mon, 15 Feb 2010 06:45:43 Z

Ok . that looks very complecated to code lol. i want to code a similar program to this but i dnt really know how to go about it (still an amature at programming). I just want to create a program that displays a n*n matrix with ' n ' number of 'Q''s on board. For example for a 4*4 matrix it displays 2 uniqe matrixes with for 4 queens Q ' s (representin the number of qeens) and '0' 's (empty spaces) or it displays a matrix with any unique solution and prints the total number of unique solutions. Any help would be greatly appreciated.

Thanks in advance

not on male 12

Jabz — Sun, 28 Feb 2010 00:47:00 Z

I tried looking for it but its not in the database of maple 12's help?