MaplePrimes - answers and comments on Question, Asympotic solution

Asymptotic solution

Robert Israel — Sat, 27 Jun 2009 03:54:00 Z

> de := diff(y(r), r, r)+2*(diff(y(r),r))/r+9*(16*43)*Pi^2*sqrt(Pi/(2*(1/43)^3))
*polylog(3/2,-exp(1/43*(43-y(r))))/(16*Pi^2*sqrt(43)^3) = 0;

Change of independent variable: s = 1/r.

> sde:= simplify(PDEtools[dchange](r=1/s, de));

sde := s^4*diff(y(s),`$`(s,2))+387/2*2^(1/2)*Pi^(1/2)*polylog(3/2,-exp(1-1/43*y(s))) = 0

As mentioned in another thread, it looks like the solutions are asymptotically logarithmic. Try a logarithm:

> simplify(eval(lhs(sde),y(s) = c + a*ln(s)));

-s^2*a+387/2*2^(1/2)*Pi^(1/2)*polylog(3/2,-exp(1-c/43)*s^(-1/43*a))

Now polylog(3/2, t) = t + O(t^2), so for this to give 0 to lowest order, we want a = -86.

> series(eval(%,a=-86),s);

(86-387/2*2^(1/2)*Pi^(1/2)*exp(1-1/43*c))*s^2+387/4*Pi^(1/2)*exp(1-1/43*c)^2*s^4+O(s^6)

Choose c to make the s^2 term 0.

> c0:= solve(coeff(%,s,2)=0);

c0 := 43+43/2*ln(81/8*Pi)

Now let y(s) = c0 - 86*ln(s) + u(s), where hopefully u(s) is small when s is small.

> ude:= simplify(eval(sde, y(s) = c0 - 86*ln(s) + u(s)));

ude := 86*s^2+s^4*diff(u(s),`$`(s,2))+387/2*2^(1/2)*Pi^(1/2)*polylog(3/2,-2/9*2^(1/2)/Pi^(1/2)*s^2*exp(-1/43*u(s))) = 0

Linearize this, and solve the linearization:

> lde:= eval(ude,{polylog=unapply(t,(r,t)), exp=(t -> 1+t)});
  dsolve(lde);

u(s) = _C1*s^(1/2)*sin(1/2*7^(1/2)*ln(s))+_C2*s^(1/2)*cos(1/2*7^(1/2)*ln(s))

Presumably the _C1 and _C2 will be arbitrary constants, corresponding to the fact that solutions form a 2-parameter family. The next terms, which we'll want to make the s^3 terms in the differential equation 0, are, I think, c1*s*cos(7^(1/2)*ln(s))+c2*s*sin(7^(1/2)*ln(s))+c3*s.

> eval(ude,u(s) = _C1*s^(1/2)*sin(1/2*7^(1/2)*ln(s))+_C2*s^(1/2)*cos(1/2*7^(1/2)*ln(s)) 
    + c1*s*cos(7^(1/2)*ln(s)) + c2*s*sin(7^(1/2)*ln(s)) + c3*s);

The usual series command can't handle this, but the MultiSeries version can.

> MultiSeries:-series(lhs(%),s,3);

(2/43*_C1*sin(1/2*ln(1/s)*7^(1/2))*_C2*cos(1/2*ln(1/s)*7^(1/2))-5*c1*cos(ln(1/s)*7^(1/2))-1/43*_C1^2*sin(1/2*ln(1/s)*7^(1/2))^2-1/43*_C2^2*cos(1/2*ln(1/s)*7^(1/2))^2+5*c2*sin(ln(1/s)*7^(1/2))+7^(1/2)*c2*cos(ln(1/s)*7^(1/2))+2*c3+7^(1/2)*c1*sin(ln(1/s)*7^(1/2)))*s^3+O(s^(7/2)*(((-1/86*exp(-I*ln(1/s)*7^(1/2))-1/86*exp(ln(1/s)*7^(1/2)*I))*c1+(1/86*I*exp(-I*ln(1/s)*7^(1/2))-1/86*I*exp(ln(1/s)*7^(1/2)*I))*c2-1/43*c3)*((1/86*I*exp(-1/2*I*ln(1/s)*7^(1/2))-1/86*I*exp(1/2*I*ln(1/s)*7^(1/2)))*_C1+(-1/86*exp(-1/2*I*ln(1/s)*7^(1/2))-1/86*exp(1/2*I*ln(1/s)*7^(1/2)))*_C2)+1/6*((1/86*I*exp(-1/2*I*ln(1/s)*7^(1/2))-1/86*I*exp(1/2*I*ln(1/s)*7^(1/2)))*_C1+(-1/86*exp(-1/2*I*ln(1/s)*7^(1/2))-1/86*exp(1/2*I*ln(1/s)*7^(1/2)))*_C2)^3))

> s3term:= simplify(combine(eval(%,O=0))) assuming s > 0;

s3term := 1/86*s^3*(-2*_C1*_C2*sin(7^(1/2)*ln(s))-430*c1*cos(7^(1/2)*ln(s))-_C1^2+_C1^2*cos(7^(1/2)*ln(s))-_C2^2*cos(7^(1/2)*ln(s))-_C2^2-430*c2*sin(7^(1/2)*ln(s))+86*7^(1/2)*c2*cos(7^(1/2)*ln(s))+172*c3-86*7^(1/2)*c1*sin(7^(1/2)*ln(s)))

> solve(identity(s3term,s),{c1,c2,c3});

{c1 = 1/19264*7^(1/2)*(-5*7^(1/2)*_C2^2-14*_C1*_C2+5*7^(1/2)*_C1^2), c2 = -1/19264*(-7*_C2^2+10*_C1*_C2*7^(1/2)+7*_C1^2)*7^(1/2), c3 = 1/172*_C2^2+1/172*_C1^2}

To sum up, an asymptotic form for the solution as r -> infinity is

c0 + 86*ln(r) - _C1*r^(-1/2)*sin(1/2*7^(1/2)*ln(r))+_C2*r^(-1/2)*cos(1/2*7^(1/2)*ln(r)) + c1/r*cos(7^(1/2)*ln(r)) - c2/r*sin(7^(1/2)*ln(r))+c3/r

with c0, c1, c2 and c3 as above. The approximate values of _C1 and _C2 may be obtained by comparing this function and its derivative to the values for the numerical solution (obtained in another thread) at some convenient large value of r.

Masterly

PatrickT — Sat, 27 Jun 2009 11:55:27 Z

manjees, you can tell your prof that Robert cracked it.

my favorite moment is "The next terms, which we'll want to make the s^3 terms in the differential equation 0, are, I think,..." I guess this is the modern equivalent of a Tartaglia moment!

btw manjees, the last line comes from something like:

eval(´c0´ - 86*ln(s) + u(s), 
     u(s)=_C1*s^(1/2)*sin(1/2*7^(1/2)*ln(s))
          +_C2*s^(1/2)*cos(1/2*7^(1/2)*ln(s)) 
          +c1*s*cos(7^(1/2)*ln(s))
          +c2*s*sin(7^(1/2)*ln(s))
          +c3*s):
 eval(%,s=1/r);

Thanks

manjees — Sat, 27 Jun 2009 12:06:01 Z

Hi, my prof had given this problem over summer so that we learn problem solving using maple. It has lot more to it, but I was stuck on this DE thing and thanks to Robert, i fully understand it now. I really appreciate the length you guy go to help out. Thanks again MS P.S. I am still not able to get an expression for y(x) after applying numerical dsolve. It's in another thread. Any advice?

Ha....In the above post it

manjees — Sat, 27 Jun 2009 12:07:22 Z

Ha....In the above post it was meant to be guys. 'Guy' is a typo...thanks to both of u guys...

last step..

manjees — Mon, 29 Jun 2009 05:39:08 Z

Hi, how do we get the last step in Robert's solution above... Patrick's version is a solution for y(1/r) but we need sol. for y(r). Thanks MS

@ r=infinity

manjees — Tue, 30 Jun 2009 04:26:40 Z

the asymptotic solution above does not go to zero at infinity as ln(r) becomes problematic at infinity... I can take care of this if i write all ln(r)'s as ln(r/r[max]) where r[max] is a very large no. and the limit goes to r[max] rather than to infinity. My question is : should I use r[max] at the very start or jus replace all ln[r] by ln[r/r[max]] in final asymptotic solution...(Robert's solution in a post above). Thanks MS